SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

DROP PROCEDURE IF EXISTS sp_GetIskolalatogatasiIgazolas
GO

CREATE PROCEDURE sp_GetIskolalatogatasiIgazolas
	@osztalyId	INT,
	@tanevId	INT
AS
BEGIN

	SET NOCOUNT ON;

    -- fejléc
	SELECT
	   IntezmenyAdatok.C_NEV AS IntezmenyNeve
	  ,IntezmenyAdatok.C_IGAZGATONEVE AS IGAZGATONEVE
	  ,IntezmenyAdatok.C_VAROS AS IntezmenyVaros
	  ,dbo.fnGetDokumentumIntezmenyCime(@tanevId) AS IntezmenyCime
	  ,C_OSZTALYFONOKID AS PartnerID
	  ,KepzesTipus.C_NAME AS KepzesForma
	  ,Tanev.C_NEV AS TANEV
	  ,ocs.C_NEV AS Osztaly
	  ,@osztalyId AS OsztalyId
	  ,ocs.C_EVFOLYAMTIPUSA AS EvfolyamTipusa
	  ,ocs.C_FELADATELLATASIHELYID AS FeladatEllatasiHelyId
	  ,Osztaly.C_KEPZESIFORMA AS KepzesiForma
	  ,Osztaly.C_OSZTALYFONOKID AS OsztalyFonokId
	  ,Osztaly.C_TANTERVID AS TantervId
	  ,ocs.C_KERESZTFELEVES AS OJCSJKeresztfeleves
	  ,Osztaly.C_TECHNIKAIOSZTALY AS OJTechnikaiOsztaly
	  ,Osztaly.C_NEMZETISEGI AS OJNemzetisegi
	  ,Osztaly.C_KETTANNYELVU AS OJKettannyelvu
	  ,Osztaly.C_NYELVIELOKESZITO AS OJNyelviElokeszito
	  ,Osztaly.C_LOGOPEDIAI AS OJLogopediai
	  ,Osztaly.C_SPORT AS OJSportOsztaly
	  ,Osztaly.C_AJPROGRAM AS OJAranyJanosProgram
	  ,Osztaly.C_GYOGYPEDAGOGIAI AS OJGyogypedagogiai
	  ,Osztaly.C_SZAKMACSOPORT AS SzakmaCsoport
	  ,Osztaly.C_AGAZAT AS Agazat
	  ,Osztaly.C_SZAKKEPESITES AS Szakkepesites
	  ,Osztaly.C_RESZSZAKKEPESITES AS Reszszakkepesites
	FROM T_INTEZMENYADATOK_OSSZES IntezmenyAdatok
    INNER JOIN T_TANEV_OSSZES Tanev ON Tanev.ID = IntezmenyAdatok.C_TANEVID AND Tanev.TOROLT = 'F'
	INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = @osztalyId AND ocs.C_TANEVID = IntezmenyAdatok.C_TANEVID AND ocs.TOROLT = 'F'
	INNER JOIN T_OSZTALY_OSSZES Osztaly ON Osztaly.C_ALTANEVID = IntezmenyAdatok.C_TANEVID AND Osztaly.ID = ocs.ID AND Osztaly.TOROLT = 'F'
	INNER JOIN T_DICTIONARYITEMBASE_OSSZES KepzesTipus ON KepzesTipus.ID = Osztaly.C_KEPZESIFORMA AND KepzesTipus.C_TANEVID = IntezmenyAdatok.C_TANEVID AND KepzesTipus.TOROLT = 'F'
	WHERE IntezmenyAdatok.TOROLT = 'F' AND IntezmenyAdatok.C_TANEVID = @tanevId

	-- tanulók
    SELECT
	   Tanulo.C_NYOMTATASINEV AS TanuloNev
	  ,Tanulo.C_OKTATASIAZONOSITO AS OktatasiAzonosito
	  ,Tanulo.C_SZULETESIDATUM AS SzuletesiIdo
	  ,Tanulo.C_SZULETESIHELY AS SzuletesiHely
	  ,Tanulo.C_ANYJANEVE AS AnyjaNeve
	  ,Tanulo.C_NYILVANTARTASKEZDETE AS JogviszonyKezdete
	  ,tta.C_JOGVISZONYVARHATOBEFEJEZESE AS JogviszonyVarhatoBefejezese
      ,@osztalyId AS OsztalyId
      ,Tanulo.ID AS TanuloId
	FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@TanevId, @osztalyId, 'T') s
	INNER JOIN T_FELHASZNALO_OSSZES Tanulo ON Tanulo.Id = s.TanuloId AND Tanulo.TOROLT = 'F' AND Tanulo.C_TANEVID = @tanevId
	INNER JOIN T_TANULOTANUGYIADATOK_OSSZES tta ON tta.C_TANULOCSOPORTID = s.TanuloCsoportId AND tta.TOROLT = 'F' AND tta.C_TANEVID = Tanulo.C_TANEVID
	ORDER BY Tanulo.C_NYOMTATASINEV

END

GO