DROP PROCEDURE IF EXISTS uspGetAlkalmazottElsodlegesMunkaugyiAdatok
GO
  CREATE PROCEDURE uspGetAlkalmazottElsodlegesMunkaugyiAdatok
     @pId INT
    ,@pTanevId INT
  AS
  BEGIN
    SET NOCOUNT ON;

    SELECT Felhasznalo.C_SZULETESINEV AS SzuletesiNev
      ,Felhasznalo.C_ANYJANEVE AS AnyjaNeve
      ,Felhasznalo.C_SZULETESIDATUM AS SzuletesiDatum
      ,Felhasznalo.C_SZULETESIHELY AS SzuletesiHely
      ,MunkaugyiAdatok.C_ALKALMAZASKEZDETE AS AlkalmazasKezdete
      ,MunkaugyiAdatok.C_ALKALMAZASMEGSZUNESE AS AlkalmazasMegszunese
      ,FoglalkoztatasTipusDictionary.C_NAME AS FoglalkoztatasTipusa
    FROM T_FELHASZNALO_OSSZES Felhasznalo
    LEFT JOIN T_MUNKAUGYIADATOK_OSSZES MunkaugyiAdatok ON MunkaugyiAdatok.C_ALKALMAZOTTID = Felhasznalo.ID
      AND MunkaugyiAdatok.TOROLT = 'F'
      AND MunkaugyiAdatok.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND MunkaugyiAdatok.C_TANEVID = Felhasznalo.C_TANEVID
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES FoglalkoztatasTipusDictionary ON FoglalkoztatasTipusDictionary.ID = MunkaugyiAdatok.C_FOGLALKOZTATASTIPUS
      AND FoglalkoztatasTipusDictionary.TOROLT = 'F'
      AND FoglalkoztatasTipusDictionary.C_INTEZMENYID = Felhasznalo.C_INTEZMENYID
      AND FoglalkoztatasTipusDictionary.C_TANEVID = Felhasznalo.C_TANEVID
    WHERE Felhasznalo.TOROLT = 'F'
      AND Felhasznalo.C_TANEVID = @pTanevId
      AND Felhasznalo.ID = @pId
      AND EXISTS (
        SELECT 1
        FROM T_ALKALMAZOTT_OSSZES Alkalmazott
        WHERE Alkalmazott.C_ALTANEVID = Felhasznalo.C_TANEVID
          AND Alkalmazott.C_ALINTEZMENYID = Felhasznalo.C_INTEZMENYID
          AND Alkalmazott.ID = Felhasznalo.ID
          AND Alkalmazott.TOROLT = 'F'
        )
  END
GO


