SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('fnGetIktatottDokumentumok') IS NOT NULL
BEGIN
  DROP FUNCTION fnGetIktatottDokumentumok
END  
GO

CREATE FUNCTION [dbo].[fnGetIktatottDokumentumok](
	@pTanevId INT
	,@pIntezmenyId INT
)
RETURNS @Result TABLE (  
   ID		INT NOT NULL  
  ,Kategoria	INT NOT NULL  
  ,DokumentumTipus	INT NOT NULL  
  ,DokumentumNeve	NVARCHAR(MAX) NOT NULL  
  ,FeladatellatasihelyId INT NULL
  ,FeladatellatasihelyNeve	NVARCHAR(MAX) NULL  
  ,Iktatoszam	NVARCHAR(MAX) NULL  
  ,IktatasDatuma	DATETIME NULL  
  ,IktatoSzemelye	NVARCHAR(MAX) NOT NULL  
  ,Statusz	INT NOT NULL  
  ,TanevNev	NVARCHAR(MAX) NOT NULL
  ,ElektronikusPeldanyId INT NULL
  ,FoszamosDokumentumId INT NULL
) AS  
BEGIN
INSERT INTO @Result (ID, Kategoria, DokumentumTipus, DokumentumNeve, FeladatellatasihelyId, FeladatellatasihelyNeve, Iktatoszam,
						IktatasDatuma, IktatoSzemelye, Statusz, TanevNev, ElektronikusPeldanyId, FoszamosDokumentumId)
		SELECT
			iktd.ID,
			iktd.C_DOKUMENTUMKATEGORIA Kategoria,
			iktd.C_DOKUMENTUMTIPUS DokumentumTipus,
			iktd.C_DOKUMENTUMNEVE DokumentumNeve,
			iktd.C_FELADATELLATASIHELYID FeladatellatasihelyId,
			IIF (iktd.C_FELADATELLATASIHELYID is NULL, '', CONCAT(mukodHely.C_NEV, ' - ', DIB.C_NAME)) FeladatellatasihelyNeve,
			iktd.C_IKTATOSZAM Iktatoszam,
			CASE iktd.C_DOKUMENTUMSTATUSZ 
				WHEN 7387 THEN iktd.C_GENERALASDATUMA
				WHEN 7388 THEN iktd.C_IKTATASDATUMA
				ELSE iktd.C_ELEKTRONIKUSPELDANYFELTOLTES
			END IktatasDatuma,
			felhasznalo.C_NYOMTATASINEV IktatoSzemelye,
			iktd.C_DOKUMENTUMSTATUSZ Statusz,
			tanev.C_NEV TanevNev,
			iktd.C_ELEKTRONIKUSPELDANYID ElektronikusPeldanyId,
			iktd.C_FOSZAMOSIKTATOTTDOKUMENTUMID FoszamosDokumentumId
			FROM T_IKTATOTTDOKUMENTUM iktd
			LEFT JOIN T_TANEV_OSSZES tanev ON tanev.ID = iktd.C_TANEVID and tanev.TOROLT = 'F'
			LEFT JOIN T_FELHASZNALO_OSSZES felhasznalo ON felhasznalo.ID = iktd.C_IKTATOSZEMELYID and felhasznalo.TOROLT = 'F'
			LEFT JOIN T_FELADATELLATASIHELY_OSSZES feh ON feh.ID = iktd.C_FELADATELLATASIHELYID and feh.TOROLT = 'F' and feh.C_TANEVID = iktd.C_TANEVID
			LEFT JOIN T_MUKODESIHELY_OSSZES mukodHely ON feh.C_MUKODESIHELYID = mukodHely.ID and mukodHely.TOROLT = 'F'
			LEFT JOIN T_DICTIONARYITEMBASE_OSSZES DIB ON feh.C_OKTATASINEVELESIFELADATTIPUS = DIB.ID
				AND feh.C_INTEZMENYID = DIB.C_INTEZMENYID
				AND feh.C_TANEVID = DIB.C_TANEVID 
			WHERE iktd.TOROLT = 'F'	AND iktd.C_TANEVID = @pTanevId AND iktd.C_INTEZMENYID = @pIntezmenyId
RETURN
END
GO
