﻿DROP PROCEDURE IF EXISTS [dbo].[sp_GetFeljegyzesBeirasokData]
GO

-- =============================================
-- Description:  <Előszedjük az osztály csoport tanulóinak feljegyzéseit a faliújság bejegyzések oldalhoz>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesBeirasokData]
   @pTanevId INT
  ,@pIntezmenyId INT
  ,@pOsztalyCsoportId INT
  ,@pStartDate DATE
  ,@pTanarId INT

AS
BEGIN

  SET NOCOUNT ON;

  SELECT DISTINCT
     TanuloEsemeny.ID AS ID
    ,TanuloEsemeny.C_ESEMENYDATUMA AS EsemenyDatuma
    ,TanuloEsemeny.C_TARGY AS Targy
    ,TanuloEsemeny.C_TARTALOM AS Tartalom
    ,TanuloEsemeny.C_TIPUS AS Tipus
    ,Tanulo.ID AS TanuloId
    ,Tanulo.C_NYOMTATASINEV AS TanuloNev
    ,IIF(Tanulo.C_NEVSORREND = 'T',            
       Tanulo.C_UTONEV + ' ' + Tanulo.C_VEZETEKNEV,
       Tanulo.C_VEZETEKNEV + ' ' + Tanulo.C_UTONEV) AS TanuloNevElotagNelkul
    ,Tanulo.C_ANYJANEVE AS AnyjaNeve
    ,Tanulo.C_SZULETESIDATUM AS SzuletesiIdo
    ,Tanar.C_NYOMTATASINEV AS FeljegyzoNeve
    ,OsztalyCsoport.C_NEV AS OsztalyNev
    ,CASE
      WHEN TanuloEsemeny.C_FELJEGYZOID = @pTanarId
        THEN 'T' 
        ELSE 'F' 
      END AS Modosithato
    ,mua.C_SZERVEZETID AS FeljegyzoSzervezetId
  FROM T_FELHASZNALO_OSSZES Tanulo
    LEFT JOIN T_TANULO_TANULOESEMENY TanuloTanuloEsemeny ON TanuloTanuloEsemeny.C_TANULOID = Tanulo.ID 
    LEFT JOIN T_TANULOESEMENY_OSSZES TanuloEsemeny ON TanuloEsemeny.ID = TanuloTanuloEsemeny.C_TANULOESEMENYID
      AND CAST(TanuloEsemeny.C_ESEMENYDATUMA AS DATE) >= @pStartDate
      AND CAST(TanuloEsemeny.C_ESEMENYDATUMA AS DATE) <= CAST(GETDATE() AS DATE)
      AND TanuloEsemeny.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO_OSSZES Tanar ON Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
      AND Tanar.TOROLT = 'F'
    LEFT JOIN T_TANULOCSOPORT_OSSZES TanuloCsoport ON TanuloCsoport.C_TANULOID = TANULO.ID 
      AND TanuloCsoport.TOROLT = 'F'
    LEFT JOIN T_OSZTALYCSOPORT_OSSZES OsztalyCsoport ON OsztalyCsoport.ID = TanuloCsoport.C_OSZTALYCSOPORTID 
      AND OsztalyCsoport.TOROLT = 'F'
    LEFT JOIN T_MUNKAUGYIADATOK_OSSZES mua ON mua.C_ALKALMAZOTTID = Tanar.ID
      AND mua.TOROLT = 'F'
  WHERE Tanulo.TOROLT = 'F'
    AND OsztalyCsoport.ID = @pOsztalyCsoportId
    AND Tanulo.C_TANEVID = @pTanevId
    AND Tanulo.C_INTEZMENYID = @pIntezmenyId
  ORDER BY 
    TanuloNevElotagNelkul

END

GO

