-- =============================================
-- Description:  <Előszedjük a szamonkeres elorejelzeseket a megadott paraméterek alapján>
-- =============================================
DROP PROCEDURE IF EXISTS uspGetSzamonkeresElorejelzesekByDateRange
GO

CREATE PROCEDURE uspGetSzamonkeresElorejelzesekByDateRange 
   @pIntezmenyId int
  ,@pTanevId int
  ,@pDatumTol datetime = NULL
  ,@pDatumIg datetime = NULL
AS BEGIN
  SET NOCOUNT ON;

  CREATE TABLE #NaptariNap (
     Datum datetime
    ,OsztalyCsoportId int
    ,IsEgyediNap char(1) COLLATE database_default
    ,PRIMARY KEY (Datum, OsztalyCsoportId)
  )

  INSERT INTO #NaptariNap (
     Datum
    ,OsztalyCsoportId
    ,IsEgyediNap
  )
  SELECT
     tr.Datum AS Datum
    ,tr.OsztalyId AS OsztalyId
    ,ISNULL(tro.IsEgyediNap, tr.IsEgyediNap) AS IsEgyediNap
  FROM (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,ocs.ID AS OsztalyId
      ,'F' AS IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
      INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.C_TANEVID = @pTanevId
    WHERE nn.C_TANEVID = @pTanevId
      AND nn.TOROLT = 'F'
      AND nn.C_ORARENDINAP = 'T'
  ) tr
  LEFT JOIN (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,ocstr.C_OSZTALYCSOPORTID AS OsztalyId
      ,tr.C_EGYEDINAP AS IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
      INNER JOIN T_TANEVRENDJE_OSSZES tr ON tr.C_DATUM = nn.C_NAPDATUMA 
        AND tr.C_OSSZESCSOPORTRAVONATKOZIK = 'F' 
        AND tr.TOROLT = 'F'
      INNER JOIN T_OSZTALYCSOPORT_TANEVRENDJE ocstr ON ocstr.C_TANEVRENDJEID = tr.ID
      INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = ocstr.C_OSZTALYCSOPORTID
      INNER JOIN T_NAPTIPUS_OSSZES nt ON nt.ID = tr.C_NAPTIPUSA 
        AND nt.C_ALTANEVID = tr.C_TANEVID 
        AND nt.TOROLT = 'F'
    WHERE nn.C_TANEVID = @pTanevId
      AND nn.TOROLT = 'F'
      AND tr.C_ORARENDINAP = 'T'
  ) tro ON tr.Datum = tro.Datum
    AND tr.OsztalyId = tro.OsztalyId

  SELECT
     sze.ID AS ID
    ,oo.C_ORASZAM AS Oraszam
    ,targy.C_NEV AS Tantargy
    ,ISNULL(helyettestanar.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV) AS Tanar
    ,dib.C_NAME AS SzamonkeresMod
    ,sze.C_SZAMONKERESMODID AS SzamonkeresModId
    ,rogzito.C_NYOMTATASINEV AS RogzitoTanar
    ,sze.C_ROGZITOID AS RogzitoId
    ,ocs.C_NEV AS Osztaly
    ,sze.C_ROGZITESDATUMA AS RogzitesDatum
    ,sze.C_SZAMONKERESDATUMA AS SzamonkeresDatum
    ,sze.C_ORARENDIORAGROUPID AS GroupId
  FROM T_SZAMONKERESELOREJELZES sze
    INNER JOIN T_ORARENDIORA oo ON oo.C_ORARENDIORAGROUPID = sze.C_ORARENDIORAGROUPID 
      AND sze.C_SZAMONKERESDATUMA BETWEEN oo.C_ORAERVENYESSEGKEZDETE 
      AND oo.C_ORAERVENYESSEGVEGE 
      AND oo.TOROLT = 'F'
    INNER JOIN #NaptariNap nn ON nn.IsEgyediNap = oo.C_EGYEDINAP 
      AND nn.OsztalyCsoportId = oo.C_OSZTALYCSOPORTID 
      AND nn.Datum = sze.C_SZAMONKERESDATUMA
    INNER JOIN T_TANTARGY targy ON targy.ID = oo.C_TANTARGYID 
      AND targy.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO tanar ON tanar.ID = oo.C_TANARID 
      AND tanar.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO rogzito ON rogzito.ID = sze.C_ROGZITOID 
      AND rogzito.TOROLT = 'F'
    INNER JOIN T_OSZTALYCSOPORT ocs ON ocs.ID = oo.C_OSZTALYCSOPORTID 
      AND ocs.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE dib ON dib.ID = sze.C_SZAMONKERESMODID 
      AND dib.C_INTEZMENYID = sze.C_INTEZMENYID 
      AND dib.C_TANEVID = sze.C_TANEVID 
      AND dib.C_TYPE = 'ErtekelesMod'
    LEFT JOIN T_HELYETTESITESIIDOSZAK helyettes ON helyettes.C_HELYETTESITETTORARENDID = oo.ID 
      AND helyettes.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO helyettestanar ON helyettestanar.ID = helyettes.C_HELYETTESTANAROKID 
    AND helyettestanar.TOROLT = 'F'
  WHERE sze.C_SZAMONKERESDATUMA BETWEEN @pDatumtol AND @pDatumig 
    AND sze.C_INTEZMENYID = @pIntezmenyId 
    AND sze.C_TANEVID = @pTanevId

END
GO