DROP PROCEDURE  IF EXISTS uspGetGyerekemOsztalyaBankszamlaszamEugyintezes 
GO

CREATE PROCEDURE uspGetGyerekemOsztalyaBankszamlaszamEugyintezes
   @pGondviseloId INT
  ,@pOktNevKatTipus INT
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Osztaly.ID AS KretaAzonosito
    ,Osztaly.C_OSZTALYPENZBANKSZAMLASZAMA AS Szamlaszam
    ,Osztaly.C_OSZTALYPENZBANKSZAMLASZAMKED AS KedvezmenyezettNeve
  FROM T_GONDVISELO_OSSZES Gondviselo
  INNER JOIN T_TANULOCSOPORT_OSSZES Tanulocsoport ON Tanulocsoport.C_TANULOID = Gondviselo.C_TANULOID
    AND Tanulocsoport.TOROLT = 'F'
    AND TanuloCsoport.C_BELEPESDATUM <= (
      SELECT IIF(GETDATE() < C_ELSOTANITASINAP, C_ELSOTANITASINAP, GETDATE())
      FROM T_TANEV_OSSZES
      WHERE C_AKTIV = 'T'
        AND TOROLT = 'F'
        AND C_INTEZMENYID = Tanulocsoport.C_INTEZMENYID
      )
    AND (
      TanuloCsoport.C_KILEPESDATUM IS NULL
      OR TanuloCsoport.C_KILEPESDATUM > GETDATE()
      )
  INNER JOIN T_OSZTALY_OSSZES Osztaly ON Osztaly.ID = Tanulocsoport.C_OSZTALYCSOPORTID
    AND Osztaly.TOROLT = 'F'
  INNER JOIN T_OSZTALYCSOPORT_OSSZES OsztalyCsoport ON OsztalyCsoport.ID = Osztaly.ID
    AND OsztalyCsoport.TOROLT = 'F'
    AND OsztalyCsoport.C_FELADATKATEGORIAID = @pOktNevKatTipus
  WHERE Gondviselo.ID = @pGondviseloId
    AND Gondviselo.TOROLT = 'F'
END
GO


