DROP PROCEDURE  IF EXISTS uspGetSZMKKepviselokEugyintezes 
GO

CREATE PROCEDURE uspGetSZMKKepviselokEugyintezes
   @pOktNevKatTipusNevOkt INT
  ,@pTanevId INT
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Gondviselo.ID AS KretaAzonosito
    ,Gondviselo.C_NEV AS GondviseloNev
    ,Email.C_EMAILCIM AS EmailCim
    ,Felhasznalo.C_NYOMTATASINEV AS TanuloNev
    ,Felhasznalo.C_OKTATASIAZONOSITO AS TanuloOktatasiAzonosito
    ,Felhasznalo.ID AS TanuloId
    ,SZMKKepviselo.SZMKOsztaly
    ,SZMKKepviseloHelyettes.ID AS SZMKOsztalyHelyettesKretaAzonosito
    ,SZMKKepviseloHelyettes.SZMKOsztalyHelyettes
    ,SZMKKepviselo.ID AS SZMKOsztalyKretaAzonosito
    ,IIF(SZMKKepviselo.SZMKKepviseloId = Gondviselo.ID, 1, 0) AS IsSZMK
    ,IIF(SZMKKepviseloHelyettes.SZMKKepviseloHelyettesId = Gondviselo.ID, 1, 0) AS IsSZMKHelyettes
    ,Gondviselo.C_EGYEDIAZONOSITO AS EgyediAzonosito
    ,Gondviselo.C_IDPEGYEDIAZONOSITO AS IdpEgyediAzonosito
  FROM T_GONDVISELO_OSSZES Gondviselo
  LEFT JOIN T_EMAIL_OSSZES Email ON Email.C_GONDVISELOID = Gondviselo.ID
    AND Email.TOROLT = 'F'
    AND Email.C_ALAPERTELMEZETT = 'T'
  INNER JOIN T_FELHASZNALO_OSSZES Felhasznalo ON Felhasznalo.ID = Gondviselo.C_TANULOID
    AND Felhasznalo.TOROLT = 'F'
  LEFT JOIN (
    SELECT OsztalyCsoport.ID
      ,OsztalyCsoport.C_NEV AS SZMKOsztaly
      ,Osztaly.C_SZMKKEPVISELOID AS SZMKKepviseloId
    FROM T_OSZTALYCSOPORT_OSSZES OsztalyCsoport
    INNER JOIN T_OSZTALY_OSSZES Osztaly ON Osztaly.ID = OsztalyCsoport.ID
      AND Osztaly.TOROLT = 'F'
    WHERE OsztalyCsoport.TOROLT = 'F'
      AND OsztalyCsoport.C_FELADATKATEGORIAID = @pOktNevKatTipusNevOkt
    ) SZMKKepviselo ON SZMKKepviselo.SZMKKepviseloID = Gondviselo.ID
  LEFT JOIN (
    SELECT OsztalyCsoport.ID
      ,OsztalyCsoport.C_NEV AS SZMKOsztalyHelyettes
      ,Osztaly.C_SZMKKEPVISELOHELYETTESID AS SZMKKepviseloHelyettesId
    FROM T_OSZTALYCSOPORT_OSSZES OsztalyCsoport
    INNER JOIN T_OSZTALY_OSSZES Osztaly ON Osztaly.ID = OsztalyCsoport.ID
      AND Osztaly.TOROLT = 'F'
    WHERE OsztalyCsoport.TOROLT = 'F'
      AND OsztalyCsoport.C_FELADATKATEGORIAID = @pOktNevKatTipusNevOkt
    ) SZMKKepviseloHelyettes ON SZMKKepviseloHelyettes.SZMKKepviseloHelyettesId = Gondviselo.ID
  WHERE Gondviselo.TOROLT = 'F'
    AND Gondviselo.C_TANEVID = @pTanevId
    AND (
      SZMKKepviselo.SZMKKepviseloId = Gondviselo.ID
      OR SZMKKepviseloHelyettes.SZMKKepviseloHelyettesId = Gondviselo.ID
      )
END
GO