DROP PROCEDURE IF EXISTS [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetReszletek]
GO

-- =============================================
-- Description:  <Előszedjük a tanuló feljegyzéseit az elektronikus üzenetek oldal napló nézet tab-jához részletesen>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetReszletek]
   @pIntezmenyId INT
  ,@pTanevId INT
  ,@pTanuloId INT
  ,@pToroltElemek CHAR = 'F'
  ,@pTanarId INT
  ,@pEsemenyTipusElektronikusUzenetId INT
AS
BEGIN

  SET NOCOUNT ON;

  SELECT
     TanuloEsemeny.ID AS ID
    ,TanuloEsemeny.C_ESEMENYDATUMA AS EsemenyDatuma
    ,TanuloEsemeny.C_TIPUS AS Tipus
    ,TanuloEsemeny.C_TARGY AS Targy
    ,TanuloEsemeny.C_TARTALOM AS Tartalom
    ,TanuloEsemeny.TOROLT AS Torolt
    ,Tanulo.ID AS TanuloId
    ,Tanulo.C_NYOMTATASINEV AS TanuloNev
    ,Tanar.C_NYOMTATASINEV AS FeljegyzoNeve
    ,CASE
      WHEN TanuloEsemeny.C_FELJEGYZOID = @pTanarId
        THEN 'T'
        ELSE 'F'
    END AS Modosithato
    ,mua.C_SZERVEZETID AS FeljegyzoSzervezetId
  FROM T_TANULOESEMENY_OSSZES TanuloEsemeny
    LEFT JOIN T_TANULO_TANULOESEMENY TanuloTanuloEsemeny ON TanuloTanuloEsemeny.C_TANULOESEMENYID = TanuloEsemeny.ID
    LEFT JOIN T_FELHASZNALO_OSSZES Tanulo ON Tanulo.ID = TanuloTanuloEsemeny.C_TANULOID
      AND Tanulo.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO_OSSZES Tanar ON Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
      AND Tanar.C_INTEZMENYID = @pIntezmenyId
      AND Tanar.C_TANEVID = @pTanevId
      AND Tanar.TOROLT = 'F'
    LEFT JOIN T_MUNKAUGYIADATOK_OSSZES mua ON mua.C_ALKALMAZOTTID = Tanar.ID
      AND mua.TOROLT = 'F'
  WHERE Tanulo.ID = @pTanuloId
    AND TanuloEsemeny.C_INTEZMENYID = @pIntezmenyId
    AND TanuloEsemeny.C_TANEVID = @pTanevId
    AND TanuloEsemeny.C_TIPUS = @pEsemenyTipusElektronikusUzenetId
    --Ha a törölt flag True, a törölt elemeket is visszaadjuk
    AND TanuloEsemeny.TOROLT = IIF(@pToroltElemek = 'T',TanuloEsemeny.TOROLT, 'F')

END

GO

