-- =============================================
-- Author: Szekeres András
-- Create date:	2018.04.24.
-- Description:	Egy tanuló felmentéseinek frissítése a következõ tanévre
-- =============================================

IF OBJECT_ID('sp_FollowUpTanuloFelmentes') IS NOT NULL BEGIN
  DROP PROCEDURE sp_FollowUpTanuloFelmentes
END;
GO

CREATE PROCEDURE sp_FollowUpTanuloFelmentes
  @intezmenyId int,
  @aktTanevId int,
  @kovTanevId int,
  @tanuloId int
AS
BEGIN

	DECLARE @kovTanevesTanuloId int;
	SELECT @kovTanevesTanuloId = kovTanevesTanulo.ID
	FROM T_FELHASZNALO_OSSZES aktTanevesTanulo
	INNER JOIN T_FELHASZNALO_OSSZES kovTanevesTanulo ON aktTanevesTanulo.C_OKTATASIAZONOSITO = kovTanevesTanulo.C_OKTATASIAZONOSITO AND kovTanevesTanulo.C_TANEVID = @kovTanevId AND kovTanevesTanulo.C_INTEZMENYID = @intezmenyId
	WHERE aktTanevesTanulo.ID = @tanuloId
	  AND aktTanevesTanulo.C_INTEZMENYID = @intezmenyId
	  AND aktTanevesTanulo.C_TANEVID = @aktTanevId
	  AND kovTanevesTanulo.TOROLT = 'F'
	  AND aktTanevesTanulo.TOROLT = 'F'; --kell? elv olyat nem módosíthat, aki törölt

	IF @kovTanevesTanuloId IS NOT NULL
	BEGIN
		DELETE FROM T_TANULOMENTESSEG_OSSZES
		WHERE C_TANULOID = @kovTanevesTanuloId
		  AND C_INTEZMENYID = @intezmenyId
		  AND C_TANEVID = @kovTanevId;

		INSERT INTO T_TANULOMENTESSEG_OSSZES (C_ERTEKELESMENTESITES, C_KEZDETE, C_MENTESSEGOKA, C_ORAMENTESITES, C_VEGE, C_SZOVEGESENERTEKELHETO, C_TANTARGYID, C_TANULOID, C_INTEZMENYID, C_TANEVID, TOROLT, SERIAL, LASTCHANGED, CREATED, MODIFIER, CREATOR, NNID, ELOZOTANEVIREKORDID)
		SELECT
			C_ERTEKELESMENTESITES
		   ,C_KEZDETE
		   ,C_MENTESSEGOKA
		   ,C_ORAMENTESITES
		   ,C_VEGE
		   ,C_SZOVEGESENERTEKELHETO
		   ,C_TANTARGYID
		   ,@kovTanevesTanuloId
		   ,C_INTEZMENYID
		   ,@kovTanevId
		   ,TOROLT
		   ,0
		   ,GETDATE()
		   ,GETDATE()
		   ,MODIFIER
		   ,MODIFIER
		   ,NULL
		   ,ID
		FROM T_TANULOMENTESSEG_OSSZES
		WHERE C_TANULOID = @tanuloId
		  AND C_INTEZMENYID = @intezmenyId
		  AND C_TANEVID = @aktTanevId
		  AND TOROLT = 'F';
	END
END
GO
