SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

DROP FUNCTION IF EXISTS fnGetIktatottDokumentumok
GO

CREATE FUNCTION [dbo].[fnGetIktatottDokumentumok](
	@pTanevId INT
)
RETURNS TABLE
AS  
RETURN
	SELECT
     iktd.ID
    ,iktd.C_DOKUMENTUMKATEGORIA Kategoria
    ,iktd.C_DOKUMENTUMTIPUS DokumentumTipus
    ,iktd.C_DOKUMENTUMNEVE DokumentumNeve
    ,iktd.C_FELADATELLATASIHELYID FeladatellatasihelyId
    ,CASE 
      -- Ahol működési hely van megadva feladatellátási helynek
      WHEN iktd.C_DOKUMENTUMTIPUS IN (7430) THEN 
        IIF (iktd.C_FELADATELLATASIHELYID IS NULL, '', CONCAT(igaziMukodHely.C_NEV, ' - ', DIBM.C_NAME))
      -- feladatellátási hely van megadva
      ELSE
        IIF (iktd.C_FELADATELLATASIHELYID is NULL, '', CONCAT(mukodHely.C_NEV, ' - ', DIB.C_NAME))
      END AS FeladatellatasihelyNeve
    ,iktd.C_IKTATOSZAM Iktatoszam
    ,CASE iktd.C_DOKUMENTUMSTATUSZ 
      WHEN 7387 THEN iktd.C_GENERALASDATUMA
      WHEN 7388 THEN iktd.C_IKTATASDATUMA
      ELSE iktd.C_ELEKTRONIKUSPELDANYFELTOLTES
      END IktatasDatuma
    ,felhasznalo.C_NYOMTATASINEV IktatoSzemelye
    ,iktd.C_DOKUMENTUMSTATUSZ Statusz
    ,tanev.C_NEV TanevNev
    ,iktd.C_ELEKTRONIKUSPELDANYID ElektronikusPeldanyId
    ,iktd.C_FOSZAMOSIKTATOTTDOKUMENTUMID FoszamosDokumentumId
    ,iktd.C_ISFOSZAMOS IsFoszamos
    ,iktd.TOROLT Torolt
  FROM T_IKTATOTTDOKUMENTUM_OSSZES iktd
    LEFT JOIN T_TANEV_OSSZES tanev ON tanev.ID = iktd.C_TANEVID and tanev.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO_OSSZES felhasznalo ON felhasznalo.ID = iktd.C_IKTATOSZEMELYID and felhasznalo.TOROLT = 'F'
    LEFT JOIN T_FELADATELLATASIHELY_OSSZES feh ON feh.ID = iktd.C_FELADATELLATASIHELYID and feh.TOROLT = 'F' 
    LEFT JOIN T_MUKODESIHELY_OSSZES mukodHely ON feh.C_MUKODESIHELYID = mukodHely.ID and mukodHely.TOROLT = 'F'
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES DIB ON feh.C_OKTATASINEVELESIFELADATTIPUS = DIB.ID
      AND feh.C_INTEZMENYID = DIB.C_INTEZMENYID
      AND feh.C_TANEVID = DIB.C_TANEVID 
      AND DIB.TOROLT = 'F'
    LEFT JOIN T_MUKODESIHELY_OSSZES igaziMukodHely ON iktd.C_FELADATELLATASIHELYID = igaziMukodHely.ID and igaziMukodHely.TOROLT = 'F'
    LEFT JOIN T_FELADATELLATASIHELY_OSSZES igaziFeh ON igaziFeh.C_MUKODESIHELYID = igaziMukodHely.ID and igaziFeh.TOROLT = 'F'
    LEFT JOIN T_DICTIONARYITEMBASE_OSSZES DIBM ON igaziFeh.C_OKTATASINEVELESIFELADATTIPUS = DIBM.ID
      AND igaziFeh.C_INTEZMENYID = DIBM.C_INTEZMENYID
      AND igaziFeh.C_TANEVID = DIBM.C_TANEVID 
      AND DIBM.TOROLT = 'F'
	WHERE iktd.C_TANEVID = @pTanevId 
GO