SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID('sp_GetDokumentumHelyettesitesekByHet') IS NOT NULL BEGIN
  DROP PROCEDURE sp_GetDokumentumHelyettesitesekByHet
END  
GO

CREATE PROCEDURE sp_GetDokumentumHelyettesitesekByHet
	@tanevId		INT,
	@hetSorszama	INT

AS
BEGIN
  SET NOCOUNT ON;

SELECT 
	FORMAT(C_HELYETTESITESNAPJA, 'yyyy.MM.dd.')	HelyettesitesNapja
	,helyettesito.C_NYOMTATASINEV			HelyettesitoNeve
	,helyettesitesett.C_NYOMTATASINEV		HelyettesitettNeve
	,helyettesitesett.ID					HelyettesitettId
	,het.C_HETSORSZAMA						HetSorszama
	,ocs.C_NEV								OsztalyCsoportNev
	,tantargy.C_NEV							TantargyNev
	,terem.C_NEV							TeremNev
	,ISNULL(CONVERT(NVARCHAR(5), orarendiOra.C_ORASZAM) + '.', '')Oraszam
INTO #adatok
FROM T_HELYETTESITESIIDOSZAK_OSSZES hi
	LEFT JOIN T_ORARENDIORA_OSSZES orarendiOra ON orarendiOra.Id = hi.C_HELYETTESITETTORARENDID AND orarendiOra.TOROLT = 'F'
	LEFT JOIN T_FELHASZNALO_OSSZES helyettesito ON helyettesito.Id = hi.C_HELYETTESTANAROKID AND helyettesito.TOROLT = 'F'
	LEFT JOIN T_FELHASZNALO_OSSZES helyettesitesett ON helyettesitesett.ID = orarendiOra.C_TANARID AND helyettesitesett.TOROLT = 'F'
	INNER JOIN T_NAPTARIHET_OSSZES het ON het.C_HETKEZDONAPJA <= C_HELYETTESITESNAPJA AND C_HELYETTESITESNAPJA <= C_HETUTOLSONAPJA  AND het.TOROLT = 'F' AND het.C_TANEVID = @tanevId
	LEFT JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.Id = orarendiOra.C_OSZTALYCSOPORTID AND ocs.TOROLT = 'F'
	LEFT JOIN T_TANTARGY_OSSZES tantargy ON tantargy.Id = orarendiOra.C_TANTARGYID AND tantargy.TOROLT = 'F'
	LEFT JOIN T_TEREM_OSSZES terem ON terem.Id = orarendiOra.C_TEREMID AND terem.TOROLT = 'F'
WHERE
	hi.TOROLT = 'F'	
	AND hi.C_TANEVID = @tanevId	
	AND het.C_HETSORSZAMA = @hetSorszama
ORDER BY FORMAT(C_HELYETTESITESNAPJA, 'yyyy.MM.dd.'), orarendiOra.C_ORASZAM

SELECT DISTINCT HetSorszama FROM #adatok

SELECT DISTINCT HelyettesitettId, HelyettesitettNeve, HetSorszama FROM #adatok ORDER BY HelyettesitettNeve

SELECT * FROM #adatok ORDER BY HelyettesitesNapja, Oraszam

DROP TABLE #adatok

END

GO