SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetErtekelesMegtekinteseReszletek]') IS NOT NULL 
BEGIN
  DROP PROCEDURE [dbo].[sp_GetErtekelesMegtekinteseReszletek]
END
GO

-- =============================================
-- Author:		<Szikora Zoltán>
-- Create date: <2016. 09. 02.>
-- Description:	<Előszedjük a tanuló értékeléseit részletesen>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetErtekelesMegtekinteseReszletek]
	@pTanuloId INT
AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT
		 TanuloErtekeles.ID							ID
		,TanuloErtekeles.C_ERTEKELESDATUM 			ErtekelesDatuma
		,TanuloErtekeles.C_ERTEKELESTIPUSA 			ErtekelesTipusa
		,TanuloErtekeles.C_ERTEKELESSZOVEG 			ErtekelesSzoveg
		,TanuloErtekeles.C_SZOVEGROVIDNEV			SzovegRovidNev
		,TanuloErtekeles.C_OSZTALYZAT 				Osztalyzat
		,TanuloErtekeles.C_TANORAID					TanoraID
		,OsztalyzatErtekeles.C_ERTEKELESMODJA 		ErtekelesModja
		,OsztalyzatErtekeles.C_SZAZALEK 			Szazalek
		,OsztalyzatErtekeles.C_TEMA 				Tema
		,TanuloCsoport.C_TANULOID 					TanuloId
		,Felhasznalo.C_NYOMTATASINEV 				Ertekelo
	FROM(
		SELECT DISTINCT
			[C_TANULOID]
		FROM 
			[T_TANULOCSOPORT] 
		WHERE 
			[TOROLT] = 'F' 
			AND [C_TANULOID] = @pTanuloId
	) AS TanuloCsoport
		INNER JOIN (
			SELECT
				[ID]
				,[C_ERTEKELESDATUM]
				,[C_ERTEKELESTIPUSA]
				,[C_ERTEKELESSZOVEG]
				,[C_SZOVEGROVIDNEV]
				,[C_OSZTALYZAT]
				,[C_TANULOID]
				,[C_ERTEKELOID]
				,[C_TANORAID]
			FROM 
				[T_TANULOERTEKELES] 
			WHERE 
				[TOROLT] = 'F'
		) AS TanuloErtekeles
			ON TanuloCsoport.C_TANULOID = TanuloErtekeles.C_TANULOID 
		INNER JOIN (
			SELECT
				[ID]
				,[C_ERTEKELESMODJA]
				,[C_SZAZALEK]
				,[C_TEMA]
			FROM 
				[T_OSZTALYZATERTEKELES] 
			WHERE 
				[TOROLT] = 'F'
		) AS OsztalyzatErtekeles 
			ON OsztalyzatErtekeles.ID = TanuloErtekeles.ID
		INNER JOIN (
			SELECT
				[ID]
				,[C_NYOMTATASINEV]
			FROM 
				[T_FELHASZNALO] 
			WHERE 
				[TOROLT] = 'F' 
		) AS Felhasznalo
			ON Felhasznalo.ID = TanuloErtekeles.C_ERTEKELOID
			
END