﻿SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetFeljegyzesBeirasokData]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetFeljegyzesBeirasokData]
END
GO

-- =============================================
-- Description:	<Előszedjük az osztály csoport tanulóinak feljegyzéseit>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesBeirasokData]
	 @pOsztalyCsoportId		INT
	,@pStartDate			DATETIME

AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT DISTINCT
		 TanuloEsemeny.ID							ID
		,TanuloEsemeny.C_ROGZITESDATUMA				RogzitesDatuma
		,TanuloEsemeny.C_TARGY						Targy
		,TanuloEsemeny.C_TARTALOM					Tartalom
		,Tanulo.ID									TanuloId
		,Tanulo.C_NYOMTATASINEV						TanuloNev
		,Tanulo.C_ANYJANEVE							AnyjaNeve
		,Tanulo.C_SZULETESIDATUM					SzuletesiIdo
		,Tanar.C_NYOMTATASINEV						FeljegyzoNeve
		,FeljegyzesTipus.ID							Tipus
		,OsztalyCsoport.C_NEV						OsztalyNev
	FROM 
		T_FELHASZNALO Tanulo
	LEFT JOIN 
		T_TANULO_TANULOESEMENY TanuloTanuloEsemeny ON
			TanuloTanuloEsemeny.C_TANULOID = Tanulo.ID 
	LEFT JOIN 
		T_TANULOESEMENY TanuloEsemeny ON
				TanuloEsemeny.ID = TanuloTanuloEsemeny.C_TANULOESEMENYID
			AND CAST(TanuloEsemeny.C_ROGZITESDATUMA AS DATE) >= CAST(@pStartDate AS DATE)
			AND CAST(TanuloEsemeny.C_ROGZITESDATUMA AS DATE) <= CAST(GETDATE() AS DATE)
	LEFT JOIN 
		T_DICTIONARYITEMBASE FeljegyzesTipus ON 
				FeljegyzesTipus.ID = TanuloEsemeny.C_TIPUS
			AND FeljegyzesTipus.TOROLT = 'F'
	LEFT JOIN 
		T_FELHASZNALO Tanar ON
				Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
			AND Tanar.TOROLT = 'F'
	LEFT JOIN 
		T_OSZTALYCSOPORT_TANULOESEMENY OsztalyCsoportTanuloEsemeny ON
			OsztalyCsoportTanuloEsemeny.C_TANULOESEMENYID = TanuloEsemeny.ID	
	LEFT JOIN 
		T_TANULOCSOPORT TanuloCsoport ON 
				TanuloCsoport.C_TANULOID = TANULO.ID 
			AND TanuloCsoport.TOROLT = 'F'
	LEFT JOIN 
		T_OSZTALYCSOPORT OsztalyCsoport ON
				OsztalyCsoport.ID = TanuloCsoport.C_OSZTALYCSOPORTID 
			AND OsztalyCsoport.TOROLT = 'F'
	WHERE 
			Tanulo.TOROLT = 'F'
		AND OsztalyCsoport.ID = @pOsztalyCsoportId
	ORDER BY 
		Tanulo.C_NYOMTATASINEV

END


GO

