SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetReszletek]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetReszletek]
END
GO	

-- =============================================
-- Description:	<Előszedjük a tanuló feljegyzéseit az elektronikus üzenetek oldal napló nézet tab-jához részletesen>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetReszletek]
	 @pIntezmenyId						INT
	,@pTanevId							INT
	,@pTanuloId							INT
	,@pToroltElemek						CHAR = 'F'
	,@pTanarId							INT
	,@pEsemenyTipusElektronikusUzenetId	INT

AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT
		 TanuloEsemeny.ID					ID
		,TanuloEsemeny.C_ROGZITESDATUMA		RogzitesDatuma 
		,TanuloEsemeny.C_TIPUS				Tipus
		,TanuloEsemeny.C_TARGY				Targy
		,TanuloEsemeny.C_TARTALOM			Tartalom
		,TanuloEsemeny.TOROLT				Torolt
		,Tanulo.ID							TanuloId
		,Tanulo.C_NYOMTATASINEV				TanuloNev
		,Tanar.C_NYOMTATASINEV				FeljegyzoNeve	
		,CASE
			WHEN TanuloEsemeny.C_FELJEGYZOID = @pTanarId
				THEN 'T' 
				ELSE 'F' 
		END									Modosithato			
	FROM 
		T_TANULOESEMENY_OSSZES TanuloEsemeny
	LEFT JOIN
		T_TANULO_TANULOESEMENY TanuloTanuloEsemeny ON
			TanuloTanuloEsemeny.C_TANULOESEMENYID = TanuloEsemeny.ID
	LEFT JOIN 
		T_FELHASZNALO_OSSZES Tanulo ON
			Tanulo.ID = TanuloTanuloEsemeny.C_TANULOID
	LEFT JOIN 
		T_FELHASZNALO_OSSZES Tanar ON
			Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
		AND Tanar.C_INTEZMENYID = @pIntezmenyId
		AND Tanar.C_TANEVID = @pTanevId
	WHERE
			Tanulo.ID = @pTanuloId
		AND TanuloEsemeny.C_INTEZMENYID = @pIntezmenyId
		AND TanuloEsemeny.C_TANEVID = @pTanevId
		AND TanuloEsemeny.C_TIPUS = @pEsemenyTipusElektronikusUzenetId
		--Ha a törölt flag True, a törölt elemeket is visszaadjuk
		AND TanuloEsemeny.TOROLT = IIF(@pToroltElemek = 'T',TanuloEsemeny.TOROLT, 'F')

END


GO

