﻿DROP PROCEDURE IF EXISTS uspGetTanarAltalErtekelhetoCsoportok
GO

CREATE PROCEDURE uspGetTanarAltalErtekelhetoCsoportok
   @pTanarId int
  ,@pTanevId int
  ,@OktNevKatTipus int
  ,@pSzuperOsztalyfonok int
  ,@pDatum date
  ,@pOsztalyGroup nvarchar(255)
  ,@pCsoportGroup nvarchar(255)
AS BEGIN
  SET NOCOUNT ON
  SELECT
     ocs.Id AS OsztalyCsoportId
    ,ocs.C_NEV AS Nev
    ,CASE WHEN o.ID IS NULL THEN @pCsoportGroup ELSE @pOsztalyGroup END AS GroupName
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND ocs.C_FELADATKATEGORIAID = @OktNevKatTipus
      AND ocs.TOROLT = 'F'
    INNER JOIN T_TANULOCSOPORT_OSSZES tcs ON ocs.ID = tcs.C_OSZTALYCSOPORTID 
      AND tcs.TOROLT = 'F'
    LEFT JOIN T_OSZTALY_OSSZES o ON o.ID = ocs.ID
  WHERE f.TOROLT = 'F'
    AND @pDatum >= tcs.C_BELEPESDATUM
    AND (tcs.C_KILEPESDATUM IS NULL OR tcs.C_KILEPESDATUM > @pDatum)
    AND tcs.C_TANULOID IN (SELECT ID FROM fnGetOsztalyfonokOsztalyanakTanuloi(@pTanarId, @pSzuperOsztalyfonok, @pDatum))
    AND f.C_TANEVID = @pTanevId
  UNION
  SELECT
     ocs.ID AS OsztalyCsoportId
    ,ocs.C_NEV AS Nev
    ,CASE WHEN o.ID IS NULL THEN @pCsoportGroup ELSE @pOsztalyGroup END AS GroupName
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND ocs.C_FELADATKATEGORIAID = @OktNevKatTipus
      AND ocs.TOROLT = 'F'
    LEFT JOIN T_OSZTALY_OSSZES o ON o.ID = ocs.ID
  WHERE (f.C_TANARID = @pTanarId OR @pSzuperOsztalyfonok = 1)
    AND ocs.C_TANEVID = @pTanevId
    AND f.TOROLT = 'F'
  ORDER BY Nev
END
GO