DROP PROCEDURE IF EXISTS uspGetTanarDolgozatTantargyak
GO

CREATE PROCEDURE uspGetTanarDolgozatTantargyak
   @pTanarId int
  ,@pTanevId int
  ,@OktNevKatTipus int
  ,@pSzuperOsztalyfonok int
  ,@pDatum date
AS BEGIN
  SET NOCOUNT ON
  SELECT DISTINCT
     t.ID AS TantargyId
    ,t.C_NEV AS TantargyNev
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND ocs.C_FELADATKATEGORIAID = @OktNevKatTipus
      AND ocs.C_TANEVID = f.C_TANEVID
      AND ocs.TOROLT = 'F'
    INNER JOIN T_TANULOCSOPORT_OSSZES tcs ON ocs.ID = tcs.C_OSZTALYCSOPORTID
    INNER JOIN T_TANTARGY_OSSZES t ON t.ID = f.C_TANTARGYID
  WHERE f.TOROLT = 'F'
    AND @pDatum >= tcs.C_BELEPESDATUM
    AND (tcs.C_KILEPESDATUM IS NULL OR tcs.C_KILEPESDATUM > @pDatum)
    AND tcs.C_TANULOID IN (SELECT ID FROM fnGetOsztalyfonokOsztalyanakTanuloi(@pTanarId, @pSzuperOsztalyfonok, @pDatum))
    AND f.C_TANEVID = @pTanevId
  UNION
  SELECT
     t.ID AS TantargyId
    ,t.C_NEV AS TantargyNev
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND ocs.C_FELADATKATEGORIAID = @OktNevKatTipus
    INNER JOIN T_TANTARGY_OSSZES t ON t.ID = f.C_TANTARGYID
      AND t.TOROLT = 'F'
  WHERE (f.C_TANARID = @pTanarId OR @pSzuperOsztalyfonok = 1)
    AND ocs.C_TANEVID = @pTanevId
  ORDER BY TantargyNev
END
GO