DROP PROCEDURE IF EXISTS uspGetNemNaplozottOrakSzama
GO

CREATE PROCEDURE uspGetNemNaplozottOrakSzama
   @pTanevId INT
  ,@pIntezmenyId INT
AS

BEGIN
  SET NOCOUNT ON

  CREATE TABLE #OsztalyCsoportok (
     Id INT
    ,IsVegzos CHAR(1)
    ,IdoszakKezdete DATETIME
    ,IdoszakVege DATETIME
  )

  CREATE TABLE #NaptariNapok (
     Datum DATETIME
    ,HetirendId INT
    ,HetNapjaId INT
    ,OsztalyCsoportId INT
    ,IsEgyediNap CHAR(1) COLLATE DATABASE_DEFAULT
  )

  DECLARE
     @IdoszakKezdete DATETIME
    ,@IdoszakVege DATETIME = GETDATE()
    ,@VegzosUtolsoTanitasiNap DATETIME

  SELECT
    @IdoszakKezdete = tv.C_ELSOTANITASINAP
  FROM T_TANEV_OSSZES tv WHERE ID = @pTanevId

  SELECT
    @VegzosUtolsoTanitasiNap = MIN(C_DATUM)
  FROM T_TANEVRENDJE_OSSZES
  WHERE TOROLT = 'F' AND C_TANEVID = @pTanevId AND C_NAPTIPUSA IN (1402, 7600, 7601, 7602, 7603, 1395) AND C_OSSZESCSOPORTRAVONATKOZIK = 'T'

  INSERT INTO #OsztalyCsoportok (
     Id
    ,IsVegzos
    ,IdoszakKezdete
    ,IdoszakVege
  )
  SELECT
     ID As Id
    ,C_VEGZOSEVFOLYAM AS IsVegzos
    ,@IdoszakKezdete AS IdoszakKezdete
    ,IIF(C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap IS NOT NULL AND @IdoszakVege > @VegzosUtolsoTanitasiNap, @VegzosUtolsoTanitasiNap + 1, @IdoszakVege) AS IdoszakVege
  FROM T_OSZTALYCSOPORT_OSSZES
  WHERE TOROLT = 'F' AND C_TANEVID = @pTanevId

    UPDATE ocs
  SET
    ocs.IdoszakVege = NewVegeDatum
  FROM #OsztalyCsoportok ocs
  INNER JOIN (
    SELECT
       MIN(tr.C_DATUM) + 1 AS NewVegeDatum
      ,ocstr.C_OSZTALYCSOPORTID
      FROM T_TANEVRENDJE_OSSZES tr
      INNER JOIN T_OSZTALYCSOPORT_TANEVRENDJE ocstr ON ocstr.C_TANEVRENDJEID = tr.ID
      WHERE tr.C_OSSZESCSOPORTRAVONATKOZIK = 'F' AND tr.C_NAPTIPUSA IN (1402, 7600, 7601, 7602, 7603) AND tr.TOROLT = 'F' AND tr.C_TANEVID = @pTanevId
      GROUP BY ocstr.C_OSZTALYCSOPORTID
  ) x ON x.C_OSZTALYCSOPORTID = ocs.Id
  WHERE ocs.IsVegzos = 'T'

  INSERT INTO #NaptariNapok (
     Datum
    ,HetirendId
    ,HetNapjaId
    ,OsztalyCsoportId
    ,IsEgyediNap
  )
  SELECT
     nn.Datum
    ,ISNULL(tr.HetirendId, nn.HetirendId) AS HetirendId
    ,ISNULL(tr.HetNapjaId, nn.HetNapjaId) AS HetNapjaId
    ,nn.OsztalyCsoportId
    ,COALESCE(tr.IsEgyediNap, nn.IsEgyediNap, 'F')
  FROM (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,nn.C_HETIREND AS HetirendId
      ,nn.C_HETNAPJA AS HetNapjaId
      ,nn.C_ORARENDINAP AS OrarendiNap
      ,ocs.ID AS OsztalyCsoportId
      ,tr.C_EGYEDINAP AS IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
    INNER JOIN #OsztalyCsoportok ocs ON ocs.IdoszakKezdete <= nn.C_NAPDATUMA AND ocs.IdoszakVege > nn.C_NAPDATUMA
    LEFT JOIN T_TANEVRENDJE_OSSZES tr ON tr.C_DATUM = nn.C_NAPDATUMA AND nn.C_INTEZMENYID = tr.C_INTEZMENYID AND nn.C_TANEVID = tr.C_TANEVID AND tr.TOROLT = 'F' AND tr.C_OSSZESCSOPORTRAVONATKOZIK = 'T'
    WHERE nn.TOROLT = 'F' AND nn.C_INTEZMENYID = @pIntezmenyId AND nn.C_TANEVID = @pTanevId
  ) nn
  LEFT JOIN (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,tr.C_HETIREND AS HetirendId
      ,tr.C_HETNAPJA AS HetNapjaId
      ,tr.C_ORARENDINAP AS OrarendiNap
      ,ocstr.C_OSZTALYCSOPORTID AS OsztalyCsoportId
      ,tr.C_EGYEDINAP AS IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
    INNER JOIN T_TANEVRENDJE_OSSZES tr ON tr.C_DATUM = nn.C_NAPDATUMA AND nn.C_INTEZMENYID = tr.C_INTEZMENYID AND nn.C_TANEVID = tr.C_TANEVID AND tr.TOROLT = 'F' AND tr.C_OSSZESCSOPORTRAVONATKOZIK = 'F'
    INNER JOIN T_OSZTALYCSOPORT_TANEVRENDJE ocstr ON tr.ID = ocstr.C_TANEVRENDJEID
    INNER JOIN #OsztalyCsoportok ocs ON ocs.Id = ocstr.C_OSZTALYCSOPORTID AND ocs.IdoszakKezdete <= nn.C_NAPDATUMA AND ocs.IdoszakVege > nn.C_NAPDATUMA
    WHERE nn.TOROLT = 'F' AND nn.C_INTEZMENYID = @pIntezmenyId AND nn.C_TANEVID = @pTanevId AND nn.C_NAPDATUMA >= @IdoszakKezdete AND nn.C_NAPDATUMA < ocs.IdoszakVege
  ) tr ON nn.Datum = tr.datum AND nn.OsztalyCsoportId = tr.OsztalyCsoportId
  WHERE ISNULL(tr.OrarendiNap, nn.OrarendiNap) = 'T'

  SELECT
     COALESCE(helyettes.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV) AS Tanar
    ,FORMAT(nn.Datum, 'MM') AS Honap
    ,COUNT(*) AS Darab
  FROM T_ORARENDIORA_OSSZES oo
  INNER JOIN #NaptariNapok nn ON nn.HetnapjaId = oo.C_HETNAPJA AND oo.C_OSZTALYCSOPORTID = nn.OsztalyCsoportId AND nn.Datum >= oo.C_ORAERVENYESSEGKEZDETE
    AND ((nn.Datum < oo.C_ORAERVENYESSEGVEGE) OR (oo.C_ORAERVENYESSEGKEZDETE = oo.C_ORAERVENYESSEGVEGE AND nn.Datum = oo.C_ORAERVENYESSEGKEZDETE))
    AND (oo.C_HETIREND = 1554 OR nn.HetirendId = oo.C_HETIREND) AND oo.C_EGYEDINAP = nn.IsEgyediNap
  LEFT JOIN T_FELHASZNALO_OSSZES tanar ON tanar.ID = oo.C_TANARID AND tanar.C_TANEVID = oo.C_TANEVID AND tanar.TOROLT = 'F'
  LEFT JOIN T_HELYETTESITESIIDOSZAK_OSSZES hisz ON oo.ID = hisz.C_HELYETTESITETTORARENDID AND hisz.C_HELYETTESITESNAPJA = nn.Datum  AND hisz.C_TANEVID = oo.C_TANEVID AND hisz.TOROLT = 'F'
  LEFT JOIN T_FELHASZNALO_OSSZES helyettes ON hisz.C_HELYETTESTANAROKID = helyettes.ID AND helyettes.C_TANEVID = oo.C_TANEVID AND helyettes.TOROLT = 'F'
  WHERE oo.TOROLT = 'F' AND oo.C_TANEVID = @pTanevId AND nn.Datum <= @IdoszakVege AND nn.Datum >= @IdoszakKezdete
  GROUP BY COALESCE(helyettes.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV), FORMAT(nn.Datum, 'MM')

END
GO
