DROP PROCEDURE IF EXISTS [uspGetKozossegiSzolgalatNaplo]
GO

CREATE PROCEDURE [dbo].[uspGetKozossegiSzolgalatNaplo]
   @pIntezmenyId int
  ,@pTanevId int
  ,@pOsztalyCsoportId int
AS 
BEGIN
  SET NOCOUNT ON;

  SELECT
     C_NEV AS IntezmenyNev
    ,dbo.fnGetDokumentumIntezmenyCime(@pTanevId)  IntezmenyCim
  FROM T_INTEZMENYADATOK_OSSZES
  WHERE C_TANEVID = @pTanevId

  CREATE TABLE #Tanulok (
     TanuloId int
    ,TanuloNev nvarchar(255)
    ,OsztalyNev nvarchar(255)
    ,OsztalycsoportId int
  )
  INSERT INTO #Tanulok
  SELECT 
     t.TanuloId
    ,f.C_NYOMTATASINEV
    ,ocs.C_NEV
    ,@pOsztalyCsoportId
  FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@pTanevId, @pOsztalyCsoportId, 'F') t
    INNER JOIN T_FELHASZNALO_OSSZES f ON f.ID = t.TanuloId AND f.TOROLT = 'F'
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = @pOsztalyCsoportId

  SELECT * FROM #Tanulok

  CREATE TABLE #NaploAdatok (
     ID int
    ,IntervallumKezdete datetime
    ,IntervallumVege datetime
    ,RogzitesDatuma  datetime
    ,TeljesitesiHelye nvarchar(255)
    ,Oraszam numeric(10,2)
    ,KozossegiSzolgalatTipusaId  int
    ,Megjegyzes nvarchar(1000)
    ,Torolt char(1)
    ,TanuloId int
    ,TanuloNev nvarchar(255)
    ,OsztalyNev nvarchar(255)
    ,Ugyiratszam nvarchar(50)
    ,Modosithato char(1)
    )

  INSERT INTO #NaploAdatok
  EXEC sp_GetKozossegiSzolgalatokReszletek @pIntezmenyId, @pTanevId

  SELECT DISTINCT
     na.ID
    ,dbo.fnGetDokumentumDatumFormatum(na.IntervallumKezdete) AS IntervallumKezdete
    ,dbo.fnGetDokumentumDatumFormatum(na.IntervallumVege) AS IntervallumVege
    ,dbo.fnGetDokumentumDatumFormatum(na.RogzitesDatuma) AS RogzitesDatuma
    ,na.TeljesitesiHelye
    ,na.Oraszam
    ,d.C_NAME AS KozossegiSzolgalatTipusa
    ,na.Megjegyzes
    ,na.Torolt
    ,na.TanuloId
    ,na.Ugyiratszam
    ,na.Modosithato
    ,@pOsztalyCsoportId AS OsztalycsoportId
  FROM #NaploAdatok na
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES d ON d.ID = na.KozossegiSzolgalatTipusaId 
      AND d.TOROLT = 'F'
      AND d.C_INTEZMENYID = @pIntezmenyId
      AND d.C_TANEVID = @pTanevId

END
GO