SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO


IF OBJECT_ID('[dbo].[sp_GetElfogadottTantargyfelosztasok]') IS NOT NULL 
BEGIN
  DROP PROCEDURE [dbo].[sp_GetElfogadottTantargyfelosztasok]
END  
GO
CREATE PROCEDURE [dbo].[sp_GetElfogadottTantargyfelosztasok]
	@tanevId   int,
	@intezmenyId int
AS
BEGIN
	SET NOCOUNT ON;

    -- fejléc
	SELECT IA.C_NEV IntezmenyNeve,
		   TE.C_NEV TANEV,
		   IA.C_ENGEDELYEZETTALLASHELYEK Allasok,
		   FORMAT(IASZ.C_ELFOGADOTTTTFDATUMA, 'yyyy. MMMM dd.', 'hu-hu') ElfogadasDatuma
	FROM T_INTEZMENYADATOK_OSSZES IA
	inner join T_TANEV_OSSZES TE on TE.ID = IA.C_TANEVID and TE.C_INTEZMENYID = IA.C_INTEZMENYID and TE.TOROLT = 'F'
	inner join T_INTEZMENYADATSZOLGALTATAS_OSSZES IASZ on IASZ.C_INTEZMENYID=IA.C_INTEZMENYID and IASZ.TOROLT='F' AND IASZ.C_TANEVID=@tanevId
	WHERE IA.TOROLT = 'F'
	and TE.ID = @tanevId
	and IA.C_INTEZMENYID = @intezmenyId

	--Pedagógusok
	select
	FA.C_ALKALMAZOTTID TanarId,
	FA.C_TANARNEVE TanarNev,
	FA.C_TANARMUNKAKORE Munkakor,
	FA.C_TANARPEDAGOGIAIKEPESITESE PedagogiaiKepesites,
	FA.C_TANARKOTELEZOORASZAMA KotelezoOraszam,
	FA.C_TANARMUNKAIDOKEDVEZMENYE MunkaidoKedvezmeny,
	FA.C_TANARMUNKAIDOKEDVEZMENYOKA MunkaidoKedvezmenyOka,
	IIF(FA.C_TANARKOTELEZOORASZAMA = 0 or C_TANARKOTELEZOORASZAMA <= FA.C_TANARMUNKAIDOKEDVEZMENYE, 0, FA.C_TANARKOTELEZOORASZAMA - isnull(FA.C_TANARMUNKAIDOKEDVEZMENYE, 0)) HetiOraszam,
	sum(FA.C_ORASZAM) ValosOraszam
	from T_FOGLALKOZASARCHIV_OSSZES FA
	where FA.TOROLT = 'F'
	and FA.C_INTEZMENYID = @intezmenyId and FA.C_TANEVID = @tanevId
	group by FA.C_ALKALMAZOTTID, FA.C_TANARNEVE, FA.C_TANARMUNKAKORE, FA.C_TANARPEDAGOGIAIKEPESITESE, FA.C_TANARKOTELEZOORASZAMA,
	FA.C_TANARMUNKAIDOKEDVEZMENYE, FA.C_TANARMUNKAIDOKEDVEZMENYOKA

	----Osztályok
	select
	FA.C_OSZTALYCSOPORTNEVE OsztalyNev,
	sum(FA.C_ORASZAM) OsszesOraszam
	from T_FOGLALKOZASARCHIV_OSSZES FA
	where FA.TOROLT = 'F'
	and FA.C_INTEZMENYID = @intezmenyId and FA.C_TANEVID = @tanevId
	group by FA.C_OSZTALYCSOPORTNEVE

	----Tantárgyfelosztás
	select
	FA.ID,
	FA.C_TANARNEVE TanarNev,
	FA.c_OSZTALYCSOPORTNEVE OsztalyNev,
	FA.C_TANTARGYNEVE TantargyNev,
	FA.C_ORASZAM Oraszam
	from T_FOGLALKOZASARCHIV_OSSZES FA
	where FA.TOROLT = 'F'
	and FA.C_INTEZMENYID = @intezmenyId and FA.C_TANEVID = @tanevId
END
GO