DROP PROCEDURE IF EXISTS uspGetAlkalmazottAlapadatok
GO
  CREATE PROCEDURE uspGetAlkalmazottAlapadatok
     @pId INT
    ,@pTanevId INT
    ,@pIntezmenyId INT
  AS
  BEGIN
    SET NOCOUNT ON;

    SELECT Felhasznalo.C_OKTATASIAZONOSITO AS OktatasiAzonosito
      ,Felhasznalo.C_ELOTAG AS NevElotag
      ,Felhasznalo.C_VEZETEKNEV AS Vezeteknev
      ,Felhasznalo.C_UTONEV AS Utonev
      ,IIF(Felhasznalo.C_SZULETESINEVSORREND = 'F', Felhasznalo.C_SZULETESIVEZETEKNEV, Felhasznalo.C_SZULETESIUTONEV) AS SzuletesiVezeteknev
      ,IIF(Felhasznalo.C_SZULETESINEVSORREND = 'F', Felhasznalo.C_SZULETESIUTONEV, Felhasznalo.C_SZULETESIVEZETEKNEV) AS SzuletesiUtonev
      ,IIF(Felhasznalo.C_ANYJANEVESORREND = 'F', Felhasznalo.C_ANYJAVEZETEKNEVE, Felhasznalo.C_ANYJAUTONEVE) AS AnyjaNeveVezeteknev
      ,IIF(Felhasznalo.C_ANYJANEVESORREND = 'F', Felhasznalo.C_ANYJAUTONEVE, Felhasznalo.C_ANYJAVEZETEKNEVE) AS AnyjaNeveUtonev
      ,Felhasznalo.C_SZULETESINEV AS SzuletesiNev
      ,Felhasznalo.C_ANYJANEVE AS AnyjaNeve
      ,Felhasznalo.C_SZULETESIDATUM AS SzuletesiDatum
      ,Felhasznalo.C_SZULETESIHELY AS SzuletesiHely
      ,SzuletesiOrszagDictionary.C_NAME AS SzuletesiOrszag
      ,AllampolgarsagaDictionary.C_NAME AS Allampolgarsag
      ,Allampolgarsaga2Dictionary.C_NAME AS Allampolgarsag2
      ,NemDictionary.C_NAME AS Nem
    FROM T_FELHASZNALO_OSSZES Felhasznalo
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES SzuletesiOrszagDictionary ON SzuletesiOrszagDictionary.ID = Felhasznalo.C_SZULETESIORSZAG
      AND SzuletesiOrszagDictionary.TOROLT = 'F'
      AND SzuletesiOrszagDictionary.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND SzuletesiOrszagDictionary.C_TANEVID = Felhasznalo.C_TANEVID
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES AllampolgarsagaDictionary ON AllampolgarsagaDictionary.ID = Felhasznalo.C_ALLAMPOLGARSAGA
      AND AllampolgarsagaDictionary.TOROLT = 'F'
      AND AllampolgarsagaDictionary.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND AllampolgarsagaDictionary.C_TANEVID = Felhasznalo.C_TANEVID
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES Allampolgarsaga2Dictionary ON Allampolgarsaga2Dictionary.ID = Felhasznalo.C_ALLAMPOLGARSAGA2
      AND Allampolgarsaga2Dictionary.TOROLT = 'F'
      AND Allampolgarsaga2Dictionary.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND Allampolgarsaga2Dictionary.C_TANEVID = Felhasznalo.C_TANEVID
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES NemDictionary ON NemDictionary.ID = Felhasznalo.C_NEME
      AND NemDictionary.TOROLT = 'F'
      AND NemDictionary.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND NemDictionary.C_TANEVID = Felhasznalo.C_TANEVID
    WHERE Felhasznalo.TOROLT = 'F'
      AND Felhasznalo.C_TANEVID = @pTanevId
      AND Felhasznalo.ID = @pId
      AND EXISTS (
        SELECT 1
        FROM T_ALKALMAZOTT_OSSZES Alkalmazott
        WHERE Alkalmazott.C_ALTANEVID = Felhasznalo.C_TANEVID
          AND Alkalmazott.C_ALINTEZMENYID = Felhasznalo.C_INTEZMENYID
          AND Alkalmazott.ID = Felhasznalo.ID
          AND Alkalmazott.TOROLT = 'F'
          AND Alkalmazott.C_ALINTEZMENYID =  @pIntezmenyId
        )
  END
GO


