DROP PROCEDURE IF EXISTS uspGetEszkozIgenylesAlkalmazottakExportData 
GO
  CREATE PROCEDURE uspGetEszkozIgenylesAlkalmazottakExportData
      @pTanevId INT
     ,@pIsKellTovabbiMunkaugyiAdatok BIT
  AS
  BEGIN
    SET NOCOUNT ON;

    SELECT
       fh.ID AS Id
      ,fh.C_NYOMTATASINEV AS Nyomtatasinev
      ,fh.C_OKTATASIAZONOSITO AS OktatasiAznosito
      ,IIF(m.C_ALKALMAZOTTMUNKAKORTIPUSID IS NOT NULL OR (@pIsKellTovabbiMunkaugyiAdatok = 1 AND tm.C_ALKALMAZOTTMUNKAKORTIPUSID IS NOT NULL),'T','F') AS HasTanarAlkalmazottMunkakorTipus
      ,IIF(ei.ID IS NULL, 'F','T') AS HasEszkozIgenyles
      ,IIF(fb.ID IS NULL, 'F','T') AS HasBelepes
      ,IIF(fsz.C_FELHASZNALOID IS NULL,'F','T') AS HasNaploSzerepkor
      ,CASE WHEN (@pIsKellTovabbiMunkaugyiAdatok = 1 AND tma.C_MUNKAKORTIPUSA IS NOT NULL) THEN tma.C_MUNKAKORTIPUSA ELSE ma.C_MUNKAKORTIPUSA END AS MunkakorTipusaId
    FROM T_FELHASZNALO_OSSZES fh
      INNER JOIN T_ALKALMAZOTT_OSSZES a ON a.ID = fh.ID AND a.TOROLT = 'F' AND a.C_ALTANEVID = fh.C_TANEVID
      LEFT JOIN (T_MUNKAUGYIADATOK_OSSZES ma
      INNER JOIN T_MUNKAKORTIPUS_OSSZES m ON m.ID = ma.C_MUNKAKORTIPUSA AND m.TOROLT = 'F' AND m.C_ALTANEVID = ma.C_TANEVID) 
        ON ma.C_ALKALMAZOTTID = fh.ID AND ma.TOROLT = 'F' AND ma.C_TANEVID = fh.C_TANEVID AND m.C_ALKALMAZOTTMUNKAKORTIPUSID = 8384
      LEFT JOIN (T_TOVABBIMUNKAUGYIADATOK tma
      INNER JOIN T_MUNKAKORTIPUS_OSSZES tm ON tm.ID = tma.C_MUNKAKORTIPUSA AND tm.TOROLT = 'F' AND tm.C_ALTANEVID = tma.C_TANEVID)
         ON tma.C_ALKALMAZOTTID = fh.ID AND tma.TOROLT = 'F' AND tma.C_TANEVID = fh.C_TANEVID  AND tm.C_ALKALMAZOTTMUNKAKORTIPUSID = 8384
      LEFT JOIN T_ESZKOZIGENYLES_OSSZES ei ON ei.C_ALKALMAZOTTID = fh.ID AND ei.TOROLT = 'F' AND ei.C_TANEVID = fh.C_TANEVID
      LEFT JOIN T_FELHASZNALOBELEPES_OSSZES fb ON fb.C_FELHASZNALOID = fh.ID AND fb.TOROLT = 'F' AND fb.C_TANEVID = fh.C_TANEVID
      LEFT JOIN (
        T_FELHASZNALO_SZEREPKOR fsz 
        INNER JOIN T_SZEREPKOR_OSSZES szk ON szk.ID = fsz.C_SZEREPKORID AND szk.C_SZEREPKORTIPUS = 1760
        ) ON fsz.C_FELHASZNALOID = fh.ID
    WHERE fh.TOROLT = 'F' AND fh.C_TANEVID = @pTanevId
  END
GO


