DROP PROCEDURE IF EXISTS uspGetTanarAltalErtekelhetoCsoportok
GO

CREATE PROCEDURE uspGetTanarAltalErtekelhetoCsoportok
   @pTanarId int
  ,@pTanevId int
  ,@pSzuperOsztalyfonok int
  ,@pDatum date
  ,@pOsztalyGroup nvarchar(255)
  ,@pCsoportGroup nvarchar(255)
AS BEGIN
  SET NOCOUNT ON
  SELECT
     ocs.Id AS OsztalyCsoportId
    ,ocs.C_NEV AS Nev
    ,CASE WHEN o.ID IS NULL THEN @pCsoportGroup ELSE @pOsztalyGroup END AS GroupName
  FROM T_OSZTALYCSOPORT ocs
    LEFT JOIN T_FOGLALKOZAS f ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND f.TOROLT = 'F'
    LEFT JOIN T_OSZTALY_OSSZES o ON o.ID = ocs.ID
      AND o.TOROLT = 'F'
  WHERE ocs.TOROLT = 'F'
    AND ocs.C_TANEVID = @pTanevId
    AND EXISTS( SELECT 1 
                FROM T_TANULOCSOPORT_OSSZES tcs 
                WHERE tcs.C_OSZTALYCSOPORTID=ocs.ID 
                  AND tcs.TOROLT='F'
                  AND @pDatum >= tcs.C_BELEPESDATUM
                  AND (tcs.C_KILEPESDATUM IS NULL OR tcs.C_KILEPESDATUM > @pDatum)
                  AND tcs.C_TANULOID IN (SELECT ID FROM fnGetOsztalyfonokOsztalyanakTanuloi(@pTanarId, @pSzuperOsztalyfonok, ocs.C_FELADATKATEGORIAID, @pDatum)))
  UNION
  SELECT
     ocs.ID AS OsztalyCsoportId
    ,ocs.C_NEV AS Nev
    ,CASE WHEN o.ID IS NULL THEN @pCsoportGroup ELSE @pOsztalyGroup END AS GroupName
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
      AND ocs.TOROLT = 'F'
    LEFT JOIN T_OSZTALY_OSSZES o ON o.ID = ocs.ID
  WHERE (f.C_TANARID = @pTanarId OR @pSzuperOsztalyfonok = 1)
    AND ocs.C_TANEVID = @pTanevId
    AND f.TOROLT = 'F'
  ORDER BY Nev
END
GO