SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetUzenofuzetErtekelolap]') IS NOT NULL 
BEGIN
  DROP PROCEDURE [dbo].[sp_GetUzenofuzetErtekelolap]
END  
GO

CREATE PROCEDURE [dbo].[sp_GetUzenofuzetErtekelolap]
	@osztalyId INT,
	@tanevId   INT

AS
BEGIN
	SET NOCOUNT ON;

	--Intézmény, tanév
	SELECT T_INTEZMENYADATOK_OSSZES.C_NEV				IntezmenyNeve,
		   T_INTEZMENYADATOK_OSSZES.C_VAROS				IntezmenyVaros,
		   dbo.fnGetDokumentumIntezmenyCime(@tanevId)	IntezmenyCime,
		   T_INTEZMENYADATOK_OSSZES.C_TELEFONSZAM		TELEFON,
		   T_INTEZMENYADATOK_OSSZES.C_EMAILCIM			EMAILCIM,
		   T_INTEZMENYADATOK_OSSZES.C_OMKOD				IntezmenyOMKod,
		   T_INTEZMENYADATOK_OSSZES.C_IGAZGATONEVE		Intezmenyvezeto, 
		   (SELECT C_OSZTALYFONOKID FROM T_OSZTALY_OSSZES WHERE T_OSZTALY_OSSZES.ID = @osztalyId AND T_OSZTALY_OSSZES.C_ALTANEVID = @tanevId AND T_OSZTALY_OSSZES.TOROLT = 'F') PartnerID,
		   T_TANEV_OSSZES.C_NEV							TANEV
	FROM T_INTEZMENYADATOK_OSSZES
		INNER JOIN T_TANEV_OSSZES on T_TANEV_OSSZES.ID = T_INTEZMENYADATOK_OSSZES.C_TANEVID AND T_TANEV_OSSZES.C_INTEZMENYID = T_INTEZMENYADATOK_OSSZES.C_INTEZMENYID AND T_TANEV_OSSZES.TOROLT = 'F'
	WHERE 
		T_INTEZMENYADATOK_OSSZES.TOROLT = 'F'
		AND T_TANEV_OSSZES.ID = @tanevId

	--Osztály, évfolyam
	SELECT T_OSZTALYCSOPORT_OSSZES.C_NEV,
		   T_OSZTALYCSOPORT_OSSZES.C_EVFOLYAMTIPUSA,
		   T_FELHASZNALO_OSSZES.C_NYOMTATASINEV Osztalyfonok
	FROM T_OSZTALYCSOPORT_OSSZES
		INNER JOIN T_OSZTALY_OSSZES ON T_OSZTALYCSOPORT_OSSZES.id = T_OSZTALY_OSSZES.ID
		INNER JOIN T_FELHASZNALO_OSSZES ON T_FELHASZNALO_OSSZES.id = T_OSZTALY_OSSZES.c_osztalyfonokid
	WHERE T_OSZTALYCSOPORT_OSSZES.TOROLT='F' 
		AND T_OSZTALYCSOPORT_OSSZES.ID = @osztalyId
		AND T_OSZTALYCSOPORT_OSSZES.C_TANEVID = @tanevId

	
	--Tanuló adatai
	SELECT 
		 TanuloId						Id
		,TanuloCsoportId				TanuloCsoportId
		,OsztalyTanuloi.BelepesDatum	BelepesDatum
		,OsztalyTanuloi.KilepesDatum	KilepesDatum
	INTO #studentsWithTanuloCsoport
	FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@tanevId, @osztalyId, 'T') OsztalyTanuloi

	SELECT 
		T_FELHASZNALO_OSSZES.ID						TANULOID,
		TanuloCsoportId,
		T_FELHASZNALO_OSSZES.C_NYOMTATASINEV		TANULONEV,
		T_FELHASZNALO_OSSZES.C_OKTATASIAZONOSITO	OKTATASIAZONOSITO
	FROM T_FELHASZNALO_OSSZES
		INNER JOIN #studentsWithTanuloCsoport Tanulok ON Tanulok.Id = T_FELHASZNALO_OSSZES.Id
	ORDER BY T_FELHASZNALO_OSSZES.C_NYOMTATASINEV
	
		SELECT 
		Datum
		,TipusId
		,ErtekelesSzoveg
		,ErtekelesOsztalyzatId
		,ErtekelesOsztalyzatValue
		,ErtekelesOsztalyzatNev
		,ErtekelesSzazalek
		,MagatartasOsztalyzatId
		,MagatartasOsztalyzatNev
		,MagatartasSzoveg
		,MagatartasErtekId
		,MagatartasErtek
		,SzorgalomOsztalyzatId
		,SzorgalomOsztalyzatNev
		,SzorgalomSzoveg
		,SzorgalomErtekId
		,SzorgalomErtek
		,TanuloId
		,TanuloCsoportId
		,OsztalyCsoportId
		,TantargyId
		,TantargyNevZarojellel
		,TantargyNev
		,TantargyNevNyomtatvanyban
		,TargyKategoriaId
		,FotargyE
		,FotargyId
		,Altantargy
		,ErtekelesTema
		,Jeloles
		,JelolesAndErtekelesTema 
		,isMagatartasSzorgalom
	INTO #ErtekelesekTemp
	FROM fnGetDokumentumErtekelesekOsztalyonkent (@tanevId, @osztalyId, DEFAULT, DEFAULT, DEFAULT, DEFAULT)

	EXEC sp_GetDokumentumErtekelesekIdoszakonkent
		@tanevId						= @tanevId,
		@osztalyCsoportId				= @osztalyId,
		@ertekelesTipusa				= NULL, 
		@csakTanorai					= 1, 
		@csakKivlasztottOsztalyCsoport	= 0, 
		@atsoroltTanuloErtekelesek		= 0,
		@fuggolegesTantargyak			= 0,
		@isMegjegyzesMegjelenjen		= 0

	DROP TABLE #studentsWithTanuloCsoport
END

GO