-- =============================================
-- Author:	  	Sólyom Péter
-- Create date: 2016.02.16.
-- Description:	Órarend lekérdezése.
-- =============================================

IF OBJECT_ID('sp_GetOrarendTanoranKivuli') IS NOT NULL BEGIN
  DROP PROCEDURE sp_GetOrarendTanoranKivuli
END
GO

CREATE PROCEDURE [sp_GetOrarendTanoranKivuli]
	@IntezmenyId int,
	@TanevId int,
	@IdoszakKezdete datetime,
	@IdoszakVege datetime,
	@TanarId int,
	@OsztalyCsoportId int,
	@TanuloId int,
	@CsakOrarendiOrak bit
AS
BEGIN
	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;
	DECLARE @KezdoHet int = DATEPART( ISO_WEEK, @IdoszakKezdete);
	DECLARE @ZaroHet int = DATEPART( ISO_WEEK, @IdoszakVege);
		
	SELECT Distinct
  	Datum,
	  ISNULL(TanevHetirend, NapHetirend) Hetirend,
	  ISNULL(TanevHetNapja, NapHetNapja) HetNapja,
	  OsztalyCsoportId
	INTO #TEMPORARENDINAPOK
	FROM (
	  SELECT 
  		NAPTARINAP.Datum Datum,
  		NAPTARINAP.NapHetirend,
  		NAPTARINAP.NapHetNapja,
  		NAPTARINAP.TanevHetirend,
  		NAPTARINAP.TanevHetNapja,
		  NAPTARINAP.OsztalyCsoportId
	  FROM (
		(
         SELECT 
          C_NAPDATUMA Datum,
          C_HETIREND NapHetirend,
  		    IIF(C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_NAPDATUMA), C_HETNAPJA) NapHetNapja,
          null TanevHetirend,
          null TanevHetNapja,
          null OsztalyCsoportId
        FROM T_NAPTARINAP_OSSZES            
        WHERE (TOROLT = 'F' AND C_NAPDATUMA >= @IdoszakKezdete AND C_NAPDATUMA < @IdoszakVege AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId)
    )
		union 
    (
        SELECT 
          NAPTARINAP.C_NAPDATUMA Datum,
          NAPTARINAP.C_HETIREND NapHetirend,
  		    IIF(NAPTARINAP.C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_NAPDATUMA), NAPTARINAP.C_HETNAPJA) NapHetNapja,
          tanevRendHetirend.C_HETIREND TanevHetirend,
          tanevRendHetirend.C_HETNAPJA TanevHetNapja,
          tanevRendHetirend.C_OSZTALYCSOPORTID OsztalyCsoportId
        FROM T_NAPTARINAP_OSSZES NAPTARINAP 
        inner JOIN (      
          SELECT  
            C_DATUM,
            C_HETIREND,
            T_OSZTALYCSOPORT_TANEVRENDJE.C_OSZTALYCSOPORTID,
            IIF(C_HETNAPJA = 1407, dbo.fnGetHetNapja(C_DATUM), C_HETNAPJA) AS C_HETNAPJA
          from T_TANEVRENDJE_OSSZES  
          inner Join T_OSZTALYCSOPORT_TANEVRENDJE on T_OSZTALYCSOPORT_TANEVRENDJE.C_TANEVRENDJEID = T_TANEVRENDJE_OSSZES.ID     
          WHERE TOROLT = 'F' AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId And TOROLT = 'F') tanevRendHetirend on  tanevRendHetirend.C_DATUM = NAPTARINAP.C_NAPDATUMA          
      WHERE (TOROLT = 'F' AND NAPTARINAP.C_NAPDATUMA >= @IdoszakKezdete AND NAPTARINAP.C_NAPDATUMA < @IdoszakVege AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId)     
    )   
    ) NAPTARINAP
    ) result

	-- Vegzosok utolso tanitasi napja
	DECLARE @VegzosUtolsoTanitasiNap DATETIME;
	SELECT
		@VegzosUtolsoTanitasiNap = C_DATUM
	FROM
		T_TANEVRENDJE_OSSZES
	WHERE
		TOROLT = 'F'
		AND C_TANEVID = (SELECT ID FROM T_TANEV_OSSZES WHERE TOROLT = 'F' AND C_AKTIV = 'T' AND C_INTEZMENYID = @IntezmenyId)
		AND C_NAPTIPUSA = 1402  AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId
	
	-- Kapcsolódó csoportok
	 SELECT CsoportID 
	 into #TEMPCSOPORTOK
	 FROM 
			 (
			 SELECT C_CSOPORTOKID CsoportID 
		
					 FROM 
						 T_CSOPORTOK_OSZTALYOK
					 WHERE C_OSZTALYOKID = @OsztalyCsoportId AND @OsztalyCsoportId IS NOT NULL 
				 UNION ALL
					SELECT ID CsoportID FROM T_CSOPORT_OSSZES
					WHERE C_OSZTALYBONTASID = @OsztalyCsoportId --AND C_OSZTALYBONTASID IS NOT NULL
					AND TOROLT='F' AND C_ALINTEZMENYID = @IntezmenyId AND C_ALTANEVID=@TanevId) KapcsolodoCsoportok	
			-- CSAK AKKOR KELL AZ OSZTÁLYOKHOZ KAPCSOLÓDÓ CSOPORTOK IS, HA KIFEJEZETTEN OSZTÁLY ÓRAREND VAN LEKÉRVE
	UNION ALL
	SELECT @OsztalyCsoportId
	
	-- Tanítási órák
	SELECT
        TANITASIORA.ID Id,
		TANITASIORA.C_ORARENDIORAID ORARENDIID,	
        TANITASIORA.C_BONTOTT Bontott,
        (   SELECT 
                T_NAPTARINAP_OSSZES.C_HETIREND
            FROM 
                T_NAPTARINAP_OSSZES 
            WHERE 
                T_NAPTARINAP_OSSZES.ID = TANITASIORA.C_NAPTARINAPID
        ) Hetirend,
        TANITASIORA.C_HETNAPJA HetNapja,
        CAST('19000101' AS DATETIME) ErvenyessegKezdete,
        CAST('19000101' AS DATETIME) ErvenyessegVege,                  
        TANITASIORA.C_ORAKEZDETE OraKezdete,
        TANITASIORA.C_ORAVEGE OraVege,                   
        ISNULL(TARGY.C_ROVIDNEV, targy.C_NEV) TargyNev,
        TANITASIORA.C_MEGTARTOTT Megtartott,
        OSZTALY.C_NEV OsztalyNev,
		CAST(null AS int) TanevRendOsztalyCsoportId,
        fh.C_NYOMTATASINEV TanarNev,
        TEREM.C_NEV TeremNev,
        'TanitasiOra' OraTipus,
        CASE WHEN (@TanuloId IS NOT NULL AND
					 (SELECT COUNT(1) 
					  FROM T_TANULOMULASZTAS_OSSZES MULASZTAS 
					  WHERE MULASZTAS.C_ORATANULOIID = @TanuloId
							AND MULASZTAS.C_TANITASIORAKID = TANITASIORA.ID  AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId
							AND MULASZTAS.C_TIPUS = 1500 AND MULASZTAS.TOROLT = 'F') > 0)   --Kreta.Enums.MulasztasTipusEnum.hianyzas
				THEN 'T'
				ELSE 'F'
			END AS Hianyzas,
		CASE WHEN (@TanuloId IS NOT NULL AND
					(SELECT COUNT(1) 
					FROM T_TANULOMULASZTAS_OSSZES MULASZTAS 
					WHERE MULASZTAS.C_ORATANULOIID = @TanuloId
						AND MULASZTAS.C_TANITASIORAKID = TANITASIORA.ID  AND C_INTEZMENYID = @IntezmenyId AND C_TANEVID=@TanevId
						AND MULASZTAS.C_TIPUS = 1499 AND MULASZTAS.TOROLT = 'F') > 0)   --Kreta.Enums.MulasztasTipusEnum.keses
			THEN 'T'
			ELSE 'F'
		END AS Keses,
		TANITASIORA.C_HELYETTESITOTANARID HelyettesitoTanarID,
		HELYETTESTANAR.C_NYOMTATASINEV HelyettesitoTanarNev,
		fh.ID TanarID,
		null as HelyettesitesId,
		TANITASIORA.C_ADMINALTALKIIRT AdminAltalKiirt,
		TANITASIORA.C_TEMA as Tema
			INTO #TEMPORAK
     FROM T_TANITASIORA_OSSZES TANITASIORA
        LEFT JOIN T_TANTARGY_OSSZES TARGY ON (TARGY.ID = TANITASIORA.C_TANTARGYID)
        LEFT JOIN T_ORAK_TANAROK ON TANITASIORA.ID = T_ORAK_TANAROK.C_ORAKID 
        LEFT JOIN T_FELHASZNALO_OSSZES fh on T_ORAK_TANAROK.C_TANAROKID = fh.ID
        LEFT JOIN T_OSZTALYCSOPORT_OSSZES OSZTALY on (TANITASIORA.C_OSZTALYCSOPORTID = OSZTALY.ID  )
        LEFT JOIN T_TEREM_OSSZES TEREM on (TEREM.id = TANITASIORA.C_TEREMID ) 
		LEFT JOIN T_FELHASZNALO_OSSZES HELYETTESTANAR on TANITASIORA.C_HELYETTESITOTANARID = HELYETTESTANAR.ID
     WHERE @CsakOrarendiOrak = 0	-- TANÓRA IS
        AND TANITASIORA.TOROLT='F'  AND TANITASIORA.C_INTEZMENYID = @IntezmenyId AND TANITASIORA.C_TANEVID=@TanevId
        AND TANITASIORA.C_CSENGETESIRENDORAID IS NULL
		AND (TANITASIORA.C_ORAKEZDETE >= @IdoszakKezdete 
				AND TANITASIORA.C_ORAVEGE <= (CASE WHEN OSZTALY.C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap IS NOT NULL AND @IdoszakVege > @VegzosUtolsoTanitasiNap THEN @VegzosUtolsoTanitasiNap ELSE @IdoszakVege END))
		AND (@TanarId IS NULL OR ( TANITASIORA.C_HELYETTESITOTANARID = @TanarId OR TANITASIORA.C_ORATULAJDONOSID = @TanarId OR T_ORAK_TANAROK.C_TANAROKID = @TanarId))
		--KAPCSOLÓDÓ CSOPORTOK
        AND (@OsztalyCsoportId IS NULL OR TANITASIORA.C_OSZTALYCSOPORTID IN (SELECT CsoportID FROM #TEMPCSOPORTOK)
				
		)
        AND ( @TanuloId IS NULL
				 OR EXISTS (SELECT 1 
								FROM T_TANULOCSOPORT_OSSZES TANCSOP 
								WHERE TANCSOP.C_OSZTALYCSOPORTID = TANITASIORA.C_OSZTALYCSOPORTID
									AND TANCSOP.TOROLT = 'F'  AND TANCSOP.C_INTEZMENYID = @IntezmenyId AND TANCSOP.C_TANEVID=@TanevId
									AND TANCSOP.C_BELEPESDATUM < GETDATE()
									AND (TANCSOP.C_KILEPESDATUM IS NULL OR TANCSOP.C_KILEPESDATUM >= GETDATE())		-- TÖRÖLT
									AND TANCSOP.C_TANULOID = @TanuloId )
		   )
-- Órarendi órák
INSERT INTO #TEMPORAK
Select 
OrarendiOrak.Id, ORARENDIID, Bontott, Hetirend, HetNapja, ErvenyessegKezdete, ErvenyessegVege, OraKezdete, OraVege,
 TargyNev, Megtartott, OsztalyNev,TanevRendOsztalyCsoportId, TanarNev, TeremNev, OraTipus, Hianyzas, Keses,
C_HELYETTESTANAROKID HelyettesitoTanarID, HelyettesitoTanarNev, TanarID,HelyettesitesId,AdminAltalKiirt, Tema
FROM (
  SELECT
    T_ORARENDIORA_OSSZES.ID Id,
	T_ORARENDIORA_OSSZES.ID ORARENDIID,
    T_ORARENDIORA_OSSZES.C_BONTOTT Bontott,
    T_ORARENDIORA_OSSZES.C_HETIREND Hetirend,
    T_ORARENDIORA_OSSZES.C_HETNAPJA HetNapja,
    T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGKEZDETE ErvenyessegKezdete,
    T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGVEGE ErvenyessegVege,
    DATEADD(day, 0, DATEDIFF(day, 0, ORARENDINAPOK.Datum)) +
    DATEADD(day, 0 - DATEDIFF(day, 0, T_ORARENDIORA_OSSZES.C_ORAKEZDETE), T_ORARENDIORA_OSSZES.C_ORAKEZDETE) OraKezdete,
    DATEADD(day, 0, DATEDIFF(day, 0, ORARENDINAPOK.Datum)) +
    DATEADD(day, 0 - DATEDIFF(day, 0, T_ORARENDIORA_OSSZES.C_ORAVEGE), T_ORARENDIORA_OSSZES.C_ORAVEGE) OraVege,
    ISNULL(TARGY.C_ROVIDNEV, targy.C_NEV) TargyNev,
    'F' Megtartott,
    OSZTALY.C_NEV OsztalyNev,
	ORARENDINAPOK.OsztalyCsoportId TanevRendOsztalyCsoportId,
    fh.C_NYOMTATASINEV TanarNev,
    TEREM.C_NEV TeremNev,
    'OrarendiOra'  OraTipus,
    'F' Hianyzas,
	'F' Keses,
  	fh.ID TanarID,
    hi.C_HELYETTESTANAROKID,
	HELYETTESTANAR.C_NYOMTATASINEV as HelyettesitoTanarNev,
	hi.ID as HelyettesitesId,
	'F' AdminAltalKiirt,
	NULL AS Tema
  FROM T_ORARENDIORA_OSSZES
		INNER JOIN #TEMPORARENDINAPOK ORARENDINAPOK ON (( T_ORARENDIORA_OSSZES.C_HETIREND = 1554 OR ORARENDINAPOK.HETIREND = T_ORARENDIORA_OSSZES.C_HETIREND ) AND ORARENDINAPOK.HETNAPJA = T_ORARENDIORA_OSSZES.C_HETNAPJA And (T_ORARENDIORA_OSSZES.C_OSZTALYCSOPORTID = ORARENDINAPOK.OsztalyCsoportId or ORARENDINAPOK.OsztalyCsoportId is null) )
    LEFT JOIN T_TANTARGY_OSSZES TARGY ON TARGY.ID = T_ORARENDIORA_OSSZES.C_TANTARGYID
    LEFT JOIN T_FELHASZNALO_OSSZES fh ON fh.ID = T_ORARENDIORA_OSSZES.C_TANARID
    LEFT JOIN T_OSZTALYCSOPORT_OSSZES OSZTALY ON T_ORARENDIORA_OSSZES.C_OSZTALYCSOPORTID = OSZTALY.ID
    LEFT JOIN T_TEREM_OSSZES TEREM on (TEREM.id = T_ORARENDIORA_OSSZES.C_TEREMID )
    LEFT JOIN T_HELYETTESITESIIDOSZAK_OSSZES hi on (T_ORARENDIORA_OSSZES.ID = hi.C_HELYETTESITETTORARENDID) AND (hi.TOROLT = 'F')
	LEFT JOIN T_FELHASZNALO_OSSZES HELYETTESTANAR on hi.C_HELYETTESTANAROKID = HELYETTESTANAR.ID
  WHERE
	T_ORARENDIORA_OSSZES.TOROLT= 'F'
	AND T_ORARENDIORA_OSSZES.C_CSENGETESIRENDORAID IS NULL
	AND T_ORARENDIORA_OSSZES.C_TANEVID = @TanevId
    AND T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGVEGE >= @IdoszakKezdete AND T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGKEZDETE <= (CASE WHEN OSZTALY.C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap IS NOT NULL AND @IdoszakVege > @VegzosUtolsoTanitasiNap THEN @VegzosUtolsoTanitasiNap ELSE @IdoszakVege END) 
	AND ORARENDINAPOK.DATUM BETWEEN @IdoszakKezdete AND (CASE WHEN OSZTALY.C_VEGZOSEVFOLYAM = 'T' AND @VegzosUtolsoTanitasiNap IS NOT NULL AND @IdoszakVege > @VegzosUtolsoTanitasiNap THEN @VegzosUtolsoTanitasiNap ELSE @IdoszakVege END)
	AND TEREM.C_TANEVID = @TanevId
    AND (hi.C_HETSORSZAMA >= @KezdoHet OR hi.ID IS NULL)
    AND (hi.C_HETSORSZAMA <= @ZaroHet OR hi.ID IS NULL)
    --AND ORARENDINAPOK.DATUM BETWEEN  CAST(T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGKEZDETE AS DATE) AND CAST(T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGVEGE AS DATE)
	AND (
		(ORARENDINAPOK.DATUM >= T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGKEZDETE AND ORARENDINAPOK.DATUM < T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGVEGE) 
		OR
		(ORARENDINAPOK.DATUM = T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGKEZDETE AND ORARENDINAPOK.DATUM = T_ORARENDIORA_OSSZES.C_ORAERVENYESSEGVEGE)
	)
  AND (@TanarId IS NULL OR ( T_ORARENDIORA_OSSZES.C_TANARID = @TanarId OR hi.C_HELYETTESTANAROKID = @TanarId))
  
   --KAPCSOLÓDÓ CSOPORTOK
    AND ( @OsztalyCsoportId IS NULL OR T_ORARENDIORA_OSSZES.C_OSZTALYCSOPORTID IN (SELECT CsoportID FROM #TEMPCSOPORTOK) )
    AND ( @TanuloId IS NULL
		  OR EXISTS (
        SELECT 1 
			  FROM T_TANULOCSOPORT_OSSZES TANCSOP 
				WHERE TANCSOP.C_OSZTALYCSOPORTID = T_ORARENDIORA_OSSZES.C_OSZTALYCSOPORTID
					AND TANCSOP.C_TANEVID = @TanevId
					AND TANCSOP.C_BELEPESDATUM < GETDATE()
					AND (TANCSOP.C_KILEPESDATUM IS NULL OR TANCSOP.C_KILEPESDATUM >= GETDATE())		-- TÖRÖLT
					AND TANCSOP.C_TANULOID = @TanuloId )
	  )
	  
  ) OrarendiOrak
  WHERE	 NOT EXISTS ( 
      SELECT 1 
      FROM #TEMPORAK TANORAK 
			WHERE TANORAK.ORARENDIID = OrarendiOrak.ID
				AND TANORAK.OraKezdete = OrarendiOrak.[OraKezdete]
				AND TANORAK.OraVege = OrarendiOrak.[OraVege]
    )		-- HA MÁR VAN TANÍTÁSI ÓRA, AMELYIK VALAMELYIK ÓRARENDI ÓRÁBÓL JÖN, AKKOR NEM KELL AHHOZ AZ ÓRARENDI ÓRA IS
  	
  SELECT * FROM #TEMPORAK order by orakezdete
  
	DROP TABLE #TEMPORAK
	DROP TABLE #TEMPCSOPORTOK
	DROP TABLE #TEMPORARENDINAPOK
END
GO