SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetIskolalatogatasiIgazolas]') IS NOT NULL 
BEGIN
  DROP PROCEDURE [dbo].[sp_GetIskolalatogatasiIgazolas]
END  
GO

CREATE PROCEDURE [dbo].[sp_GetIskolalatogatasiIgazolas]
	@osztalyId	INT,
	@TanevId	INT,
	@pTanuloId  INT,
	@isJogviszony BIT = 0
AS
BEGIN

	SET NOCOUNT ON;

    -- fejléc
	SELECT 
		IntezmenyAdatok.C_NEV			IntezmenyNeve
		,IntezmenyAdatok.C_IGAZGATONEVE	IGAZGATONEVE
		,IntezmenyAdatok.C_VAROS		IntezmenyVaros
		,dbo.fnGetDokumentumIntezmenyCime(@tanevId) IntezmenyCime
		,C_OSZTALYFONOKID				PartnerID
		,KepzesTipus.C_NAME				KepzesForma
		,Tanev.C_NEV					TANEV
		,ocs.C_NEV Osztaly
		,@osztalyId OsztalyId
		,ocs.C_EVFOLYAMTIPUSA EvfolyamTipusa
		,ocs.C_FELADATELLATASIHELYID FeladatEllatasiHelyId
		,Osztaly.C_KEPZESIFORMA KepzesiForma
		,Osztaly.C_OSZTALYFONOKID OsztalyFonokId
		,Osztaly.C_TANTERVID TantervId
		,ocs.C_KERESZTFELEVES OJCSJKeresztfeleves
		,Osztaly.C_TECHNIKAIOSZTALY OJTechnikaiOsztaly
		,Osztaly.C_NEMZETISEGI OJNemzetisegi
		,Osztaly.C_KETTANNYELVU OJKettannyelvu
		,Osztaly.C_NYELVIELOKESZITO OJNyelviElokeszito
		,Osztaly.C_LOGOPEDIAI OJLogopediai
		,Osztaly.C_SPORT OJSportOsztaly
		,Osztaly.C_AJPROGRAM OJAranyJanosProgram
		,Osztaly.C_GYOGYPEDAGOGIAI OJGyogypedagogiai
		,Osztaly.C_SZAKMACSOPORT SzakmaCsoport
		,Osztaly.C_AGAZAT Agazat
		,Osztaly.C_SZAKKEPESITES Szakkepesites
		,Osztaly.C_RESZSZAKKEPESITES Reszszakkepesites
	FROM T_INTEZMENYADATOK_OSSZES IntezmenyAdatok
			INNER JOIN T_TANEV_OSSZES Tanev ON Tanev.ID = IntezmenyAdatok.C_TANEVID AND Tanev.TOROLT = 'F'
			INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = @osztalyId
			INNER JOIN T_OSZTALY_OSSZES Osztaly ON Osztaly.C_ALTANEVID = Tanev.ID AND Osztaly.ID = @osztalyId
			INNER JOIN T_DICTIONARYITEMBASE_OSSZES KepzesTipus ON KepzesTipus.ID = Osztaly.C_KEPZESIFORMA AND KepzesTipus.C_TANEVID = @TanevId
	WHERE 
		 IntezmenyAdatok.TOROLT = 'F'
		 AND Tanev.ID = @TanevId
	
	-- tanulók
	IF (@isJogviszony = 0)
		SELECT 
			Tanulo.C_NYOMTATASINEV		TanuloNev
			,Tanulo.C_OKTATASIAZONOSITO	OktatasiAzonosito
			,Tanulo.C_SZULETESIDATUM	SzuletesiIdo
			,Tanulo.C_SZULETESIHELY		SzuletesiHely
			,Tanulo.C_ANYJANEVE			AnyjaNeve
			,NULL	JogviszonyKezdete
			,NULL	JogviszonyVarhatoBefejezese
		FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@TanevId, @osztalyId, 'T') s
			INNER JOIN T_FELHASZNALO_OSSZES Tanulo ON Tanulo.Id = s.TanuloId
	  WHERE s.TanuloId = @pTanuloId
		ORDER BY Tanulo.C_NYOMTATASINEV    
	ELSE
		SELECT 
			Tanulo.C_NYOMTATASINEV		TanuloNev
			,Tanulo.C_OKTATASIAZONOSITO	OktatasiAzonosito
			,Tanulo.C_SZULETESIDATUM	SzuletesiIdo
			,Tanulo.C_SZULETESIHELY		SzuletesiHely
			,Tanulo.C_ANYJANEVE			AnyjaNeve
			,Tanulo.C_NYILVANTARTASKEZDETE	JogviszonyKezdete
			,TanuloOsszes.C_JOGVISZONYVARHATOBEFEJEZESE	JogviszonyVarhatoBefejezese
		FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@TanevId, @osztalyId, 'T') s
			INNER JOIN T_FELHASZNALO_OSSZES Tanulo ON Tanulo.Id = s.TanuloId
			INNER JOIN T_TANULO_OSSZES TanuloOsszes ON TanuloOsszes.ID = s.TanuloId
	  WHERE s.TanuloId = @pTanuloId
		ORDER BY Tanulo.C_NYOMTATASINEV    
	
END

GO