DROP PROCEDURE IF EXISTS dbo.[sp_GetTanulokJelenletiIvAlkalmankent]
GO

CREATE PROCEDURE dbo.[sp_GetTanulokJelenletiIvAlkalmankent]
	@foglalkozasId		INT,
	@tanevId			INT,
	@kivalasztottNap	DATE
AS
BEGIN
	SET NOCOUNT ON;
	
	SELECT 
		 OsztalyCsoport.C_NEV + ' - ' + Tantargy.C_NEV + ' - ' + Felhasznalo.C_NYOMTATASINEV				Foglalkozas
		,Tantargy.C_NEV					Tantargy 
		,Felhasznalo.C_NYOMTATASINEV	Tanar
		,IntezmenyAdatok.C_NEV			Intezmeny
		,IntezmenyAdatok.C_VAROS		Varos
	FROM T_FOGLALKOZAS_OSSZES Foglalkozas
		INNER JOIN T_FELHASZNALO_OSSZES Felhasznalo ON Felhasznalo.id = Foglalkozas.C_TANARID
		INNER JOIN T_INTEZMENYADATOK_OSSZES IntezmenyAdatok ON IntezmenyAdatok.C_INTEZMENYID = Foglalkozas.C_INTEZMENYID AND IntezmenyAdatok.C_TANEVID = @tanevId
		INNER JOIN T_TANTARGY_OSSZES Tantargy ON Tantargy.ID = Foglalkozas.C_TANTARGYID
		INNER JOIN T_OSZTALYCSOPORT_OSSZES OsztalyCsoport ON OsztalyCsoport.ID = Foglalkozas.C_OSZTALYCSOPORTID
	WHERE 
		Foglalkozas.id = @foglalkozasId

	SELECT 
		Felhasznalo.C_OKTATASIAZONOSITO		OktAzon,
		Felhasznalo.C_NYOMTATASINEV			NEV
	FROM T_FELHASZNALO_OSSZES Felhasznalo
		INNER JOIN T_TANULOCSOPORT_OSSZES TanuloCsoport ON Felhasznalo.ID = TanuloCsoport.C_TANULOID AND TanuloCsoport.TOROLT = 'F'
		INNER JOIN T_FOGLALKOZAS_OSSZES Foglalkozas ON Foglalkozas.C_OSZTALYCSOPORTID = TanuloCsoport.C_OSZTALYCSOPORTID
	WHERE 
		Foglalkozas.ID = @foglalkozasId
		AND (
				(@kivalasztottNap >= TanuloCsoport.C_BELEPESDATUM AND @kivalasztottNap <= TanuloCsoport.C_KILEPESDATUM) 
				OR 
				(@kivalasztottNap >= TanuloCsoport.C_BELEPESDATUM AND TanuloCsoport.C_KILEPESDATUM IS NULL)
			)
	ORDER BY C_NYOMTATASINEV

END