﻿IF OBJECT_ID('dbo.sp_HelyettesitesekKeresese') IS NOT NULL BEGIN
  DROP PROCEDURE dbo.sp_HelyettesitesekKeresese
END
GO

CREATE PROCEDURE [dbo].[sp_HelyettesitesekKeresese]
	@IntezmenyId int,
	@TanevId int,
	@pHelyettesitettTanarId int,
	@pHelyettesitesKezdete datetime,
	@pHelyettesitesVege datetime
AS
BEGIN
SET NOCOUNT ON;

DECLARE @TEMPORARENDINAPOK TABLE (Datum datetime, Hetirend int,HetNapja int,OsztalyCsoportId int)
INSERT INTO @TEMPORARENDINAPOK (Datum, Hetirend,HetNapja,OsztalyCsoportId)
SELECT Distinct
	Datum,
  ISNULL(TanevHetirend, NapHetirend) Hetirend,
  ISNULL(TanevHetNapja, NapHetNapja) HetNapja,
  OsztalyCsoportId
FROM (
  SELECT 
		NAPTARINAP.Datum Datum,
		NAPTARINAP.NapHetirend,
		NAPTARINAP.NapHetNapja,
		NAPTARINAP.TanevHetirend,
		NAPTARINAP.TanevHetNapja,
	  NAPTARINAP.OsztalyCsoportId
  FROM (
	(
       SELECT 
        C_NAPDATUMA Datum,
        C_HETIREND NapHetirend,
		    IIF(C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_NAPDATUMA), C_HETNAPJA) NapHetNapja,
        null TanevHetirend,
        null TanevHetNapja,
        null OsztalyCsoportId
      FROM T_NAPTARINAP_OSSZES            
      WHERE (TOROLT = 'F' AND C_NAPDATUMA >= @pHelyettesitesKezdete AND C_NAPDATUMA <= @pHelyettesitesVege AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId)
  )
	union 
  (
      SELECT 
        NAPTARINAP.C_NAPDATUMA Datum,
        NAPTARINAP.C_HETIREND NapHetirend,
		    IIF(NAPTARINAP.C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_NAPDATUMA), NAPTARINAP.C_HETNAPJA) NapHetNapja,
        tanevRendHetirend.C_HETIREND TanevHetirend,
        tanevRendHetirend.C_HETNAPJA TanevHetNapja,
        tanevRendHetirend.C_OSZTALYCSOPORTID OsztalyCsoportId
      FROM T_NAPTARINAP_OSSZES NAPTARINAP 
      inner JOIN (      
        SELECT  
          C_DATUM,
          C_HETIREND,
          T_OSZTALYCSOPORT_TANEVRENDJE.C_OSZTALYCSOPORTID,
          IIF(C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_DATUM), C_HETNAPJA) AS C_HETNAPJA
        from T_TANEVRENDJE_OSSZES  
        inner Join T_OSZTALYCSOPORT_TANEVRENDJE on T_OSZTALYCSOPORT_TANEVRENDJE.C_TANEVRENDJEID = T_TANEVRENDJE_OSSZES.ID     
        WHERE TOROLT = 'F' AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId And TOROLT = 'F') tanevRendHetirend on  tanevRendHetirend.C_DATUM = NAPTARINAP.C_NAPDATUMA          
    WHERE (TOROLT = 'F' AND NAPTARINAP.C_NAPDATUMA >= @pHelyettesitesKezdete AND NAPTARINAP.C_NAPDATUMA < @pHelyettesitesVege AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId)     
  )   
  ) NAPTARINAP
  ) result

-- Vegzosok utolso tanitasi napja
DECLARE @VegzosUtolsoTanitasiNap_spGetOrarend DATETIME;
SELECT
	@VegzosUtolsoTanitasiNap_spGetOrarend = C_DATUM
FROM T_TANEVRENDJE_OSSZES
WHERE
	TOROLT = 'F'
	AND C_TANEVID = (SELECT ID FROM T_TANEV_OSSZES WHERE TOROLT = 'F' AND C_AKTIV = 'T' AND C_INTEZMENYID = @IntezmenyId)
	AND C_NAPTIPUSA = 1402  AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId
  
