::
:: %RS_TOOLSBIN%\RockstarTargetManager\_connect_target_orbis.bat should not be directly modified.
::
:: This file gets automatically copied from %RS_CODEBRANCH%\rage\base\tools\ui\RockstarTargetManager\RockstarTargetManager\_connect_target_orbis.bat
:: when a new version of R*TM is released (see %RS_CODEBRANCH%\rage\base\tools\ui\RockstarTargetManager\CopyToTools.bat).
::

:: Need to add Orbis SDK bin directory to path, since the path has spaces in it, and using
:: double quotes inside of the for used for the orbis-ctrl pkill does not seem to work
set "sce_root=%SCE_ROOT_DIR%"
if "%sce_root%" == "" (
	set "sce_root=C:\Program Files (x86)\SCE"
)
set "orbis_bin_dir=%sce_root%\ORBIS\Tools\Target Manager Server\bin\"
if not exist "%orbis_bin_dir%\orbis-run.exe" (
	echo "PS4 SDK or support tools not installed as expected"
	exit 1
)
PATH=%orbis_bin_dir%;%PATH%

if not exist "%exename%.elf" (
	echo Can't find PS4 executable [%exename%.elf]
	exit 1
)

:: If target was not specified, use the default target.
if "%target_ip%" == "" (
	for /F "usebackq tokens=1" %%i in (`orbis-ctrl default`) do set target_ip=%%i
	if "!target_ip!" == "" (
		echo No default PS4 set
		exit 1
	)
)

set target_ip_bare=%target_ip%

orbis-ctrl connect %target_ip%
if errorlevel 1 (
	echo Failure connecting to target %target_ip%
	exit 1
)

:: Kill any currently running game.
call "%batch_dir%\..\..\script\util\kill_orbis_processes.bat" [%target_ip%]