DROP PROCEDURE  IF EXISTS uspGetTanoraiCsoportTanulok 
GO

CREATE PROCEDURE uspGetTanoraiCsoportTanulok
  @pTanuloiCsoportAzonosito INT
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Felhasznalo.ID AS KretaAzonosito
    ,Felhasznalo.C_VEZETEKNEV AS VezetekNev
    ,Felhasznalo.C_UTONEV AS KeresztNev
    ,Felhasznalo.C_OKTATASIAZONOSITO AS OktatasiAzonosito
    ,ISNULL(Felhasznalo.C_ELOTAG, '') AS Elotag
    ,TanuloCsoport.Osztaly AS Osztaly /*ami Csoport*/
    ,TanuloCsoport.OsztalyKretaAzonosito AS OsztalyKretaAzonosito /*ami CsoportKretaAzonosito*/
    ,Felhasznalo.C_EGYEDIAZONOSITO AS EgyediAzonosito
    ,Felhasznalo.C_IDPEGYEDIAZONOSITO AS IdpEgyediAzonosito
  FROM T_FELHASZNALO_OSSZES Felhasznalo
  INNER JOIN T_TANULO_OSSZES Tanulo ON Tanulo.ID = Felhasznalo.ID
    AND Tanulo.TOROLT = 'F'
  INNER JOIN (
    SELECT TanuloCsoport.C_TANULOID AS TanuloId
      ,OsztalyCsoport.C_NEV AS Osztaly /*ami Csoport*/
      ,OsztalyCsoport.ID AS OsztalyKretaAzonosito /*ami CsoportKretaAzonosito*/
    FROM T_TANULOCSOPORT_OSSZES TanuloCsoport
    INNER JOIN T_OSZTALYCSOPORT_OSSZES OsztalyCsoport ON OsztalyCsoport.ID = TanuloCsoport.C_OSZTALYCSOPORTID
      AND OsztalyCsoport.TOROLT = 'F'
      AND TanuloCsoport.TOROLT = 'F'
      AND TanuloCsoport.C_BELEPESDATUM <= (
        SELECT IIF(GETDATE() < C_ELSOTANITASINAP, C_ELSOTANITASINAP, GETDATE())
        FROM T_TANEV_OSSZES
        WHERE C_AKTIV = 'T'
          AND TOROLT = 'F'
          AND C_INTEZMENYID = TanuloCsoport.C_INTEZMENYID
        )
      AND (
        TanuloCsoport.C_KILEPESDATUM IS NULL
        OR TanuloCsoport.C_KILEPESDATUM > GETDATE()
        )
    WHERE EXISTS (
        SELECT 1
        FROM T_CSOPORT_OSSZES Csoport
        INNER JOIN T_OSZTALYCSOPORT_OSSZES InnerOsztalyCsoport ON InnerOsztalyCsoport.ID = Csoport.ID
          AND InnerOsztalyCsoport.TOROLT = 'F'
        WHERE Csoport.ID = OsztalyCsoport.ID
          AND Csoport.TOROLT = 'F'
          AND Csoport.ID = @pTanuloiCsoportAzonosito
        )
    ) TanuloCsoport ON TanuloCsoport.TanuloId = Felhasznalo.ID
  WHERE Felhasznalo.TOROLT = 'F'
  ORDER BY Felhasznalo.C_NYOMTATASINEV
END
GO