SELECT
    NEWID() as ID
    ,ORARENDINAPOK.Datum as HelyettesitettDatum
    ,ora.ID as HelyettesitettOrarendiOraId
    ,IIF(ora.C_CSENGETESIRENDID = NULL, NULL, ora.C_ORASZAM) as HelyettesitettOraszam
    ,ora.C_CSENGETESIRENDORAID as HelyettesitettCsengetesiRendOraId
    ,ora.C_TANTARGYID as HelyettesitettTantargyID
    ,DATEADD(HOUR, DATEPART(HOUR, ora.C_ORAKEZDETE), DATEADD(MINUTE, DATEPART(MINUTE,ora.C_ORAKEZDETE),  ORARENDINAPOK.Datum)) HelyettesitettOraKezdete
	,DATEADD(HOUR, DATEPART(HOUR, ora.C_ORAVEGE), DATEADD(MINUTE, DATEPART(MINUTE,ora.C_ORAVEGE),  ORARENDINAPOK.Datum)) HelyettesitettOraVege
    ,ISNULL(TARGY.C_ROVIDNEV, targy.C_NEV) as HelyettesitettTantargy
    ,osztalycsoport.C_NEV as HelyettesitettOsztaly
    ,osztalycsoport.ID as HelyettesitettOsztalyId
    ,osztalycsoport.C_EVFOLYAMTIPUSA as HelyettesitettEvFolyamId
    ,terem.C_NEV as HelyettesitettTerem  
    ,terem.ID as HelyettesitettTeremId
    ,helyettesidoszak.ID as HelyettesitesId
    ,IIF(tanora.C_MEGTARTOTT = 'F', 'Elmaradt óra', helyettesito.C_NYOMTATASINEV) as HelyettesitoTanarNEV
	,tanora.ID as TanoraId
FROM T_ORARENDIORA ora
INNER JOIN @TEMPORARENDINAPOK ORARENDINAPOK ON (( ora.C_HETIREND = 1554 OR ORARENDINAPOK.HETIREND = ora.C_HETIREND ) AND ORARENDINAPOK.HETNAPJA = ora.C_HETNAPJA  
  And (ora.C_OSZTALYCSOPORTID = ORARENDINAPOK.OsztalyCsoportId or ORARENDINAPOK.OsztalyCsoportId is null))				
LEFT JOIN T_TEREM terem on (TEREM.id = ora.C_TEREMID AND TEREM.C_INTEZMENYID = @IntezmenyId AND TEREM.C_TANEVID=@TanevId)
LEFT JOIN T_TANTARGY targy ON targy.ID = ora.C_TANTARGYID AND targy.TOROLT = 'F'
LEFT JOIN T_OSZTALYCSOPORT osztalycsoport ON ora.C_OSZTALYCSOPORTID = osztalycsoport.ID AND osztalycsoport.TOROLT = 'F'
LEFT JOIN T_TANITASIORA tanora ON (tanora.C_ORARENDIORAID = ora.ID OR tanora.C_ORARENDIORAGROUPID = ora.ID)and DATEDIFF(DAY, tanora.C_ORAKEZDETE, ORARENDINAPOK.Datum) = 0 and tanora.TOROLT = 'F' 
LEFT JOIN T_HELYETTESITESIIDOSZAK helyettesidoszak ON helyettesidoszak.C_HELYETTESITETTORARENDID = ora.ID 
  AND ORARENDINAPOK.Datum = cast(helyettesidoszak.C_HELYETTESITESNAPJA AS date) AND helyettesidoszak.TOROLT = 'F'
LEFT JOIN T_FELHASZNALO helyettesito on helyettesito.ID = helyettesidoszak.C_HELYETTESTANAROKID AND helyettesito.TOROLT = 'F'

WHERE 
	ora.TOROLT	='F'
	AND ora.C_TANARID = @pHelyettesitettTanarId
	AND (tanora.ID IS NULL OR tanora.C_MEGTARTOTT = 'F')
	AND ora.C_ORAERVENYESSEGVEGE >= @pHelyettesitesKezdete 
	AND ora.C_ORAERVENYESSEGKEZDETE <= (CASE WHEN osztalycsoport.C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap_spGetOrarend IS NOT NULL AND @pHelyettesitesVege > @VegzosUtolsoTanitasiNap_spGetOrarend THEN @VegzosUtolsoTanitasiNap_spGetOrarend ELSE @pHelyettesitesVege END) 
	AND ORARENDINAPOK.DATUM BETWEEN @pHelyettesitesKezdete AND (CASE WHEN osztalycsoport.C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap_spGetOrarend IS NOT NULL AND @pHelyettesitesVege > @VegzosUtolsoTanitasiNap_spGetOrarend THEN @VegzosUtolsoTanitasiNap_spGetOrarend ELSE @pHelyettesitesVege END)
	AND (
		(ORARENDINAPOK.DATUM >= ora.C_ORAERVENYESSEGKEZDETE AND ORARENDINAPOK.DATUM < ora.C_ORAERVENYESSEGVEGE) 
		OR
		(ORARENDINAPOK.DATUM = ora.C_ORAERVENYESSEGKEZDETE AND ORARENDINAPOK.DATUM = ora.C_ORAERVENYESSEGVEGE)
	)
ORDER BY [HelyettesitettDatum], [HelyettesitettOraszam]

END