/* ================================================================================ */
/* Description: Intézmény szintű lekérdezés adott pTanevId szerint a mulasztásokról */
/* ================================================================================ */
DROP PROCEDURE IF EXISTS uspGetMulasztasiOsszesitoStatisztika
GO

CREATE PROCEDURE [dbo].[uspGetMulasztasiOsszesitoStatisztika]
  @pTanevId INT

AS BEGIN
SET NOCOUNT ON;

SELECT
   i.C_AZONOSITO AS Intezmeny
  ,f.C_NYOMTATASINEV AS Tanulo
  ,f.C_OKTATASIAZONOSITO AS OktatasiAzonosito
  ,ocs.C_NEV AS 'Osztaly/Csoport'
  ,CAST(tn.C_DATUM AS date) AS Datum
  ,tn.C_ORASZAM AS Oraszam
  ,CASE mu.C_TIPUS WHEN 1500 THEN N'Hiányzás' WHEN 1499 THEN N'Késés' WHEN 1817 THEN N'Üres' END AS MulasztasTipus
  ,mu.C_KESESPERCBEN AS KesesPercben
  ,tgy.C_NEV AS Tantargy
  ,tn.C_ORAKEZDETE AS OraKezdete
  ,tn.C_ORAVEGE AS OraVege
FROM T_TANULOMULASZTAS_OSSZES mu
  INNER JOIN T_INTEZMENY_OSSZES i ON i.ID = mu.C_INTEZMENYID AND i.TOROLT = 'F'
  INNER JOIN T_FELHASZNALO_OSSZES f ON f.ID = mu.C_ORATANULOIID AND f.TOROLT = 'F'
  INNER JOIN T_TANITASIORA_OSSZES tn ON tn.ID = mu.C_TANITASIORAKID AND tn.TOROLT = 'F'
  INNER JOIN T_TANTARGY_OSSZES tgy ON tgy.ID = tn.C_TANTARGYID AND tgy.TOROLT = 'F'
  INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = tn.C_OSZTALYCSOPORTID AND ocs.TOROLT = 'F'
WHERE
  mu.TOROLT = 'F'
  AND mu.C_TANEVID = @pTanevId
ORDER BY Intezmeny, Datum, OraKezdete, Tanulo

END
GO