-- =============================================
-- Description:	<Előszedjük a tanuló alap adatait>
-- =============================================
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO


IF OBJECT_ID('[dbo].[sp_GetTanuloiAlapadatok]') IS NOT NULL
BEGIN
	DROP PROCEDURE [dbo].[sp_GetTanuloiAlapadatok]
END
GO


CREATE PROCEDURE [dbo].[sp_GetTanuloiAlapadatok]
	 @pTanuloId		INT
	,@pTanevId		INT
	,@pIntezmenyId	INT
AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from interfering with SELECT statements.
	SET NOCOUNT ON;

	--Tanuló aktuális osztályának ID-je /*TODO:Tobb Osztaly*//*OM-1605*/
	DECLARE @osztalyId INT
	SELECT TOP 1
		@osztalyId = OsztalyCsoport.ID
	FROM
		T_TANULOCSOPORT_OSSZES TanuloCsoport
	INNER JOIN
		T_OSZTALY_OSSZES Osztaly ON
			TanuloCsoport.C_OSZTALYCSOPORTID = Osztaly.ID
	INNER JOIN
		T_OSZTALYCSOPORT_OSSZES OsztalyCsoport ON
			OsztalyCsoport.ID = Osztaly.ID
            AND OsztalyCsoport.C_FELADATKATEGORIAID = (select C_DEFAULTFELADATKATEGORIAID from T_TANEV_OSSZES where ID = OsztalyCsoport.C_TANEVID)
	WHERE
			C_TANULOID = @pTanuloId
		AND TanuloCsoport.TOROLT = 'F'
		AND C_BELEPESDATUM < GETDATE() 
		AND (C_KILEPESDATUM IS NULL OR C_KILEPESDATUM > GETDATE())

	--NOTE: 0. tábla - Alapadatok
	SELECT
		 Felhasznalo.C_OKTATASIAZONOSITO	OktatasiAzonosito
		,Felhasznalo.C_ANYJANEVE			AnyjaNeve
		,ISNULL(TanuloCsoport.C_TORZSLAPSZAM,'')		Torzslapszam
		,ISNULL(TanuloCsoport.C_NAPLOSORSZAM,'')		Naplosorszam
	FROM
		T_TANULO_OSSZES Tanulo
	INNER JOIN
		T_FELHASZNALO_OSSZES Felhasznalo ON
				Felhasznalo.ID = Tanulo.ID
			AND Felhasznalo.C_INTEZMENYID = @pIntezmenyId
			AND Felhasznalo.C_TANEVID = @pTanevId
			AND Felhasznalo.TOROLT = 'F'
	LEFT JOIN
		T_TANULOCSOPORT_OSSZES TanuloCsoport ON
				TanuloCsoport.C_TANULOID = Tanulo.ID
			AND TanuloCsoport.C_OSZTALYCSOPORTID =  @osztalyId
			AND TanuloCsoport.C_INTEZMENYID = @pIntezmenyId
			AND TanuloCsoport.C_TANEVID = @pTanevId
			AND TanuloCsoport.TOROLT = 'F'
	WHERE
			Tanulo.ID = @pTanuloId
		AND Tanulo.TOROLT = 'F'

	--NOTE: 1. tábla - Címek
	SELECT
		 Cim.C_IRANYITOSZAM + ', ' +		--
		 Cim.C_VAROS + ', ' +				--
		 Cim.C_KOZTERULET + ' ' +			--
		 KozteruletJelleg.C_NAME + ' ' +	--
		 ISNULL(Cim.C_HAZSZAM, '')			CimText
		,CimTipus.C_NAME					CimTipus
		,Cim.C_CIMTIPUSA					CimTipusId
	FROM
		T_CIM_OSSZES Cim
	INNER JOIN
		T_DICTIONARYITEMBASE_OSSZES KozteruletJelleg ON
				KozteruletJelleg.ID = Cim.C_KOZTERULETJELLEGE
			AND KozteruletJelleg.C_INTEZMENYID = @pIntezmenyId
			AND KozteruletJelleg.C_TANEVID = @pTanevId
			AND KozteruletJelleg.TOROLT = 'F'
	INNER JOIN
		T_DICTIONARYITEMBASE_OSSZES CimTipus ON 
				CimTipus.ID = Cim.C_CIMTIPUSA
			AND CimTipus.C_INTEZMENYID = @pIntezmenyId
			AND CimTipus.C_TANEVID = @pTanevId
			AND CimTipus.TOROLT = 'F'
	WHERE
			Cim.C_FELHASZNALOID = @pTanuloId
		AND Cim.C_GONDVISELOID IS NULL
		AND Cim.C_INTEZMENYID = @pIntezmenyId
		AND Cim.C_TANEVID = @pTanevId
		AND Cim.TOROLT = 'F'

	--NOTE: 2. tábla - Email címek
	SELECT
		Email.C_EMAILCIM					EmailCim
	FROM
		T_EMAIL_OSSZES Email
	WHERE
			Email.C_FELHASZNALOID = @pTanuloId
		AND Email.C_INTEZMENYID = @pIntezmenyId
		AND Email.C_TANEVID = @pTanevId
		AND Email.TOROLT = 'F'

	--NOTE: 3. tábla - Telefonszámok
	SELECT
		Telefon.C_TELEFONSZAM				Telefonszam
	FROM
		T_TELEFON_OSSZES Telefon
	WHERE
			Telefon.C_FELHASZNALOID = @pTanuloId
		AND Telefon.C_INTEZMENYID = @pIntezmenyId
		AND Telefon.C_TANEVID = @pTanevId
		AND Telefon.TOROLT = 'F'
	
END
GO