DROP PROCEDURE IF EXISTS [dbo].[sp_GetTanarOrarendLefedettseg]
GO

CREATE PROCEDURE [dbo].[sp_GetTanarOrarendLefedettseg]
  @intezmenyId int, 
  @tanevId int  
AS
BEGIN

SET NOCOUNT ON;

DECLARE @AktivtanevId INT = (SELECT Id FROM T_TANEV_OSSZES tanev WHERE C_AKTIV='T' AND C_INTEZMENYID = @intezmenyId AND TOROLT = 'F')

DECLARE @UtolsoNap  DATE = (SELECT TOP 1 C_DATUM FROM T_TANEVRENDJE_OSSZES WHERE C_NAPTIPUSA=1395 AND C_TANEVID=@tanevid AND TOROLT='F')
    ,@ElsoNap  DATE = (select C_KEZDONAP from T_TANEV_OSSZES WHERE ID = @tanevid)
    ,@IdoszakKezdete  DATE
    ,@IdoszakVege    DATE

IF (@tanevId = @AktivtanevId AND GETDATE() <= @UtolsoNap)
  BEGIN
    IF (GETDATE() <= @ElsoNap)
    BEGIN
      SET @IdoszakKezdete = (SELECT TOP 1 C_HETKEZDONAPJA FROM T_NAPTARIHET_OSSZES WHERE C_HETSORSZAMA = 1 AND TOROLT = 'F' AND C_TANEVID = @tanevId)
      SET @IdoszakVege = (SELECT TOP 1 C_HETUTOLSONAPJA FROM T_NAPTARIHET_OSSZES WHERE C_HETSORSZAMA = 3 AND TOROLT = 'F' AND C_TANEVID = @tanevId)
    END
    ELSE
    BEGIN
      SET @IdoszakKezdete =(SELECT TOP 1 nh.C_HETKEZDONAPJA  FROM T_NAPTARIHET_OSSZES nh WHERE CONVERT(DATE, GETDATE())>=CONVERT(DATE, NH.C_HETKEZDONAPJA) AND CONVERT(DATE, GETDATE())<=CONVERT(DATE, nh.C_HETUTOLSONAPJA) and nh.TOROLT='F' and nh.C_TANEVID=@tanevid)
      SET @IdoszakVege = DATEADD(DAY, 13, @IdoszakKezdete)
    END
  END
ELSE
  BEGIN
    SET @IdoszakVege =(SELECT TOP 1 nh.C_HETUTOLSONAPJA  FROM T_NAPTARIHET_OSSZES nh WHERE @UtolsoNap>=CONVERT(DATE, nh.C_HETKEZDONAPJA) AND @UtolsoNap<=CONVERT(DATE, nh.C_HETUTOLSONAPJA) AND nh.TOROLT='F' AND nh.C_TANEVID=@tanevId)
    SET @IdoszakKezdete = DATEADD(DAY, -13, @IdoszakVege)
  END
  
--Órarendi lefedettség
CREATE TABLE #csoportok (CsoportId INT, Pedagogus NVARCHAR(MAX), CsoportTipus NVARCHAR(MAX), Oraszam float, Hetirend NVARCHAR(MAX))
INSERT INTO #csoportok
SELECT DISTINCT 
    cs.ID
    ,f.C_NYOMTATASINEV
    ,d.C_NAME
    ,fog.C_ORASZAM
    ,Hetirend.C_NAME 
FROM T_FOGLALKOZAS_OSSZES fog 
  LEFT JOIN T_CSOPORT_OSSZES cs ON cs.Id = fog.C_OSZTALYCSOPORTID AND cs.TOROLT='F' AND cs.C_ALTANEVID=@tanevId 
  LEFT JOIN T_OSZTALY_OSSZES o ON o.Id = fog.C_OSZTALYCSOPORTID AND o.TOROLT='F' AND o.C_ALTANEVID=@tanevId 
  INNER JOIN T_ORARENDIORA_OSSZES oo ON oo.C_FOGLALKOZASID = fog.ID 
                      AND C_ORAERVENYESSEGKEZDETE <= @IdoszakVege
                      AND C_ORAERVENYESSEGVEGE >= @IdoszakKezdete
                      AND oo.C_TANEVID=@tanevid 
                      AND oo.torolt='F'
  INNER JOIN T_FELHASZNALO_OSSZES f ON f.ID=fog.C_TANARID AND f.C_INTEZMENYID=@intezmenyId AND f.C_TANEVID=@tanevid AND f.TOROLT='F'
  LEFT JOIN (SELECT DISTINCT d.ID, d.C_NAME FROM T_DICTIONARYITEMBASE_OSSZES d)d ON d.ID=cs.C_TIPUSA
  INNER JOIN (SELECT DISTINCT d.ID, d.C_NAME FROM T_DICTIONARYITEMBASE_OSSZES d) Hetirend ON Hetirend.ID=oo.C_HETIREND

SELECT Pedagogus COLUMN456, ISNULL(CsoportTipus, 'Osztály') COLUMN262, SUM(Oraszam) COLUMN3670 FROM #csoportok cs GROUP BY Pedagogus, CsoportTipus ORDER BY Pedagogus, ISNULL(CsoportTipus, 'Osztály')

DECLARE @cols AS NVARCHAR(MAX),
    @query AS NVARCHAR(MAX)

SELECT DISTINCT @cols= ISNULL(@cols + ',','') + QUOTENAME(Hetirend) FROM #csoportok

SET @query='SELECT DISTINCT Pedagogus COLUMN456, ISNULL(CsoportTipus, ''Osztály'') COLUMN262, '+@cols+' FROM #csoportok cs PIVOT (SUM(Oraszam) FOR Hetirend IN ('+@cols+')) pv ORDER BY Pedagogus, ISNULL(CsoportTipus, ''Osztály'')'

EXEC sp_executesql @query;
DROP TABLE #csoportok

END

GO