-- =============================================
-- Description:  <Előszedjük a szamonkeres elorejelzeseket a megadott paraméterek alapján>
-- =============================================
DROP PROCEDURE IF EXISTS uspGetSzamonkeresElorejelzesGrid
GO

CREATE PROCEDURE uspGetSzamonkeresElorejelzesGrid
   @pIntezmenyId int
  ,@pTanevId int
  ,@pTanuloId int = NULL
  ,@pDatumTol datetime = NULL
  ,@pDatumIg datetime = NULL
  ,@pHetNapjaSrc int = NULL
  ,@pOraszamSrc int = NULL
  ,@pSzamonkeresModSrc int = NULL
  ,@pSzamonkeresMegnevezesSrc nvarchar(1000) = NULL
  ,@pBejelentesDatumaTol datetime = NULL
  ,@pBejelentesDatumaIg datetime = NULL
  ,@pTantargySrc int = NULL
  ,@pTanarSrc int = NULL
  ,@pSzamonkeresIdsString nvarchar(1000) = NULL
  ,@pRegiekElrejtese BIT = 0
  ,@pOsztalyCsoportId INT = NULL
  ,@pCsakLegutobbi6 bit = 0
  ,@pOraGroupId int = NULL
  ,@pFeladatKategoriaId int
  ,@pOsztalyCsoportIdsKapcsolodoCsoportokkal nvarchar(1000) = NULL
  ,@pErtekelesModTypeId int = 45
  ,@pMindegyikHetTipusId int = 1554
