DROP PROCEDURE IF EXISTS [dbo].[sp_GetErettsegiEredmenyekReszletekData]
GO

-- =============================================
-- Description:  <Előszedjük a tanuló érettségi eredményeit részletesen>
-- =============================================
CREATE PROCEDURE [dbo].[sp_GetErettsegiEredmenyekReszletekData]
   @pIntezmenyId    INT
  ,@pTanevId      INT
  ,@pTanuloId      INT

AS
BEGIN

  SET NOCOUNT ON;

  SELECT
      --NOTE: Azért CAST-oljuk NVARCHAR(10)-re, mert kellenek ideiglenes ID-k c# oldalon, amik stringesek!
      CAST(ErettsegiEredmeny.ID AS NVARCHAR(10))        ID
     ,ErettsegiEredmeny.C_ERETTSEGITANTARGY            ErettsegiTantargyId
     ,ErettsegiEredmeny.C_ERETTSEGISZINT            ErettsegiSzintId
     ,ErettsegiEredmeny.C_ERETTSEGITIPUS            ErettsegiTipusId
     ,ErettsegiEredmeny.C_IRASBELIPONTSZAM            IrasbeliPontszam
     ,ErettsegiEredmeny.C_SZOBELIPONTSZAM            SzobeliPontszam
     ,ErettsegiEredmeny.C_GYAKORLATPONTSZAM            GyakorlatiPontszam
     ,ErettsegiEredmeny.C_MEGJEGYZES              Megjegyzes
     --NOTE: Azért CAST-oljuk NVARCHAR(3)-re, mert ha nincs értéke, akkor "-"-et írunk c# oldalon, ami stringes!
     ,CAST(ErettsegiEredmeny.C_OSSZPONTSZAM AS NVARCHAR(3))    OsszPontszam
     ,ErettsegiTantargyAdatok.C_OSSZMAXPONTSZAM          OsszMaxPontszam
  FROM 
    T_ERETTSEGIEREDMENY_OSSZES ErettsegiEredmeny
  LEFT JOIN 
    T_ERETTSEGITANTARGY_OSSZES ErettsegiTantargy ON
      ErettsegiTantargy.ID = ErettsegiEredmeny.C_ERETTSEGITANTARGY
    AND  ErettsegiTantargy.C_ALINTEZMENYID = @pIntezmenyId
    AND ErettsegiTantargy.C_ALTANEVID = @pTanevId
    AND ErettsegiTantargy.TOROLT = 'F'
  LEFT JOIN 
    T_ERETTSEGITANTARGYADATOK_OSSZES ErettsegiTantargyAdatok ON
      ErettsegiTantargyAdatok.C_ERETTSEGITANTARGY = ErettsegiTantargy.ID
    AND  ErettsegiTantargyAdatok.C_ERETTSEGISZINT = ErettsegiEredmeny.C_ERETTSEGISZINT
    AND  ErettsegiTantargyAdatok.C_INTEZMENYID = @pIntezmenyId
    AND ErettsegiTantargyAdatok.C_TANEVID = @pTanevId
    AND ErettsegiTantargyAdatok.TOROLT = 'F'
  WHERE
      ErettsegiEredmeny.C_TANULOID = @pTanuloId
    AND  ErettsegiEredmeny.C_INTEZMENYID = @pIntezmenyId
    AND ErettsegiEredmeny.C_TANEVID = @pTanevId
    AND ErettsegiEredmeny.TOROLT = 'F'

END

GO