SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('[dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetData]') IS NOT NULL 
BEGIN
	DROP PROCEDURE [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetData]
END
GO

-- =============================================
-- Description:	<Előszedjük az osztály csoport tanulóinak feljegyzéseit az elektronikus üzenetek oldal napló nézet tab-jához>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetFeljegyzesElektronikusUzenetekNaploNezetData]
	 @pOsztalyCsoportId					INT
	,@pStartDate						DATE
	,@pTanarId							INT

AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	SELECT DISTINCT
		 TanuloEsemeny.ID					ID
		,TanuloEsemeny.C_ROGZITESDATUMA		RogzitesDatuma
		,TanuloEsemeny.C_TARGY				Targy
		,TanuloEsemeny.C_TARTALOM			Tartalom
		,TanuloEsemeny.C_TIPUS				Tipus
		,Tanulo.ID							TanuloId
		,Tanulo.C_NYOMTATASINEV				TanuloNev
		,Tanulo.C_ANYJANEVE					AnyjaNeve
		,Tanulo.C_SZULETESIDATUM			SzuletesiIdo
		,Tanar.C_NYOMTATASINEV				FeljegyzoNeve
		,OsztalyCsoport.C_NEV				OsztalyNev
		,CASE
			WHEN TanuloEsemeny.C_FELJEGYZOID = @pTanarId
				THEN 'T' 
				ELSE 'F' 
		END									Modosithato
	FROM 
		T_FELHASZNALO Tanulo
	LEFT JOIN 
		T_TANULO_TANULOESEMENY TanuloTanuloEsemeny ON
			TanuloTanuloEsemeny.C_TANULOID = Tanulo.ID 
	LEFT JOIN 
		T_TANULOESEMENY TanuloEsemeny ON
				TanuloEsemeny.ID = TanuloTanuloEsemeny.C_TANULOESEMENYID
			AND CAST(TanuloEsemeny.C_ROGZITESDATUMA AS DATE) >= @pStartDate
			AND CAST(TanuloEsemeny.C_ROGZITESDATUMA AS DATE) <= CAST(GETDATE() AS DATE)
	LEFT JOIN 
		T_FELHASZNALO Tanar ON
				Tanar.ID = TanuloEsemeny.C_FELJEGYZOID
			AND Tanar.TOROLT = 'F'
	LEFT JOIN 
		T_TANULOCSOPORT TanuloCsoport ON 
				TanuloCsoport.C_TANULOID = Tanulo.ID 
			AND TanuloCsoport.TOROLT = 'F'
	LEFT JOIN 
		T_OSZTALYCSOPORT OsztalyCsoport ON
				OsztalyCsoport.ID = TanuloCsoport.C_OSZTALYCSOPORTID 
			AND OsztalyCsoport.TOROLT = 'F'
	WHERE 
			Tanulo.TOROLT = 'F'
		AND OsztalyCsoport.ID = @pOsztalyCsoportId
	ORDER BY 
		Tanulo.C_NYOMTATASINEV

END


GO