-- =============================================
-- Author: Szekeres András
-- Create date:  2018.04.24.
-- Description:  Egy tanuló címeinek frissítése a következõ tanévre
-- =============================================

IF OBJECT_ID('sp_FollowUpTanuloCim') IS NOT NULL BEGIN
  DROP PROCEDURE sp_FollowUpTanuloCim
END;
GO

CREATE PROCEDURE sp_FollowUpTanuloCim
  @intezmenyId int,
  @aktTanevId int,
  @kovTanevId int,
  @tanuloId int
AS
BEGIN

  DECLARE @kovTanuloId int;
  
  SELECT @kovTanuloId = kovTanevesTanulo.ID
  FROM T_FELHASZNALO_OSSZES aktTanevesTanulo
    INNER JOIN T_FELHASZNALO_OSSZES kovTanevesTanulo ON aktTanevesTanulo.C_OKTATASIAZONOSITO = kovTanevesTanulo.C_OKTATASIAZONOSITO AND kovTanevesTanulo.C_TANEVID = @kovTanevId AND kovTanevesTanulo.C_INTEZMENYID = @intezmenyId
  WHERE aktTanevesTanulo.ID = @tanuloId
    AND aktTanevesTanulo.C_INTEZMENYID = @intezmenyId
    AND aktTanevesTanulo.C_TANEVID = @aktTanevId
    AND kovTanevesTanulo.TOROLT = 'F'
    AND aktTanevesTanulo.TOROLT = 'F'; --kell? elv olyat nem módosíthat, aki törölt

  IF @kovTanuloId IS NOT NULL BEGIN
    DELETE FROM T_CIM_OSSZES
    WHERE C_FELHASZNALOID = @kovTanuloId
      AND C_GONDVISELOID IS NULL
      AND C_INTEZMENYID = @intezmenyId
      AND C_TANEVID = @kovTanevId;

    INSERT INTO T_CIM_OSSZES (
       C_CIMTIPUSA
      ,C_ORSZAG
      ,C_IRANYITOSZAM
      ,C_VAROS
      ,C_MEGYE
      ,C_KOZTERULET
      ,C_KOZTERULETJELLEGE
      ,C_HAZSZAM
      ,C_EPULET
      ,C_LEPCSOHAZ
      ,C_EMELET
      ,C_AJTO
      ,C_OSSZETETTCIM
      ,C_ALAPERTELMEZETT
      ,C_FELHASZNALOID
      ,C_GONDVISELOID
      ,C_INTEZMENYID
      ,C_TANEVID
      ,TOROLT
      ,SERIAL
      ,LASTCHANGED
      ,CREATED
      ,MODIFIER
      ,CREATOR
      ,NNID
      ,GID
      ,ELOZOTANEVIREKORDID
    ) SELECT
       C_CIMTIPUSA
      ,C_ORSZAG
      ,C_IRANYITOSZAM
      ,C_VAROS
      ,C_MEGYE
      ,C_KOZTERULET
      ,C_KOZTERULETJELLEGE
      ,C_HAZSZAM
      ,C_EPULET
      ,C_LEPCSOHAZ
      ,C_EMELET
      ,C_AJTO
      ,C_OSSZETETTCIM
      ,C_ALAPERTELMEZETT
      ,@kovTanuloId
      ,C_GONDVISELOID
      ,C_INTEZMENYID
      ,@kovTanevId
      ,TOROLT
      ,0
      ,GETDATE()
      ,GETDATE()
      ,MODIFIER
      ,MODIFIER
      ,NULL
      ,GID
      ,ID
    FROM T_CIM_OSSZES
    WHERE C_FELHASZNALOID = @tanuloId
      AND C_GONDVISELOID IS NULL
      AND C_INTEZMENYID = @intezmenyId
      AND C_TANEVID = @aktTanevId
      AND TOROLT = 'F';
  END
END
GO