-- =============================================
-- Description:	<Beimportáljuk a tanuló értékelés mondatbankot>
-- =============================================
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

DROP PROCEDURE IF EXISTS [dbo].[uspImportTanuloErtekelesMondatbank]
GO

CREATE PROCEDURE [dbo].[uspImportTanuloErtekelesMondatbank]
	 @pIntezmenyId				INT
	,@pTanevId					INT
	,@pFelhasznaloId			INT
	,@pImportDataXml			XML
	,@pTanuloErtekelesTipusId	INT = NULL
	,@pEvfolyamTipusId			INT = NULL
	,@pTantargyId				INT = NULL
	,@pTipusId					INT
AS
BEGIN

	-- SET NOCOUNT ON added to prevent extra result sets from interfering with SELECT statements.
	SET NOCOUNT ON;
	
	DECLARE @tempImportData TABLE (
		 RovidNev	NVARCHAR(3)		NOT NULL
		,Szoveg		NVARCHAR(MAX)	NULL
	)
	
	DECLARE @currentDateTime DATETIME 
	SET @currentDateTime = (SELECT GETDATE())
		
	-- XML paraméter értelmezése
	INSERT INTO	
		@tempImportData	
	SELECT
		--Egyszerű import adatok
		 TanuloErtekelesMondatbankItem.value('(RovidNev)[1]',	'NVARCHAR(3)')		RovidNev
		,TanuloErtekelesMondatbankItem.value('(Szoveg)[1]',		'NVARCHAR(MAX)')	Szoveg 
	FROM
		@pImportDataXml.nodes('/TanuloErtekelesMondatbankImport/TanuloErtekelesMondatbank/TanuloErtekelesMondatbankItem') AS TanuloErtekelesMondatbank(TanuloErtekelesMondatbankItem)
		
	BEGIN TRY
		SET XACT_ABORT ON

		BEGIN TRANSACTION        
			INSERT INTO T_ERTEKELESMONDATBANK_OSSZES (
				--Egyszerű import adatok
				 C_ROVIDNEV
				,C_SZOVEG
				,C_ERTEKELESTIPUSA
				,C_EVFOLYAMTIPUSA
				,C_TANTARGYID
				,C_TIPUSID
						
				--Technikai adatok
				,C_INTEZMENYID
				,C_TANEVID
				,TOROLT
				,LASTCHANGED
				,CREATED
				,MODIFIER
				,CREATOR)
			SELECT
				--Egyszerű import adatok
				 tempTable.RovidNev
				,tempTable.Szoveg
				,@pTanuloErtekelesTipusId
				,@pEvfolyamTipusId
				,@pTantargyId
				,@pTipusId
						
				--Technikai adatok
				,@pIntezmenyId
				,@pTanevId
				,'F'
				,@currentDateTime
				,@currentDateTime
				,@pFelhasznaloId
				,@pFelhasznaloId
			FROM 
				@tempImportData tempTable    

		COMMIT TRANSACTION
	END TRY

	BEGIN CATCH
		IF @@TRANCOUNT > 0 AND XACT_STATE() <> 0 
			ROLLBACK TRANSACTION;
		THROW
	END CATCH

END


GO