SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetFeljegyzesFaliujsagBejegyzesekData]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetFeljegyzesFaliujsagBejegyzesekData]
END
GO

-- =============================================
-- Description:	<Előszedjük a faliújság-bejegyzés feljegyzéseket>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesFaliujsagBejegyzesekData]
	 @pTanarId							INT
	,@pEsemenyTipusFaliujsagBejegyzesId	INT

AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT DISTINCT
		 TanuloEsemeny.ID						ID
		,TanuloEsemeny.C_Kezdete				Kezdete
		,TanuloEsemeny.C_Vege					Vege
		,TanuloEsemeny.C_TARGY					Targy
		,TanuloEsemeny.C_TARTALOM				Tartalom
		,TanuloEsemeny.C_FALIUJSAGMEGJELENES	IsFaliujsagMegjelenes
		,Tanar.C_NYOMTATASINEV					FeljegyzoNeve
        ,IIF(TanuloEsemeny.C_MINDENKINEK = 'T', 
			'Egész intézmény', 
			STUFF(
  				(SELECT DISTINCT 
					', ' + OsztalyCsoportInner.C_NEV
  				FROM 
					T_OSZTALYCSOPORT OsztalyCsoportInner
				LEFT JOIN 
					T_OSZTALYCSOPORT_TANULOESEMENY OsztalyCsoportTanuloEsemeny ON
							OsztalyCsoportTanuloEsemeny.C_TANULOESEMENYID = TanuloEsemeny.ID
				WHERE OsztalyCsoportInner.ID = OsztalyCsoportTanuloEsemeny.C_OSZTALYCSOPORTID
  					FOR XML PATH (''))
  					, 1, 2, '')
		)										Cimzettek		
	FROM 
		T_TANULOESEMENY TanuloEsemeny
	LEFT JOIN 
		T_FELHASZNALO Tanar ON
				Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
			AND Tanar.TOROLT = 'F'
	WHERE
			TanuloEsemeny.C_TIPUS = @pEsemenyTipusFaliujsagBejegyzesId
		AND TanuloEsemeny.C_FELJEGYZOID = @pTanarId
		AND TanuloEsemeny.TOROLT = 'F'

END


GO