-- =============================================
-- Description:	<Minden intézmény aktív tanévéből visszaadja a még ki nem küldött házifeladatokat>
-- =============================================
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

DROP PROCEDURE IF EXISTS [dbo].[uspGetAllSchemaKikuldendoHazifeladat]
GO

CREATE PROCEDURE [dbo].[uspGetAllSchemaKikuldendoHazifeladat]
AS
BEGIN
  -- SET NOCOUNT ON added to prevent extra result sets from interfering with SELECT statements.
  SET NOCOUNT ON;

  SELECT TOP(5000)
     hazi.ID
    ,intezmeny.C_AZONOSITO AS IntezmenyAzonosito
    ,tantargy.C_NEV AS TantargyNev
    ,tanulo.ID AS TanuloId
    ,felhasznalo.C_NYOMTATASINEV AS TanuloNev
  FROM T_HAZIFELADATOK hazi
    INNER JOIN T_TANEV tanev ON tanev.ID = hazi.C_TANEVID
      AND tanev.C_AKTIV = 'T'
      AND tanev.TOROLT = 'F'
    INNER JOIN T_INTEZMENY intezmeny ON intezmeny.ID = tanev.C_INTEZMENYID
      AND intezmeny.TOROLT = 'F'
    INNER JOIN T_TANTARGY tantargy ON tantargy.ID = hazi.C_TANTARGYID
      AND tantargy.TOROLT = 'F'
    INNER JOIN T_OSZTALYCSOPORT osztalycsoport ON osztalycsoport.ID = hazi.C_OSZTALYCSOPORTID
      AND osztalycsoport.TOROLT = 'F'
    INNER JOIN T_TANULOCSOPORT tanulocsoport ON tanulocsoport.C_OSZTALYCSOPORTID = osztalycsoport.ID
      AND tanulocsoport.C_BELEPESDATUM <= hazi.C_HATARIDO
      AND (tanulocsoport.C_KILEPESDATUM IS NULL OR tanulocsoport.C_KILEPESDATUM > hazi.C_HATARIDO)
      AND tanulocsoport.TOROLT = 'F'
    INNER JOIN T_TANULO tanulo ON tanulo.ID = tanulocsoport.C_TANULOID
      AND tanulo.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO felhasznalo ON felhasznalo.ID = tanulo.ID
      AND felhasznalo.TOROLT = 'F'
  WHERE hazi.TOROLT = 'F'
    AND hazi.C_ISERTESITESELKULDVE = 'F'
  ORDER BY hazi.C_FELADASDATUMA

END
GO