﻿DROP PROCEDURE IF EXISTS uspSzirStatNemOktato
GO

CREATE PROCEDURE uspSzirStatNemOktato
   @pTanevId int
  ,@pIntezmenyid int
AS BEGIN
  
  DECLARE @datum datetime

  SELECT @datum = LEFT(tv.C_NEV, 4) + '1001' FROM T_TANEV tv WHERE ID = @pTanevId

  SELECT 
     fh.ID  AS TanuloIdAlkalmazottId
    ,fh.C_NYOMTATASINEV + ' (' + ISNULL(NULLIF(fh.C_OKTATASIAZONOSITO, ''), '-') + ')' AS AlkalmazottOktatasiAzonosito
    ,ia.C_OMKOD AS IntezmenyOmAzonosito
    ,ia.C_NEV AS IntezmenyNev
    ,ia.C_VAROS AS IntezenyTelepules
    ,ia.C_IRANYITOSZAM AS IntezmenyIrszam
    ,RTRIM(CONCAT(ia.C_KOZTERULETNEV, ' ', ia.C_KOZTERULETJELLEGENEV,' ', ia.C_HAZSZAM, ' ', ia.C_EMELET, ' ', ia.C_AJTO)) AS IntezmenyCim
    ,ISNULL(NULLIF(ia.C_EMAILCIM, ''), '-') AS IntezmenyEmailcim
    ,CONCAT(ia.C_OMKOD, '/', fhely.C_FELADATELLATASIHELYKOD) AS FelhelyAzonosito
    ,mhely.C_NEV AS FelhelyNev
    ,mhely.C_VAROS AS FelhelyTelepules
    ,mhely.C_IRANYITOSZAM AS FelhelyIrszam
    ,RTRIM(CONCAT(mhely.C_KOZTERULETNEV, ' ', mhely.C_KOZTERULETJELLEGENEV,' ', mhely.C_HAZSZAM, ' ', mhely.C_EMELET, ' ', mhely.C_AJTO)) AS FelhelyCim
    ,ISNULL(NULLIF(mhely.C_EMAILCIM, ''), '-') AS FelhelyEmailcim
    ,fhelytip.C_NAME AS FelhelyTipus
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8385, LTRIM(RTRIM(REPLACE(REPLACE(REPLACE(REPLACE(munkakor.C_NAME, 'EGYÉB', ''), 'TOVÁBBI ', ''), 'NOKS', ''), '(*)', ''))), '-') AS AlkalmazottNoksMunkakor
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8385, nem.C_NAME, '-') AS AlkalmazottNoksNem
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8385, foglalkozastipus.C_NAME, '-') AS AlkalmazottNoksMunkaido
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8385, IIF(fokozat.ID = 3040, 'Nem', fokozat.C_NAME), '-') AS AlkalmazottNoksSzakkepzettseg
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8386, LTRIM(RTRIM(REPLACE(REPLACE(REPLACE(REPLACE(munkakor.C_NAME, 'EGYÉB', ''), 'TOVÁBBI ', ''), 'NOKS', ''), '(*)', ''))), '-') AS AlkalmazottEgyebMunkakor
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8386, nem.C_NAME, '-') AS AlkalmazottEgyebNem
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8386, foglalkozastipus.C_NAME, '-') AS AlkalmazottEgyebMunkaido
    ,IIF(munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID = 8386, IIF(fokozat.ID = 3040, 'Nem', fokozat.C_NAME), '-') AS AlkalmazottEgyebSzakkepzettseg
  FROM T_FELHASZNALO fh 
    INNER JOIN T_ALKALMAZOTT a ON a.ID = fh.ID
    INNER JOIN T_INTEZMENYADATOK ia ON ia.C_TANEVID = fh.C_TANEVID AND ia.TOROLT = 'F'
    INNER JOIN T_INTEZMENY i ON ia.C_INTEZMENYID = i.ID AND i.TOROLT = 'F'
    INNER JOIN T_FELADATELLATASIHELY fhely ON fhely.C_TANEVID = ia.C_TANEVID AND fhely.TOROLT = 'F'
    INNER JOIN T_MUKODESIHELY mhely ON mhely.ID = fhely.C_MUKODESIHELYID AND mhely.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE fhelytip ON fhelytip.ID = fhely.C_OKTATASINEVELESIFELADATTIPUS AND fhelytip.C_TANEVID = fhely.C_TANEVID AND fhelytip.TOROLT = 'F'
    INNER JOIN T_MUNKAUGYIADATOK ma ON ma.C_ALKALMAZOTTID = fh.ID AND ma.TOROLT = 'F' AND ma.C_FELADATELLATASIHELYID = fhely.ID AND ma.TOROLT = 'F'
    INNER JOIN T_MUNKAKORTIPUS munkakortipus ON munkakortipus.ID = ma.C_MUNKAKORTIPUSA AND munkakortipus.C_ALTANEVID = ma.C_TANEVID AND munkakortipus.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE nem ON fh.C_NEME = nem.ID AND nem.C_TANEVID = fh.C_TANEVID AND nem.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE munkakor ON munkakor.ID = ma.C_MUNKAKORTIPUSA AND munkakor.C_TANEVID = ma.C_TANEVID AND munkakor.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE fokozat ON fokozat.ID = ma.C_BESOROLASIFOKOZAT AND fokozat.C_TANEVID = ma.C_TANEVID AND fokozat.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE foglalkozastipus ON foglalkozastipus.ID = ma.C_FOGLALKOZTATASTIPUS AND foglalkozastipus.C_TANEVID = ma.C_TANEVID AND foglalkozastipus.TOROLT = 'F'
  WHERE fh.TOROLT = 'F'
    AND (ma.C_ALKALMAZASMEGSZUNESE >= @datum OR ma.C_ALKALMAZASMEGSZUNESE IS NULL)
    AND ISNULL(fh.C_ELOTAG,'') NOT LIKE '[[]%'
    AND a.C_ALLANDOHELYETTESITESRE = 'F'
    AND ma.C_TARTOSHELYETTESITES = 'F'
    AND munkakortipus.C_ALKALMAZOTTMUNKAKORTIPUSID IN (8385, 8386)
    AND fh.C_TANEVID = @pTanevId
    AND fh.C_INTEZMENYID = @pIntezmenyid
    AND a.C_ISDUALISKEPZOHELYIOKTATO = 'F'
END
GO
