DROP PROCEDURE IF EXISTS uspGetJogviszonyByTanuloIdsAndJogvTipusId 
GO
  CREATE PROCEDURE uspGetJogviszonyByTanuloIdsAndJogvTipusId      
     @pTanevId int
    ,@pIntezmenyId int
    ,@pTanuloIds nvarchar(MAX)
  AS
  BEGIN
    SET NOCOUNT ON;
    CREATE TABLE #TanuloIds (TanuloId int)
    INSERT INTO #TanuloIds(TanuloId)
    SELECT value FROM STRING_SPLIT(@pTanuloIds,',')

     SELECT
       jogviszony.ID AS JogviszonyId
      ,jogviszonyTipusDic.C_NAME AS JogviszonyTipusa
      ,jogviszony.C_TBJOGVISZONYTIPUSID AS JogviszonyTipusaId
      ,jogviszony.C_TANULOID AS TanuloId
      ,IIF(fh.C_OKTATASIAZONOSITO IS NOT NULL,fh.C_NYOMTATASINEV + ' (' + fh.C_OKTATASIAZONOSITO +')',fh.C_NYOMTATASINEV) AS TanuloNeve
      ,jogviszony.C_TBJOGVISZONYTIPUSID AS JogviszonyTipusaId
      ,jogviszony.C_KEZDETE AS JogviszonyKezdete
      ,jogviszonyKeletkezeseJogcimTipusDic.C_NAME AS JogviszonyKeletkezesenekJogcime
      ,jogviszony.C_JOGVKELETKEZESEJOGCIMTIPUSID AS JogviszonyKeletkezesenekJogcimeId
      ,jogviszony.C_ISAKTIV AS JogviszonyStatusza
      ,jogviszony.C_MEGJEGYZES AS Megjegyzes
    FROM
      T_TBJOGVISZONY_OSSZES jogviszony
      INNER JOIN #TanuloIds t ON t.TanuloId = jogviszony.C_TANULOID
      INNER JOIN T_DICTIONARYITEMBASE jogviszonyTipusDic ON 
        jogviszonyTipusDic.ID = jogviszony.C_TBJOGVISZONYTIPUSID
        AND jogviszonyTipusDic.TOROLT = 'F' 
        AND jogviszonyTipusDic.C_TANEVID = jogviszony.C_TANEVID
        AND jogviszonyTipusDic.C_INTEZMENYID = jogviszony.C_INTEZMENYID
        AND jogviszonyTipusDic.C_DICTIONARYTYPEID = 183
      INNER JOIN T_FELHASZNALO_OSSZES fh ON fh.ID = jogviszony.C_TANULOID
        AND fh.TOROLT = 'F'
        AND fh.C_TANEVID = jogviszony.C_TANEVID
        AND fh.C_INTEZMENYID = jogviszony.C_INTEZMENYID
      INNER JOIN T_DICTIONARYITEMBASE jogviszonyKeletkezeseJogcimTipusDic ON 
        jogviszonyKeletkezeseJogcimTipusDic.ID = jogviszony.C_JOGVKELETKEZESEJOGCIMTIPUSID 
        AND jogviszonyKeletkezeseJogcimTipusDic.TOROLT = 'F' 
        AND jogviszonyKeletkezeseJogcimTipusDic.C_TANEVID = jogviszony.C_TANEVID 
        AND jogviszonyKeletkezeseJogcimTipusDic.C_INTEZMENYID = jogviszony.C_INTEZMENYID
        AND jogviszonyKeletkezeseJogcimTipusDic.C_DICTIONARYTYPEID = 184
    WHERE jogviszony.C_ISAKTIV = 'T'
      AND jogviszony.C_INTEZMENYID = @pIntezmenyId
      AND jogviszony.C_TANEVID = @pTanevId
      AND jogviszony.C_JOGVMEGSZUNESEJOGCIMTIPUSID IS NULL
      AND jogviszony.TOROLT = 'F'
  END
GO