DROP PROCEDURE IF EXISTS uspGetCsengetesiRendekByMukodesiHely
GO

CREATE PROCEDURE uspGetCsengetesiRendekByMukodesiHely
   @pTanevId INT
  ,@pMukodesiHelyId INT = null
  ,@pCsakAktiv BIT = 0

AS BEGIN
  SET NOCOUNT ON

  DECLARE @sql NVARCHAR(1000)

  SET @sql = N'
    SELECT T_CSENGETESIREND_OSSZES.ID ID, 
       T_CSENGETESIREND_OSSZES.C_NEV Nev
      ,T_CSENGETESIREND_OSSZES.C_AKTIV Aktiv
      ,T_CSENGETESIREND_OSSZES.C_MUKODESIHELYID MukodesiHely
      ,T_MUKODESIHELY_OSSZES.C_NEV MukodesiHelyNev 
    FROM T_CSENGETESIREND_OSSZES 
      LEFT JOIN T_MUKODESIHELY_OSSZES ON T_MUKODESIHELY_OSSZES.ID = T_CSENGETESIREND_OSSZES.C_MUKODESIHELYID 
    WHERE T_CSENGETESIREND_OSSZES.TOROLT =''F'' 
      AND T_CSENGETESIREND_OSSZES.C_TANEVID = @pTanevId' 

  IF (@pMukodesiHelyId IS NOT NULL) 
    SET @sql = @sql + ' AND T_CSENGETESIREND_OSSZES.C_MUKODESIHELYID = @pMukodesiHelyId' 

  IF (@pCsakAktiv = 1)  
    SET @sql = @sql + ' AND T_CSENGETESIREND_OSSZES.C_AKTIV = ''T'' ' 

  EXEC sys.Sp_executesql @sql, N'
     @pTanevId int
    ,@pMukodesiHelyId int
    ,@pCsakAktiv bit'
    ,@pTanevId
    ,@pMukodesiHelyId 
    ,@pCsakAktiv 

END
GO
