SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO


IF OBJECT_ID('[dbo].[sp_GetTanulokFelmentesekHatarozatok]') IS NOT NULL 
BEGIN
  DROP PROCEDURE dbo.[sp_GetTanulokFelmentesekHatarozatok]
END  
GO

CREATE PROCEDURE dbo.[sp_GetTanulokFelmentesekHatarozatok]
	@OsztalyId		INT,
	@TanevId		INT
AS
BEGIN
	SET NOCOUNT ON;
	
	/*Alap adatok*/
		SELECT TOP(1)
			i.C_IGAZGATONEVE	 INT_IGAZGATO_NEV
			,i.C_NEV			 INT_NEV
			,i.C_OMKOD			 INT_OMKOD
			,i.C_IRANYITOSZAM	 INT_IRSZAM
			,i.C_VAROS			 INT_VAROS
			,dbo.fnGetDokumentumIntezmenyCime(@tanevId)  INT_CIM
			,ocs.C_NEV			 OSZTALYCSOPORT_NEV
			,osztf.C_VEZETEKNEV + ' ' + osztf.C_UTONEV OSZTFO_NEV
		FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@TanevId, @OsztalyId, 'T') Tanulok
			LEFT JOIN T_FELHASZNALO_OSSZES ft ON ft.ID = Tanulok.TanuloId AND ft.TOROLT = 'F'
			LEFT JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = @OsztalyId AND ocs.TOROLT = 'F'
			LEFT JOIN T_INTEZMENYADATOK_OSSZES i ON i.C_TANEVID = @TanevId AND i.TOROLT = 'F'
			LEFT JOIN T_OSZTALY_OSSZES o ON o.ID = ocs.ID AND o.TOROLT = 'F'
			LEFT JOIN T_FELHASZNALO_OSSZES osztf ON osztf.ID = o.C_OSZTALYFONOKID AND osztf.TOROLT = 'F'
		ORDER BY ft.C_NYOMTATASINEV
		
	/*Mentességek*/
		SELECT
			tt.C_NEV				TANTARGY
			,tm.C_MENTESSEGOKA		MENTESSEG_OKA
			,IIF(C_ERTEKELESMENTESITES = 'T', 'Értékelés alóli felmentés,', '') 
			 + IIF(C_ORAMENTESITES = 'T', 'Tanóra látogatása alóli felmentés,', '') 	
			 + IIF(C_SZOVEGESENERTEKELHETO = 'T', 'Szövegesen értékelhető,', '') TIPUSA
			,dbo.fnGetDokumentumDatumFormatum(tm.C_KEZDETE)			Kezdete
			,dbo.fnGetDokumentumDatumFormatum(tm.C_VEGE)			Vege
			,ft.ID					TANULO_ID
			,ft.C_VEZETEKNEV + ' ' + ft.C_UTONEV  TANULO_NEV
			,ft.C_NYOMTATASINEV + ' ' + CAST(ft.ID AS NVARCHAR)  GROUPPARAMETER
		INTO #TanuloMentesseg
		FROM fnGetDokumentumOsztalyokCsoportokTanuloi(@TanevId, @OsztalyId, 'T') Tanulok
			INNER JOIN T_FELHASZNALO_OSSZES ft ON ft.ID = Tanulok.TanuloId AND ft.TOROLT = 'F'
			INNER JOIN T_TANULOMENTESSEG_OSSZES tm ON tm.C_TANULOID = ft.ID AND tm.TOROLT = 'F'
			INNER JOIN T_TANTARGY_OSSZES tt ON tt.ID = tm.C_TANTARGYID AND tt.TOROLT = 'F'
		ORDER BY ft.C_NYOMTATASINEV

		SELECT 
			TANTARGY
			,MENTESSEG_OKA
			,IIF(TIPUSA = '', '', LEFT(TIPUSA, LEN(TIPUSA) - 1)) TIPUSA
			,Kezdete
			,Vege
			,TANULO_ID
			,TANULO_NEV
			,GROUPPARAMETER		
		FROM #TanuloMentesseg 
		ORDER BY Kezdete
		
		SELECT C_OSZTALYFONOKID PartnerID From T_OSZTALY_OSSZES WHERE T_OSZTALY_OSSZES.ID = @OsztalyId AND T_OSZTALY_OSSZES.TOROLT='F' and T_OSZTALY_OSSZES.C_ALTANEVID = @TanevId

		SELECT TANULO_ID, TANULO_NEV FROM #TanuloMentesseg ORDER BY TANULO_NEV

		DROP TABLE #TanuloMentesseg
		
END

GO