SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetErtekelesFotargyiFoglalkozasData]') IS NOT NULL
BEGIN
	DROP PROCEDURE [dbo].[sp_GetErtekelesFotargyiFoglalkozasData]
END
GO

-- =============================================
-- Description:	<Felhasználóhoz köthető foglalkozások főtárgy adatai az értékelések szűréséhez>
-- =============================================

CREATE PROCEDURE [dbo].[sp_GetErtekelesFotargyiFoglalkozasData]
	 @pTanarId INT
	,@pTanevId INT
AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT DISTINCT
		 fotargy.ID 										TantargyId
		,osztalyCsoport.ID									OsztalyCsoportId
		,osztalyCsoport.C_NEV + ' - ' + fotargy.C_NEV		Nev
		,osztalyCsoport.C_EVFOLYAMTIPUSA					Evfolyam
		,fotargy.C_NEV										FotargyNev
	FROM
		T_FOGLALKOZAS_OSSZES foglalkozas
	LEFT JOIN
		T_OSZTALYCSOPORT_OSSZES osztalyCsoport ON
				osztalyCsoport.ID = foglalkozas.C_OSZTALYCSOPORTID
			AND osztalyCsoport.C_TANEVID = @pTanevId
			AND osztalyCsoport.TOROLT = 'F'
	LEFT JOIN
		T_TANTARGY_OSSZES tantargy ON
				tantargy.ID = foglalkozas.C_TANTARGYID
			AND tantargy.C_TANEVID = @pTanevId
			AND tantargy.TOROLT = 'F'
	LEFT JOIN
		T_FELHASZNALO_OSSZES felhasznalo ON
				felhasznalo.ID = foglalkozas.C_TANARID
			AND felhasznalo.C_TANEVID = @pTanevId
			AND felhasznalo.TOROLT = 'F'
	LEFT JOIN
		T_TANTARGY_OSSZES fotargy ON
				fotargy.C_FOTARGYE = 'T'
			AND fotargy.C_TANEVID = @pTanevId
			AND fotargy.TOROLT = 'F'
			AND fotargy.ID IN (
				SELECT
					C_FOTARGYID
				FROM
					T_TANTARGY_OSSZES
				WHERE
						ID = foglalkozas.C_TANTARGYID
					AND C_TANEVID = @pTanevId
					AND TOROLT = 'F'
			)
	WHERE
			fotargy.ID IS NOT NULL
		AND	foglalkozas.C_TANARID = @pTanarId
		AND	foglalkozas.C_TANEVID = @pTanevId
		AND	foglalkozas.TOROLT = 'F'
	ORDER BY
		osztalyCsoport.C_EVFOLYAMTIPUSA ASC,
		fotargy.C_NEV ASC

END


GO