SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetErettsegiEredmenyekData]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetErettsegiEredmenyekData]
END
GO

-- =============================================
-- Description:	<Előszedjük a tanulók érettségieredményeinek összefoglaló gridjéhez szükséges adatokat>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetErettsegiEredmenyekData]
	 @pOsztalyId		INT

AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT
		 Tanulo.ID									ID
		,COUNT(ErettsegiEredmeny.C_TANULOID)		MentettErettsegikSzama
		,Felhasznalo.C_NYOMTATASINEV				TanuloNev
		,Felhasznalo.C_ANYJANEVE					AnyjaNeve
		,Felhasznalo.C_OKTATASIAZONOSITO			OMAzonosito
		,Felhasznalo.C_SZULETESIDATUM				SzuletesiIdo
		,OsztalyCsoport.C_NEV						OsztalyNev
		,OsztalyCsoport.C_VEGZOSEVFOLYAM			IsVegzos
	FROM 
		T_TANULO Tanulo
	LEFT JOIN
		T_TANULOCSOPORT TanuloCsoport ON
				TanuloCsoport.C_TANULOID = Tanulo.ID
			AND TanuloCsoport.TOROLT = 'F'
			AND TanuloCsoport.C_BELEPESDATUM < GETDATE()
			AND (TanuloCsoport.C_KILEPESDATUM IS NULL OR TanuloCsoport.C_KILEPESDATUM >= GETDATE())
	LEFT JOIN 
		T_OSZTALYCSOPORT OsztalyCsoport ON
				OsztalyCsoport.ID = TanuloCsoport.C_OSZTALYCSOPORTID 
			AND OsztalyCsoport.TOROLT = 'F'
	LEFT JOIN
		T_ERETTSEGIEREDMENY ErettsegiEredmeny ON
				ErettsegiEredmeny.C_TANULOID = Tanulo.ID	
			AND ErettsegiEredmeny.TOROLT = 'F'		
	LEFT JOIN 
		T_FELHASZNALO Felhasznalo ON 
				Felhasznalo.ID = Tanulo.ID
			AND Felhasznalo.TOROLT = 'F'
	WHERE 
			TanuloCsoport.C_OSZTALYCSOPORTID = @pOsztalyId
		AND Tanulo.TOROLT = 'F'
	GROUP BY 
		 Tanulo.ID
		,Felhasznalo.C_NYOMTATASINEV
		,Felhasznalo.C_ANYJANEVE
		,Felhasznalo.C_OKTATASIAZONOSITO
		,Felhasznalo.C_SZULETESIDATUM
		,OsztalyCsoport.C_NEV
		,OsztalyCsoport.C_VEGZOSEVFOLYAM

END


GO