-- =============================================
-- Description:  <Előszedjük a tanuló értékeléseket a megadott paraméterek alapján>
-- =============================================
DROP PROCEDURE IF EXISTS uspGetSzamonkeresElorejelzesDetailDataSet
GO

CREATE PROCEDURE uspGetSzamonkeresElorejelzesDetailDataSet
   @IntezmenyId int
  ,@TanevId int
  ,@pDatum datetime
  ,@pOraGroupId int 
  ,@pOsztalyCsoportId int
  
AS
BEGIN
  
  CREATE TABLE #OsztalyCsoport (Id int PRIMARY KEY)
  
  INSERT INTO  #OsztalyCsoport (Id)
  SELECT ID
  FROM  dbo.fnGetKapcsolodoOsztalycsoportokByDate (@pOsztalyCsoportId, @pDatum, @pDatum, DEFAULT)

  CREATE TABLE #Tanulo (Id int PRIMARY KEY)

  INSERT INTO  #Tanulo (Id)
  SELECT tcs.C_TANULOID 
  FROM T_TANULOCSOPORT tcs
  WHERE tcs.C_OSZTALYCSOPORTID = @pOsztalyCsoportId AND (tcs.C_BELEPESDATUM <= @pDatum AND (tcs.C_KILEPESDATUM > @pDatum OR tcs.C_KILEPESDATUM IS NULL)) 

  CREATE TABLE #Szamonkeresek (SzamonkeresId int PRIMARY KEY, OsztalyCsoportId int, Letszam int, ErintettTanulokSzama int)

  
  CREATE TABLE #NaptariNap (
     Datum datetime
    ,OsztalyCsoportId int
    ,IsEgyediNap char(1) COLLATE database_default
    ,PRIMARY KEY (Datum, OsztalyCsoportId)
  )
  INSERT INTO #NaptariNap
  SELECT
     tr.Datum
    ,tr.OsztalyId
    ,ISNULL(tro.IsEgyediNap, tr.IsEgyediNap) AS IsEgyediNap
  FROM (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,ocs.ID AS OsztalyId
      ,'F' as IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
      INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.C_TANEVID = @TanevId AND ocs.C_FELADATKATEGORIAID = 7553 /*OktNevelesiKategoriaEnum.Alapkepzes*/
    WHERE nn.C_TANEVID = @TanevId
      AND nn.TOROLT = 'F'
	  AND nn.C_ORARENDINAP = 'T'
  ) tr
  LEFT JOIN (
    SELECT
       nn.C_NAPDATUMA AS Datum
      ,ocstr.C_OSZTALYCSOPORTID AS OsztalyId 
      ,tr.C_EGYEDINAP AS IsEgyediNap
    FROM T_NAPTARINAP_OSSZES nn
      INNER JOIN T_TANEVRENDJE_OSSZES tr ON tr.C_DATUM = nn.C_NAPDATUMA AND tr.C_OSSZESCSOPORTRAVONATKOZIK = 'F' AND tr.TOROLT = 'F'
      INNER JOIN T_OSZTALYCSOPORT_TANEVRENDJE ocstr ON ocstr.C_TANEVRENDJEID = tr.ID
      INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = ocstr.C_OSZTALYCSOPORTID AND ocs.C_FELADATKATEGORIAID = 7553 /*OktNevelesiKategoriaEnum.Alapkepzes*/
      INNER JOIN T_NAPTIPUS_OSSZES nt ON nt.ID = tr.C_NAPTIPUSA AND nt.C_ALTANEVID = tr.C_TANEVID AND nt.TOROLT = 'F'
    WHERE nn.C_TANEVID = @TanevId
      AND nn.TOROLT = 'F'
	  AND tr.C_ORARENDINAP = 'T'
  ) tro ON tr.Datum = tro.Datum AND tr.OsztalyId = tro.OsztalyId


  INSERT INTO #Szamonkeresek (SzamonkeresId, OsztalyCsoportId, Letszam, ErintettTanulokSzama)
  SELECT szk.ID AS SzamonkeresId, ocs.Id AS OsztalyCsoportId, COUNT(1) AS Letszam, COUNT(t.id) AS ErintettTanulokSzama 
  FROM T_SZAMONKERESELOREJELZES szk
    INNER JOIN T_ORARENDIORA oo ON oo.C_ORARENDIORAGROUPID = szk.C_ORARENDIORAGROUPID AND szk.C_SZAMONKERESDATUMA >= oo.C_ORAERVENYESSEGKEZDETE AND szk.C_SZAMONKERESDATUMA <= oo.C_ORAERVENYESSEGVEGE AND oo.TOROLT = 'F'
	INNER JOIN #NaptariNap nn ON nn.IsEgyediNap = oo.C_EGYEDINAP AND nn.OsztalyCsoportId = oo.C_OSZTALYCSOPORTID AND nn.Datum = szk.C_SZAMONKERESDATUMA 
    INNER JOIN #OsztalyCsoport ocs ON ocs.Id = oo.C_OSZTALYCSOPORTID
    INNER JOIN T_TANULOCSOPORT tcs ON tcs.C_OSZTALYCSOPORTID = oo.C_OSZTALYCSOPORTID AND (tcs.C_BELEPESDATUM <= @pDatum AND (tcs.C_KILEPESDATUM > @pDatum OR tcs.C_KILEPESDATUM IS NULL)) 
    LEFT  JOIN #Tanulo t ON t.id = tcs.C_TANULOID
  WHERE szk.C_SZAMONKERESDATUMA = @pDatum  /* + szűrés*/
  GROUP BY szk.ID, ocs.Id

  SELECT 
	   sze.ID AS ID
	  ,oo.C_ORASZAM as Oraszam
	  ,targy.C_NEV as Tantargy
	  ,ISNULL(helyettestanar.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV) as Tanar
	  ,dib.C_NAME as SzamonkeresMod
	  ,rogzito.C_NYOMTATASINEV as RogzitoTanar
	  ,ocs.C_NEV as Osztaly
	  ,sze.C_ROGZITESDATUMA as RogzitesDatum
	  ,sze.C_SZAMONKERESMEGNEVEZES as SzamonkeresMegnevezes
	  ,sze.C_SZAMONKERESDATUMA as SzamonkeresDatum
	  ,CAST(temp.ErintettTanulokSzama AS nvarchar(20)) + ' / '+ CAST(temp.Letszam AS nvarchar(20)) + ' tanuló' as TanulokSzama
	  ,IIF(@pOraGroupId = sze.C_ORARENDIORAGROUPID, 'T', 'F') as Torolheto
	FROM #Szamonkeresek temp
    INNER JOIN T_SZAMONKERESELOREJELZES sze ON sze.ID = temp.SzamonkeresId  
    INNER JOIN T_ORARENDIORA oo ON oo.C_ORARENDIORAGROUPID = sze.C_ORARENDIORAGROUPID AND sze.C_SZAMONKERESDATUMA between oo.C_ORAERVENYESSEGKEZDETE AND oo.C_ORAERVENYESSEGVEGE AND oo.TOROLT = 'F'
	INNER JOIN #NaptariNap nn ON nn.IsEgyediNap = oo.C_EGYEDINAP AND nn.OsztalyCsoportId = oo.C_OSZTALYCSOPORTID AND nn.Datum = sze.C_SZAMONKERESDATUMA 
    INNER JOIN T_TANTARGY targy ON targy.ID = oo.C_TANTARGYID AND targy.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO tanar ON tanar.ID = oo.C_TANARID AND tanar.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO rogzito ON rogzito.ID = sze.C_ROGZITOID AND rogzito.TOROLT = 'F'
    INNER JOIN T_OSZTALYCSOPORT ocs ON ocs.ID = oo.C_OSZTALYCSOPORTID AND ocs.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE dib ON dib.ID = sze.C_SZAMONKERESMODID AND dib.C_INTEZMENYID = sze.C_INTEZMENYID AND dib.C_TANEVID = sze.C_TANEVID AND dib.C_TYPE = 'ErtekelesMod'
    LEFT JOIN T_HELYETTESITESIIDOSZAK helyettes ON helyettes.C_HELYETTESITETTORARENDID = oo.ID AND helyettes.C_HELYETTESITESNAPJA = sze.C_SZAMONKERESDATUMA AND helyettes.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO helyettestanar ON helyettestanar.ID = helyettes.C_HELYETTESTANAROKID AND helyettestanar.TOROLT = 'F'
	WHERE sze.C_SZAMONKERESDATUMA = @pDatum AND sze.C_INTEZMENYID = @IntezmenyId AND sze.C_TANEVID = @TanevId
END
GO