SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetTanuloErtekelesMondatbankData]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetTanuloErtekelesMondatbankData]
END
GO	

-- =============================================
-- Description:	<Előszedjük az intézmény értékelés mondatbank adatait a bemenő paraméterek alapján>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetTanuloErtekelesMondatbankData]
	 @pIntezmenyId						INT
	,@pTanevId							INT
	,@pTanuloErtekelesTipusId			INT = NULL
	,@pEvfolyamTipusId					INT = NULL
	,@pTantargyId						INT = NULL
	,@pEvfolyamTipusNaId				INT
	,@pTipusId							INT = NULL
AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT
		 TanuloErtekelesMondatbank.ID					ID
		,TanuloErtekelesMondatbank.C_ROVIDNEV			RovidNev
		,TanuloErtekelesMondatbank.C_SZOVEG				Szoveg
		,TanuloErtekelesMondatbank.C_ERTEKELESTIPUSA	TanuloErtekelesTipusId
		,TanuloErtekelesMondatbank.C_EVFOLYAMTIPUSA		EvfolyamTipusId
		,TanuloErtekelesMondatbank.C_TIPUSID			TipusId
		,CASE											--
			 WHEN TanuloErtekelesMondatbank.C_TIPUSID = 7358 THEN 'Magatartás'
			 WHEN TanuloErtekelesMondatbank.C_TIPUSID = 7359 THEN 'Szorgalom'
			 ELSE IIF(TanuloErtekelesMondatbank.C_TANTARGYID IS NULL, 'Mind', Tantargy.C_NEV)
		 END  											TantargyNev
	FROM 
		T_ERTEKELESMONDATBANK_OSSZES TanuloErtekelesMondatbank
	LEFT JOIN
		T_TANTARGY_OSSZES Tantargy ON
				Tantargy.ID = TanuloErtekelesMondatbank.C_TANTARGYID
			AND Tantargy.C_INTEZMENYID = @pIntezmenyId
			AND Tantargy.C_TANEVID = @pTanevId
			AND Tantargy.TOROLT = 'F'
	WHERE
			(@pTanuloErtekelesTipusId IS NULL OR TanuloErtekelesMondatbank.C_ERTEKELESTIPUSA IS NULL OR TanuloErtekelesMondatbank.C_ERTEKELESTIPUSA = @pTanuloErtekelesTipusId)
		AND	(@pEvfolyamTipusId IS NULL OR @pEvfolyamTipusId = @pEvfolyamTipusNaId OR TanuloErtekelesMondatbank.C_EVFOLYAMTIPUSA IS NULL OR TanuloErtekelesMondatbank.C_EVFOLYAMTIPUSA = @pEvfolyamTipusId)
		AND	(@pTantargyId IS NULL OR TanuloErtekelesMondatbank.C_TANTARGYID IS NULL OR TanuloErtekelesMondatbank.C_TANTARGYID = @pTantargyId)
		AND	(@pTipusId IS NULL OR TanuloErtekelesMondatbank.C_TIPUSID = @pTipusId OR (@pTipusId IS NOT NULL AND TanuloErtekelesMondatbank.C_TIPUSID = 7357 AND TanuloErtekelesMondatbank.C_TANTARGYID IS NULL))
		AND	TanuloErtekelesMondatbank.C_INTEZMENYID = @pIntezmenyId
		AND TanuloErtekelesMondatbank.C_TANEVID = @pTanevId
		AND TanuloErtekelesMondatbank.TOROLT = 'F'

END


GO