DROP PROCEDURE IF EXISTS [dbo].[uspGetTeremData]
GO

CREATE PROCEDURE [dbo].[uspGetTeremData]
   @pIntezmenyId INT
  ,@pTanevId INT
  ,@pIsFromSzervezet BIT
  ,@pSzervezetId INT
  ,@pSzervezetekHalmaza INT
AS BEGIN
  SET NOCOUNT ON;

  CREATE TABLE #SzurtTermek (
     Id INT
  )

  IF @pIsFromSzervezet = 0
  BEGIN
    INSERT INTO #SzurtTermek
    SELECT
       t.ID AS Id
    FROM T_TEREM_OSSZES t
    WHERE t.TOROLT = 'F'
      AND t.C_TANEVID = @pTanevId
      AND t.C_INTEZMENYID = @pIntezmenyId
  END
  ELSE
  BEGIN
    INSERT INTO #SzurtTermek
    SELECT
       t.ID AS Id
    FROM T_TEREM_OSSZES t
      INNER JOIN (
        T_SZERVEZET_OSSZES sz
        INNER JOIN (
          SELECT * FROM dbo.fnGetLathatoSzervezetek(@pIntezmenyId, @pTanevId, @pSzervezetId, @pSzervezetekHalmaza)
        ) AS lathato ON lathato.ID = sz.ID
      ) ON sz.ID = t.C_SZERVEZETID AND sz.TOROLT = 'F'
    WHERE t.TOROLT = 'F'
      AND t.C_TANEVID = @pTanevId
      AND t.C_INTEZMENYID = @pIntezmenyId
  END

  SELECT
     t.ID AS Id
    ,t.C_NEV AS Nev
    ,t.C_JELLEG AS JellegId
    ,t.C_KAPACITAS AS Kapacitas
    ,t.C_TERULET AS Terulet
    ,t.C_IMPORTALT AS Importalt
    ,t.C_AKTIV AS IsAktiv
    ,t.C_VIZSGAKAPACITAS AS VizsgaKapacitas
    ,t.C_TOBBORATLEHETTARTANI AS IsTobbOratLehetTartani
    ,t.C_WIFILEFEDETT AS IsWifiLefedett
    ,t.C_MEGJEGYZES AS Megjegyzes
    ,t.C_ISINTERNETKAPCSOLATELERHETO AS IsInternetKapcsolatElerheto
    ,t.C_TANULOKSZAMARAHOZZAFERHINTER AS TanulokSzamaraHozzaferhInternetesGep
    ,t.C_PEDAGOGUSHOZZAFERHINTERNETES AS PedagogusHozzaferhInternetesGep
    ,t.C_OKTCELRAHASZNALTSZAMITOGEPEK AS OktCelraHasznaltSzamitogepekSzama
    ,t.C_ISINTERAKTTABLAVALMUNKAALLOM AS IsInteraktTablavalMunkaAllomassalFelszerelt
    ,m.ID AS MukodesiHelyId
    ,m.C_NEV AS MukodesiHelyNev
    ,f.ID AS TeremfelelosId
    ,f.C_NYOMTATASINEV AS TeremfelelosNev
    ,f.C_SZULETESIDATUM AS TeremfelelosSzuletesiIdo
    ,t.C_DUALISKEPZOHELYADOSZAMA AS RogziteskoriSzervezetAzonosito
    ,t.C_DUALISKEPZOHELYNEVE AS RogziteskoriSzervezetNev
    ,t.C_SZERVEZETID AS SzervezetId
    ,sz.C_AZONOSITO AS SzervezetAzonosito
    ,sz.C_NEV AS SzervezetNev
    ,t.CREATOR AS RogzitoId
  FROM T_TEREM_OSSZES t
    LEFT JOIN T_MUKODESIHELY_OSSZES m ON m.ID = t.C_MUKODESIHELYID AND m.C_TANEVID = t.C_TANEVID AND m.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO_OSSZES f ON f.ID = t.C_TEREMFELELOSID AND f.C_TANEVID = t.C_TANEVID AND f.TOROLT = 'F'
    INNER JOIN #SzurtTermek szt ON szt.Id = t.ID
    LEFT JOIN T_SZERVEZET_OSSZES sz ON sz.ID = t.C_SZERVEZETID AND sz.C_TANEVID = t.C_TANEVID AND sz.TOROLT = 'F'
  WHERE t.TOROLT = 'F'
    AND t.C_TANEVID = @pTanevId
    AND t.C_INTEZMENYID = @pIntezmenyId

END
