DROP PROCEDURE  IF EXISTS uspGetFoglalhatoTermekEugyintezes 
GO

CREATE PROCEDURE uspGetFoglalhatoTermekEugyintezes
    @pTanevId INT
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Terem.ID AS KretaAzonosito
    ,Terem.C_AR AS Ar
    ,MukodesiHely.C_IRANYITOSZAM AS Iranyitoszam
    ,MukodesiHely.C_VAROS AS Varos
    ,MukodesiHely.C_KOZTERULETNEV AS KozteruletNeve
    ,MukodesiHely.C_HAZSZAM AS Hazszam
    ,MukodesiHely.C_EMELET AS Emelet
    ,MukodesiHely.C_AJTO AS Ajto
    ,MukodesiHely.C_KOZTERULETJELLEGENEV AS KozteruletJellege
    ,Terem.C_FOGLALHATOIDOSZAKKEZDETE AS FoglalhatoIdoszakKezdete
    ,Terem.C_FOGLALHATOIDOSZAKVEGE AS FoglalhatoIdoszakVege
    ,Intezmeny.C_OMKOD AS IntezmenyOmAzonosito
    ,Terem.C_LEIRAS AS Leiras
    ,Terem.C_KAPACITAS AS Letszam
    ,Terem.C_NEV AS Megnevezes
    ,Terem.C_TERULET AS Terulet
    ,FeltoltottFajl.C_UTVONAL AS FotoPath
    ,FeltoltottSzerzodesFajl.C_UTVONAL AS SzerzodesMellekletPath
    ,TeremDictionary.ID AS TipusAzonosito
    ,TeremDictionary.C_NAME AS TipusNev
    ,Terem.C_EGYEDIAZONOSITO AS KretaEgyediAzonosito
    ,Terem.C_EMELTAR AS EmeltAr
    ,Terem.C_EMELTARKEZDETEORAPERC AS EmeltArKezdeteOraPerc
    ,TeremTulajdonosDictionary.ID AS TulajdonTipusaAzonosito
    ,TeremTulajdonosDictionary.C_NAME AS TulajdonTipusaNev
    ,MukodesiHely.C_FUNKCIOTERULET AS FunkcioTeruletSAPKod
  FROM T_TEREM_OSSZES Terem
  INNER JOIN T_INTEZMENYADATOK_OSSZES Intezmeny ON Intezmeny.C_INTEZMENYID = Terem.C_INTEZMENYID
    AND Intezmeny.TOROLT = 'F'
    AND Intezmeny.C_INTEZMENYID = Terem.C_INTEZMENYID
    AND Intezmeny.C_TANEVID = Terem.C_TANEVID
  INNER JOIN T_MUKODESIHELY_OSSZES MukodesiHely ON MukodesiHely.ID = Terem.C_MUKODESIHELYID
    AND MukodesiHely.TOROLT = 'F'
  LEFT JOIN T_DICTIONARYITEMBASE_OSSZES TeremDictionary ON TeremDictionary.ID = Terem.C_JELLEG
    AND TeremDictionary.TOROLT = 'F'
    AND TeremDictionary.C_INTEZMENYID = Intezmeny.C_INTEZMENYID
    AND TeremDictionary.C_TANEVID = Intezmeny.C_TANEVID
  LEFT JOIN T_DICTIONARYITEMBASE_OSSZES TeremTulajdonosDictionary ON TeremTulajdonosDictionary.ID = Terem.C_TULAJDONTIPUSID
    AND TeremTulajdonosDictionary.TOROLT = 'F'
    AND TeremTulajdonosDictionary.C_INTEZMENYID = Intezmeny.C_INTEZMENYID
    AND TeremTulajdonosDictionary.C_TANEVID = Intezmeny.C_TANEVID
  INNER JOIN T_TEREM_FELTOLTOTTFAJL_OSSZES TeremFeltoltottFajl ON TeremFeltoltottFajl.C_TEREMID = Terem.ID
    AND TeremFeltoltottFajl.TOROLT = 'F'
    AND TeremFeltoltottFajl.C_INTEZMENYID = Terem.C_INTEZMENYID
    AND TeremFeltoltottFajl.C_TANEVID = Terem.C_TANEVID
    AND TeremFeltoltottFajl.C_ISDOKUMENTUM = 'F'
  INNER JOIN T_FELTOLTOTTFAJL_OSSZES FeltoltottFajl ON FeltoltottFajl.ID = TeremFeltoltottFajl.C_FELTOLTOTTFAJLID
    AND FeltoltottFajl.TOROLT = 'F'
  INNER JOIN T_TEREM_FELTOLTOTTFAJL_OSSZES TeremSzerzodesFajl ON TeremSzerzodesFajl.C_TEREMID = Terem.ID
    AND TeremSzerzodesFajl.TOROLT = 'F'
    AND TeremSzerzodesFajl.C_INTEZMENYID = Terem.C_INTEZMENYID
    AND TeremSzerzodesFajl.C_TANEVID = Terem.C_TANEVID
    AND TeremSzerzodesFajl.C_ISDOKUMENTUM = 'T'
  INNER JOIN T_FELTOLTOTTFAJL_OSSZES FeltoltottSzerzodesFajl ON FeltoltottSzerzodesFajl.ID = TeremSzerzodesFajl.C_FELTOLTOTTFAJLID
    AND FeltoltottSzerzodesFajl.TOROLT = 'F'
  WHERE Terem.TOROLT = 'F'
    AND Terem.C_BERBEADHATO = 'T'
    AND Terem.C_AKTIV = 'T'
    AND Terem.C_TANEVID = @pTanevId
END
GO