AS
BEGIN
  SET NOCOUNT ON;
  DECLARE @sql nvarchar(max)   
    SET @sql = N''
    IF @pTanuloId IS NOT NULL
    BEGIN
    SET @sql += N'
      CREATE TABLE #OsztalyCsoportList(
         ID int PRIMARY KEY
      )
      INSERT INTO #OsztalyCsoportList (ID)
      SELECT DISTINCT
         OsztalyCsoport.ID
      FROM T_TANULOCSOPORT tcs
        INNER JOIN T_OSZTALYCSOPORT OsztalyCsoport ON OsztalyCsoport.C_TANEVID = tcs.C_TANEVID AND OsztalyCsoport.TOROLT = ''F'' AND OsztalyCsoport.ID = tcs.C_OSZTALYCSOPORTID
        ' + IIF(@pFeladatKategoriaId IS NULL,'','  AND OsztalyCsoport.C_FELADATKATEGORIAID = @pFeladatKategoriaId') + '
      WHERE tcs.C_TANEVID = @pTanevId
        AND tcs.C_TANULOID = @pTanuloId AND  tcs.C_BELEPESDATUM <= GETDATE() AND tcs.TOROLT = ''F''  
        AND (tcs.C_KILEPESDATUM IS NULL OR tcs.C_KILEPESDATUM > GETDATE()) '
    END
  
  SET @sql += N'
  SELECT DISTINCT '+IIF(@pCsakLegutobbi6 = 1,' TOP 6 WITH TIES ','') + '
    sze.ID as ID
    ,sze.C_ORARENDIORAGROUPID as OrarendiOraGroupId
    ,sze.C_SZAMONKERESDATUMA as SzamonkeresDatuma
    ,oo.C_HETNAPJA as HetNapja
    ,oo.C_ORASZAM as Oraszam
    ,ISNULL(helyettestanar.C_IDPEGYEDIAZONOSITO, tanar.C_IDPEGYEDIAZONOSITO) as TanarUid
    ,ISNULL(helyettestanar.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV) as TanarNev
    ,ISNULL(helyettestanar.ID, tanar.ID) as TanarId
    ,targy.C_NEV as TargyNev
    ,targy.ID as TargyId
    ,targy.C_TARGYKATEGORIA as TargyKategoria
    ,sze.C_SZAMONKERESMODID as ErtekelesModId
    ,dib.C_NAME as ErtekelesModNev
    ,sze.C_SZAMONKERESMEGNEVEZES as SzamonkeresMegnevezes
    ,sze.C_ROGZITESDATUMA as BejelentesDatuma
    ,rogzito.C_NYOMTATASINEV as RogzitoTanar
    ,ocs.C_NEV as OsztalyNev
    ,oo.C_OSZTALYCSOPORTID as OsztalyCsoportId
    ,IIF(GETDATE() < sze.C_SZAMONKERESDATUMA, ''T'', ''F'') as Torolheto
    ,sze.CREATED KeszitesDatuma
  FROM T_SZAMONKERESELOREJELZES sze
    INNER JOIN T_ORARENDIORA oo ON oo.C_ORARENDIORAGROUPID = sze.C_ORARENDIORAGROUPID AND (sze.C_SZAMONKERESDATUMA >= oo.C_ORAERVENYESSEGKEZDETE AND (sze.C_SZAMONKERESDATUMA < oo.C_ORAERVENYESSEGVEGE OR (sze.C_SZAMONKERESDATUMA = oo.C_ORAERVENYESSEGVEGE AND sze.C_SZAMONKERESDATUMA = oo.C_ORAERVENYESSEGKEZDETE)))  AND oo.TOROLT = ''F''
    INNER JOIN T_ORAREND orr ON orr.C_ORARENDIORAID = oo.ID AND sze.C_SZAMONKERESDATUMA = orr.C_DATUM'
  IF @pTanuloId IS NOT NULL
    BEGIN
    SET @sql += N'
    INNER JOIN #OsztalyCsoportList ocsl ON ocsl.ID = oo.C_OSZTALYCSOPORTID '
    END
  SET @sql += N'
    INNER JOIN T_TANTARGY targy ON targy.ID = oo.C_TANTARGYID AND targy.TOROLT = ''F''
    INNER JOIN T_FELHASZNALO tanar ON tanar.ID = oo.C_TANARID AND tanar.TOROLT = ''F''
    INNER JOIN T_FELHASZNALO rogzito ON rogzito.ID = sze.C_ROGZITOID AND rogzito.TOROLT = ''F''
    INNER JOIN T_OSZTALYCSOPORT ocs ON ocs.ID = oo.C_OSZTALYCSOPORTID AND ocs.TOROLT = ''F'' '+IIF(@pFeladatKategoriaId IS NULL,'','AND ocs.C_FELADATKATEGORIAID = @pFeladatKategoriaId')+'
    INNER JOIN T_DICTIONARYITEMBASE dib ON dib.ID = sze.C_SZAMONKERESMODID AND dib.C_TANEVID = sze.C_TANEVID
    LEFT JOIN T_HELYETTESITESIIDOSZAK helyettes ON helyettes.C_HELYETTESITETTORARENDID = oo.ID AND helyettes.C_HELYETTESITESNAPJA = sze.C_SZAMONKERESDATUMA AND helyettes.TOROLT = ''F''
    LEFT JOIN T_FELHASZNALO helyettestanar ON helyettestanar.ID = helyettes.C_HELYETTESTANAROKID AND helyettestanar.TOROLT = ''F''
  WHERE sze.C_TANEVID = @pTanevId AND sze.TOROLT = ''F''
    '

  IF @pOsztalyCsoportId IS NOT NULL AND @pOsztalyCsoportIdsKapcsolodoCsoportokkal IS NULL BEGIN  SET @sql += N' AND oo.C_OSZTALYCSOPORTID = @pOsztalyCsoportId ' END
  IF LEN(@pOsztalyCsoportIdsKapcsolodoCsoportokkal) > 0 BEGIN  SET @sql += N' AND oo.C_OSZTALYCSOPORTID IN (SELECT value FROM STRING_SPLIT(@pOsztalyCsoportIdsKapcsolodoCsoportokkal, '','')) ' END
  IF @pDatumTol IS NOT NULL BEGIN  SET @sql += N' AND sze.C_SZAMONKERESDATUMA >= @pDatumTol ' END
  IF @pDatumIg IS NOT NULL BEGIN  SET @sql += N' AND sze.C_SZAMONKERESDATUMA <= @pDatumIg ' END
  IF @pHetNapjaSrc IS NOT NULL BEGIN  SET @sql += N' AND oo.C_HETNAPJA = @pHetNapjaSrc ' END
  IF @pOraszamSrc IS NOT NULL BEGIN  SET @sql += N' AND oo.C_ORASZAM = @pOraszamSrc ' END
  IF @pSzamonkeresModSrc IS NOT NULL BEGIN  SET @sql += N' AND sze.C_SZAMONKERESMODID = @pSzamonkeresModSrc ' END
  IF @pSzamonkeresMegnevezesSrc IS NOT NULL BEGIN  SET @sql += N' AND sze.C_SZAMONKERESMEGNEVEZES LIKE ''%'' + @pSzamonkeresMegnevezesSrc + ''%''' END
  IF @pBejelentesDatumaTol IS NOT NULL BEGIN  SET @sql += N' AND sze.C_ROGZITESDATUMA >= @pBejelentesDatumaTol ' END
  IF @pBejelentesDatumaIg IS NOT NULL BEGIN  SET @sql += N' AND sze.C_ROGZITESDATUMA <= @pBejelentesDatumaIg ' END
  IF @pTantargySrc IS NOT NULL BEGIN  SET @sql += N' AND oo.C_TANTARGYID = @pTantargySrc ' END
  IF @pTanarSrc IS NOT NULL BEGIN  SET @sql += N' AND oo.C_TANARID = @pTanarSrc ' END
  IF LEN(@pSzamonkeresIdsString) > 0 BEGIN  SET @sql += N' AND sze.ID IN (SELECT value FROM STRING_SPLIT(@pSzamonkeresIdsString, '','')) ' END
  IF @pOraGroupId IS NOT NULL BEGIN  SET @sql += N' AND sze.C_ORARENDIORAGROUPID = @pOraGroupId ' END
  IF (@pCsakLegutobbi6 = 1 OR @pRegiekElrejtese = 1) BEGIN  SET @sql += N' AND sze.C_SZAMONKERESDATUMA >= DATEADD(day, -1, GETDATE()) ' END
  IF (@pCsakLegutobbi6 = 1)  BEGIN  SET @sql += N' ORDER BY sze.C_SZAMONKERESDATUMA ' END

  EXEC sp_executesql @sql, N'
   @pIntezmenyId int
  ,@pTanevId int
  ,@pTanuloId int = NULL
  ,@pDatumTol datetime = NULL
  ,@pDatumIg datetime = NULL
  ,@pHetNapjaSrc int = NULL
  ,@pOraszamSrc int = NULL
  ,@pSzamonkeresModSrc int = NULL
  ,@pSzamonkeresMegnevezesSrc nvarchar(1000) = NULL
  ,@pBejelentesDatumaTol datetime = NULL
  ,@pBejelentesDatumaIg datetime = NULL
  ,@pTantargySrc int = NULL
  ,@pTanarSrc int = NULL
  ,@pSzamonkeresIdsString nvarchar(1000) = NULL   
  ,@pOsztalyCsoportId int = NULL
  ,@pRegiekElrejtese bit = 0
  ,@pOraGroupId int = NULL
  ,@pFeladatKategoriaId int
  ,@pOsztalyCsoportIdsKapcsolodoCsoportokkal nvarchar(1000) = NULL
  ,@pErtekelesModTypeId int
  ,@pMindegyikHetTipusId int'
  ,@pIntezmenyId = @pIntezmenyId
  ,@pTanevId = @pTanevId
  ,@pTanuloId = @pTanuloId
  ,@pDatumTol = @pDatumTol
  ,@pDatumIg = @pDatumIg
  ,@pHetNapjaSrc = @pHetNapjaSrc
  ,@pOraszamSrc = @pOraszamSrc
  ,@pSzamonkeresModSrc = @pSzamonkeresModSrc
  ,@pSzamonkeresMegnevezesSrc = @pSzamonkeresMegnevezesSrc
  ,@pBejelentesDatumaTol = @pBejelentesDatumaTol
  ,@pBejelentesDatumaIg = @pBejelentesDatumaIg
  ,@pTantargySrc = @pTantargySrc
  ,@pTanarSrc = @pTanarSrc
  ,@pSzamonkeresIdsString = @pSzamonkeresIdsString
  ,@pOsztalyCsoportId = @pOsztalyCsoportId
  ,@pRegiekElrejtese = @pRegiekElrejtese
  ,@pOraGroupId = @pOraGroupId
  ,@pFeladatKategoriaId = @pFeladatKategoriaId
  ,@pOsztalyCsoportIdsKapcsolodoCsoportokkal = @pOsztalyCsoportIdsKapcsolodoCsoportokkal
  ,@pErtekelesModTypeId = @pErtekelesModTypeId
  ,@pMindegyikHetTipusId = @pMindegyikHetTipusId

END
GO