DROP PROCEDURE IF EXISTS dbo.sp_GetTanulokFeljegyzesekReszletezese
GO

-- =============================================
-- Author:    Dőrr Tamás
-- Create date: 2015.12.15.
-- Description:  sp_GetTanulokFeljegyzesekReszletezese
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetTanulokFeljegyzesekReszletezese]
  @pOsztalyId    int,
  @pTanevId    int
AS
BEGIN  
  SET NOCOUNT ON;
  
  DECLARE @feladatKategoriaId int = (SELECT C_FELADATKATEGORIAID FROM T_OSZTALYCSOPORT_OSSZES WHERE ID = @pOsztalyId)

  SELECT DISTINCT 
     @pOsztalyId AS OsztalyId
    ,ocs.C_NEV AS OSZTALYCSOPORT_NEV
    ,ofo.C_NYOMTATASINEV AS OSZTFO_NEV
    ,i.C_IGAZGATONEVE AS INT_IGAZGATO_NEV
    ,i.C_NEV AS INT_NEV
    ,i.C_IRANYITOSZAM AS INT_IRSZAM
    ,i.C_VAROS AS INT_VAROS
    ,dbo.fnGetDokumentumIntezmenyCime(@pTanevId) AS INT_CIM
    ,i.C_OMKOD AS INT_OMKOD
  FROM T_OSZTALYCSOPORT_OSSZES ocs 
    INNER JOIN T_OSZTALY_OSSZES o ON ocs.ID = o.ID AND o.torolt='F'
    LEFT JOIN T_FELHASZNALO_OSSZES ofo ON ofo.ID = o.C_OSZTALYFONOKID AND ofo.TOROLT = 'F'
    INNER JOIN T_INTEZMENYADATOK_OSSZES i on i.C_INTEZMENYID=ocs.C_INTEZMENYID AND i.C_TANEVID = ocs.C_TANEVID AND i.Torolt = 'F'
  WHERE 
    ocs.ID = @pOsztalyId
  AND ocs.C_FELADATKATEGORIAID = @feladatKategoriaId

 SELECT
     Datum as KEZDET
    ,d.C_NAME AS C_TIPUS
    ,tcs.C_TANULOID AS TANULO_ID
    ,ft.C_NYOMTATASINEV AS TANULO_NEV
    ,FeljegyzoNeve AS FELJEGYZO_NEV
    ,Tartalom AS TARTALOM
    ,Megjegyzes AS MEGJEGYZES
    ,ft.C_NYOMTATASINEV + ' ' + CAST(tcs.C_TANULOID AS NVARCHAR) AS GROUPPARAMETER
    ,@pOsztalyId AS OsztalyId
    ,ft.C_OKTATASIAZONOSITO AS TanuloOktAzon
    ,esemenyek.FeljegyzoId AS FeljegyzoId
    ,ff.C_OKTATASIAZONOSITO AS FeljegyzoOktAzon
  FROM T_TANULOCSOPORT_OSSZES tcs
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = tcs.C_OSZTALYCSOPORTID AND ocs.C_FELADATKATEGORIAID = @feladatKategoriaId AND ocs.TOROLT = 'F'
    LEFT JOIN fnGetDokumentumTanulokFeljegyzesei(@pTanevId, @pOsztalyId, 0) esemenyek ON esemenyek.TanuloId = tcs.C_TANULOID AND esemenyek.Tipusa NOT IN (1534, 5482)
    LEFT JOIN T_FELHASZNALO_OSSZES ft ON ft.ID = tcs.C_TANULOID AND ft.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO_OSSZES ff ON ff.ID = esemenyek.FeljegyzoId AND ff.TOROLT = 'F'
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES d ON d.id = Tipusa AND d.C_TANEVID = ft.C_TANEVID AND d.C_INTEZMENYID = ft.C_INTEZMENYID AND d.TOROLT = 'F'
  WHERE tcs.C_OSZTALYCSOPORTID = @pOsztalyId
    AND tcs.C_TANEVID = @pTanevId
    AND tcs.TOROLT= 'F'
  ORDER BY ft.C_NYOMTATASINEV

  SELECT
     o.ID AS OsztalyId
    ,ocs.C_EVFOLYAMTIPUSA AS EvfolyamTipusa
    ,ocs.C_FELADATELLATASIHELYID AS FeladatEllatasiHelyId
    ,ocs.C_KEPZESIFORMA AS KepzesiForma
    ,o.C_OSZTALYFONOKID AS OsztalyfonokId
    ,o.C_TANTERVID AS TantervId
    ,o.C_SZAKMACSOPORT AS SzakmaCsoport
    ,o.C_AGAZAT AS Agazat
    ,o.C_SZAKKEPESITES AS Szakkepesites
    ,o.C_RESZSZAKKEPESITES AS Reszszakkepesites
    ,o.C_AGAZATUJSZKTTIPUSID AS UjSzktAgazat
    ,o.C_SZAKMATIPUSID AS UjSzktSzakma
    ,o.C_SZAKMAIRANYTIPUSID AS UjSzktSzakmairany
    ,o.C_TANULMANYITERULETNKTTIPUSID AS NktTanulmanyiTerulet
    ,o.C_SZAKKEPESITESNKTTIPUSID AS NktSzakkepesites
    ,o.C_SZAKIRANYNKTTIPUSID AS NktSzakirany
    ,ocs.C_KERESZTFELEVES AS OJCSJKeresztfeleves
    ,ocs.C_VEGZOSEVFOLYAM  AS CSJVegzosEvfolyamu
    ,ocs.C_ISTECHNIKAI  AS OJTechnikaiOsztaly
    ,o.C_NEMZETISEGI AS OJNemzetisegi
    ,o.C_KETTANNYELVU AS OJKettannyelvu
    ,o.C_NYELVIELOKESZITO  AS OJNyelviElokeszito
    ,ocs.C_ISGYOGYPEDAGOGIAILOGOPEDIAI AS OJIsGyogypedagogiaiLogopediai
    ,o.C_SPORT AS OJSportOsztaly
    ,o.C_AJPROGRAM AS OJAranyJanosProgram
  FROM T_OSZTALY_OSSZES AS o
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = o.ID AND ocs.TOROLT = 'F' AND ocs.C_FELADATKATEGORIAID = @feladatKategoriaId
  WHERE 
    o.ID = @pOsztalyId
  
  END

GO